逼近法测量量柱测量距.doc

逼近法测量链轮量柱测量距

沈阳华晨金杯汽车有限公司发动机工厂 质量检验处 潘晓愚
沈阳经济技术开发区八号路12号 110027
xiaoyu.pan@brilliance- 13478393867

[摘要]：链轮量柱测量距的值是由分度圆直径和量柱直径计算而来，本文通过不断的改变分度圆半径拟合出不同直径的量柱，当量柱直径最接理论量柱直径时，保留分度圆半径，然后计算量柱测量距。

[关键词]：逼近法，分度圆直径，量柱测量距。

根据不同的链轮类型会有不同的量柱测量距的计算公式，如下图：

1.滚子链链轮的量柱测量距MR

d-分度圆直径; dRmin-量柱直径

2.齿型链链轮的量柱测量距MR

d-分度圆直径;p-节距;z-齿数;dR-量柱直径

测量思路:

不断的改变分度圆半径,在分度圆半径未端模拟出一点，做一个通过这点且与扫描出的轮廓相切的圆，即为模拟出的量柱。通过这个方法会拟合出多个不同直径的量柱，当量柱直径最接理论量柱直径时，保留分度圆半径，然后计算量柱测量距。

坐标系的建立：

l 第一基准为图纸要求的基准平面
l 第二基准为链轮中心，到任意一个齿中心。齿中心可采用在相邻两齿左右各打一点，取中点的形式确定。
l 坐标原点在链轮中心

如下图所示：

具体程序如下：

STOP

！******************************
！********手动建立坐标系********
！******************************

USEPRB (NAM=PRB(1))
MEPLA (NAM=PLANE(1), CSY=REFR$CSY, CPY=DEF$PLA3, ITY=GSS, DEL=Y)
MECIR (NAM=CIRCLE(1), CSY=REFR$CSY, CPY=DEF$CIR5, INO=I, ITY=GSS, DEL=Y)
MEPNT (NAM=POINT(1), CSY=REFR$CSY, CTY=DNP, DEL=Y)
MEPNT (NAM=POINT(2), CSY=REFR$CSY, CTY=DNP, DEL=Y)
MCSPTPT (NAM=POINT(3), TYP=POI, CSY=REFR$CSY, CPY=DEF$PNT4, EL1=POINT(1), TY1=POI, ST1=POI, EL2=POINT(2), TY2=POI, ST2=POI, CNN=SYM)
MCDPTPT (NAM=DISTANCE(1), TYP=DIS, CSY=REFR$CSY, CPY=DEF$DIS3, EL1=CIRCLE(1), TY1=POI, ST1=POI, EL2=POINT(3), TY2=POI, ST2=POI, CNN=DIS)
BLDCSY (NAM=CSY_MAN, TYP=CAR, SPA=PLANE(1), SDR=+Z, PLA=DISTANCE(1), PDR=+X, XZE=CIRCLE(1), YZE=CIRCLE(1), ZZE=PLANE(1))

STOP

！************************
！********参数设置********
！************************

K=0 ！计数器清零
GB_T= ！链轮类型开关：滚子链为0，齿型链为1。
PAR= ！链轮奇偶数齿开关：偶数齿为0，奇数齿为1。
NOM_TEE= ！理论齿数
ADD_TEE= ！增加检测齿数
JUM_TEE= ！跳跃检测齿数
NOM_D= ！理论量柱测量
NOM_U= ！理论量柱测量距上公差
NOM_L= ！理论量柱测量距下公差
PIN_D= ！理论量柱直径
PRE= ！精度
DIS_P= ！节距

！******************************
！********自动建立坐标系********
！******************************

USEPRB (NAM=PRB(1))
GENCIR (NAM=PLANE(2), XCO=0, YCO=0, ZCO=0, DIA=30, NPT=8, PLA=XY, INO=P, MIP=0, MXP=360, PDI=5, CSY=CSY_MAN, ZVL=5, DEL=Y, RTP=0)
MEPLA (NAM=PLANE(2), CSY=CSY_MAN, CPY=DEF$PLA3, ITY=GSS, DEL=N)
GENCIR (NAM=CIRCLE(2), XCO=0, YCO=0, ZCO=-3, DIA=19.3, NPT=6, PLA=XY, INO=I, MIP=0, MXP=360, PDI=5, CSY=CSY_MAN, DEL=Y, RTP=0)
MECIR (NAM=CIRCLE(2), CSY=CSY_MAN, CPY=DEF$CIR5, INO=I, ITY=GSS, DEL=N)
MEPNT (NAM=POINT(4), CSY=CSY_MAN, CTY=DNP, DEL=Y)
MEPNT (NAM=POINT(5), CSY=CSY_MAN, CTY=DNP, DEL=Y)
MCSPTPT (NAM=POINT(6), TYP=POI, CSY=CSY_MAN, CPY=DEF$PNT4, EL1=POINT(4), TY1=POI, ST1=POI, EL2=POINT(5), TY2=POI, ST2=POI, CNN=SYM)
MCDPTPT (NAM=DISTANCE(2), TYP=DIS, CSY=CSY_MAN, CPY=DEF$DIS3, EL1=CIRCLE(2), TY1=POI, ST1=POI, EL2=POINT(6), TY2=POI, ST2=POI, CNN=DIS)
BLDCSY (NAM=CSY_CNC, TYP=CAR, SPA=PLANE(2), SDR=+Z, PLA=DISTANCE(2), PDR=+X, XZE=CIRCLE(2), YZE=CIRCLE(2), ZZE=PLANE(2))

！************************
！********测量开始********
！************************

CRSUBTYP RES_CIR, FINT((NOM_TEE+ADD_TEE)/JUM_TEE)+1, Y, ELE, APT
！创建一个圆元素
DO (NAM=I, BGN=0, END=NOM_TEE+ADD_TEE, DLT=JUM_TEE)
！DO循环结束点为理论齿数加增加检测齿数，步距为跳跃齿数
ALROT (NEW=CSY_(I), OLD=CSY_CNC, ANG=I*360/NOM_TEE, AXI=+Z, DTY=CSY, USE=Y)
！利用DO循环和旋转坐标系，选择性测量链齿
ME2DE (NAM=CURVE(1), CSY=CSY_(I), MOD=(NOC,NOE), INO=I, DEL=N)
！扫描链轮，如下图：

RCOR2D (SRC=CURVE(1), DST=CURVE(2), OPN=Y, A_O=XY, CLW=Y)
!半径补偿
COU_D=PIN_D*10

DO (NAM=J, BGN=0, END=（2*(NOM_U-NOM_L)/PRE）)
CRSUBTYP (NAM=CUS_POI, LIN=1, DEL=Y, TYP=ELE, STY=APT)
！创建点元素
STE_X=NOM_D/2+2*NOM_L+PRE*J
！不断的改变分度圆半径
PUTVALS (OBJ=CUS_POI.ACT.PTS(1), TYP=APT, RDS=(X,Y,Z), VAL=(SET_X,0,0))
！在分度圆半径未端模拟出一点
COLAPT (NAM=CUS_CIR, CSY=CSY_(I), DEL=Y, PTS=(CURVE(2),CUS_POI), TYP=CIR)
！做一个通过这点且与扫描出的轮廓相切的圆

如下图所示：

BLDCIR (NAM=CUS_CIR, CSY=CSY_(I), INO=I, ITY=CII)
！重新计算圆，计算方式一定要为内切
GETVALS (OBJ=CUS_CIR, TYP=ELE, RDS=(X,Y,A), REA=(X1,Y1,GEN_D)
！得到量柱的中心坐标及量柱的直径

IFTHEN (VL1=FABS(GEN_D-PIN_D), VL2= FABS(COU_D-PIN_D), TYP=LT)
！利用IF语句，找到最接近的量柱直径，并且保留分度圆半径未端点的坐标
COU_D=GEN_D
X2=X1
Y2=Y1
ENDIF

ENDDO

X1=FCOS(I*360/TEETH+FATN(Y2/X2))*FSQR(FX_2(X2)+FX_2(Y2))
Y1=FSIN(I*360/TEETH+FATN(Y2/X2))*FSQR(FX_2(X2)+FX_2(Y2))
！计算分度圆半径端点在初始坐标系下的X和Y值，如下图：

K=K+1
PUTVALS (OBJ=RES_CIR.ACT.PTS(K), TYP=ELE, RDS=(X,Y,Z), VAL=(X1,Y1,0))
！将所有生成出的点放入圆
ENDDO

MECIR (NAM=RES_CIR, CSY=CSY_CNC, MOD=NOM, INO=O, ITY=GSS, DEL=N)
GETVALS (OBJ=DIA_D, TYP=ELE, RDS=A, REA=GEN_D)
！得到分度圆的直径

！****************************************************
！********根据链轮类型及奇偶齿数计算量柱测量距********
！****************************************************

IFTHEN (VL1=GB_T, VL2=0, TYP=EQ)
IFTHEN (VL1=PAR, VL2=0, TYP=EQ)
MR＝DIA_D+PIN_D
ELSE
MR＝DIA_D*FCOS(90/NOM_TEE)+PIN_D
ENDIF
ELSE
IFTHEN (VL1=PAR, VL2=0, TYP=EQ)
MR＝DIA_D-0.125*DIS_P/FSIN(30-180/NOM_TEE)+PIN_D
ELSE
MR＝FCOS(90/NOM_TEE)* (DIA_D-0.125*DIS_P/FSIN(30-180/NOM_TEE))+PIN_D
ENDIF
ENDIF

LISREA (NAME=MR, DEV=TT)
！在屏幕上显示量柱测量距

STOP

量柱测量距的值完全可以由卡尺或更简单便捷的测量工具测得，本文只是提供一种测量思路供大家参考。文章多有纰漏，请多谅解。

参考文献：

1.机械设计手册 单行本 成大先 主编 机械传动 化学工业出版社