第七讲 图层标注.doc

第7章  MO的图层渲染
图层的渲染是通过设置图层对象的Renderer属性，来对MapLayer图层采用不同的渲染方法。Renderer属性设置的语法为：
Object.Renderer[=renderer]
其中：
Object：一般为图层对象，表达为Layer，Map1.Layers.Item(0)或Map1.Layers(0)；
Renderer：表示渲染方式的对象表达式，可以是ClassBreaksRenderer、DotDensityRenderer、LabelRenderer或ValueMapRenderer等。
7.1 标注渲染(LabelRenderer)
标注渲染是通过对象LabelRenderer来实现的。
    LabelRenderer对象可以在图层上显示表示图形图元的属性文字。这些属性文字是从属性数据库(对于shape格式是dbf文件)的指定字段中读取的。
    用Field属性来指定来源字段，用symbol(TextSymbol格式)属性来设置显示方式，用SymbolCount说明采用的Symbol数量。
    在缺省方式下，LabelRenderer在一个图层内的每个图元的中心标注文字。可以通过以下的设置改变标注位置和方式。
    如果SymbolCount>1，就可以使用SymbolField属性了。使用SymbolField属性可以使一个图层上的图元有不同的渲染方式。
    还可以用DrawBackGround属性控制图元的重绘功能，用AllowDuplicates属性控制是否允许重复标注，用SplinedText属性控制是否沿着图元方向标注，用Plip属性控制在沿着图元方向标注是否需要翻转。
    除了使用Field属性决定标注来源字段外，LabelRenderer还提供了几种设置方式来源字段的属性，如用HeightField指定标注的高度的来源，用RotationField属性指定标注时旋转的角度的来源，用XoffsetField和YoffsetField属性设置标注时偏移数值的来源，还可以用FittedField属性决定一条直线来确定标注位置。最后，还可以设置LevelField属性值，利用MaxLevel和MinLevel属性，可以控制哪个比例尺的图元可以被标注。
定义标注渲染的设置语句为：
Set layer.Renderer=new LabelRenderer    ‘设置标注渲染方式；
Layer.Renderer.Field=”Name”           ‘指定要显示的字段；
Layer.Renderer.Symbol(0).Color=moBlack ‘设置Symbol；
Layer.Renderer.Symbol(0).Font.Size=10
7.12 标注偏移
有时会遇到地图上的标注位置重复，可以使用XoffsetField和YoffsetField属性设置标注的偏移，以避免文字相互覆盖。
XoffsetField定义为：
Object.XOffsetField[=value]
其中：
Object：图层对象；
Value：字符串，指定存放X方向的偏移值的字段，在属性数据库中。
YoffsetField的定义类似。定义的方法为：
Dim oRenderer as new MapObjects2.LabelRenderer
Map1.Layers(0).Renderer=oRenderer
oRenderer.XoffsetField=”CITIES_”
    如果要在一个图层中使用标注偏移，可以在属性数据库中增加2个数值型字段，分
别命名为Xoffset和Yoffset，用于存放偏移数值。
下例对于墨西哥地图的”CITIES_”字段使用了XoffsetField。在Form上添加一个Map1、Command1和Command2，运行时单击Command2，就可以在图层上看见标注偏移的效果，单击Command1还原。
Dim dbl As Boolean
Private Sub command1_click()
dbl = False
Map1.Layers.Clear
DrawLayer
End Sub
Private Sub command2_click()
dbl = True
Map1.Layers.Clear
DrawLayer
End Sub
Private Sub DrawLayer()
Dim dc As New DataConnection
Dim layer As MapLayer
Dim Trender As New mapobjects2.LabelPlacer
dc.Database = App.Path + "\..\" + "Mexico"
If Not dc.Connect Then
    MsgBox "指定的文件夹下没找到图层数据文件！"
    End
End If
Set layer = New MapLayer
Set layer.GeoDataset = dc.FindGeoDataset("states")
layer.Symbol.Color = moOrange
layer.Symbol.Size = 1
layer.Symbol.Style = 2
layer.Symbol.OutlineColor = moBrown
Map1.Layers.Add layer
Set layer = New MapLayer
Set layer.GeoDataset = dc.FindGeoDataset("cities")
layer.Symbol.Color = moRed
layer.Symbol.Size = 3
layer.Symbol.Style = 0
Set layer.Renderer = New LabelRenderer
With layer.Renderer
    If dbl Then
        .XOffsetField = "Cities_"
    End If
    .Field = "Name"
    .Symbol(0).Color = moBlack
    .Symbol(0).Font.Size = 8
End With
Map1.Layers.Add layer
Map1.Refresh
End Sub

由于cities.dbf的数据库是MO提供的，其中没有Xoffset和Yoffset字段用于存放标注偏移量，因此这个例子运行时，只是胡乱偏移，并不美观。实际应用中要仔细设置。
下图是笔者做的一个北京市的水质管理系统的GIS图，其中的水质测站利用Xoffset和Yoffset字段，设置了合理的标注偏移。
7.1.3 使用SymbolField进行多样化渲染
使用SymbolField属性，可以使一个图层上的图元有不同的标注渲染方式。
除了用Field属性来指定标注来源字段外，还要用SymbolField属性指定一个序号字段。该字段的可能取值个数决定了需要的Symbol种类。定义一个SymbolCount，对图层设置和SymbolCount数目相同的Symbol(i)。运行时每个图元从SymbolField所指定的字段中取得一个序号i值，绘制则用Symbol(i)显示渲染。
7.1.4 分级标注
可以通过Field属性得到标注字段，LevelField属性得到分级数值字段，利用设置MaxLevel和MinLevel属性，控制哪些图元可以被标注。
Private Sub command1_click()
Dim orenderer As New MapObjects2.LabelRenderer
Map1.Layers("CITIES").Renderer = orenderer
With orenderer
           .Field = "NAME"
          .LevelField = "CITIES"
          .MinLevel = 0
          .MaxLevel = 13
End With
Map1.Refresh
End Sub
7.2 按值渲染(ValueMapRenderer)
7.2.1 ValueMapRenderer定义
用ValueMapRenderer对象可以按照数值给图层的图元上色。
数值用Value属性指定的字段从属性数据库中得来，显示方式用一组Symbol来定义。另外，还可以定义一个DefaultSymbol，用以显示没有匹配的图元。
ValueMapRenderer不仅支持数值字段，也支持字符字段，它可以容纳32767个值。但ValueMapRenderer不支持Boolean或Date字段。
使用时，要先定义一个ValueMapRenderer对象，如：
Dim oRenderer as new MapObjects2.ValueMapRenderer
再得到指定字段所有不重复数值的数组(如strs)，然后设置oRenderer.Field和oRenderer.ValueCount，再用下面的语句为ValueMapRenderer对象填充值：
For i=0 to oRenderer.ValueCount-1
    oRenderer.Value(i)=strs(i)
next i
最后：
Set map1.Layers(0).Renderer=oRenderer
Map1.Refresh
7.2.2基本示例
Dim moRecset As MapObjects2.Recordset
Dim oRenderer As New MapObjects2.ValueMapRenderer
Private Sub Command1_Click()
    Dim strs As New MapObjects2.Strings
    Dim sFldname As String
    Dim oSym As New MapObjects2.Symbol
    Dim i As Integer
    '初始化
    Set moRecset = Map1.Layers(0).Records
    sFldname = "area"
    Do While Not moRecset.EOF
        strs.Add moRecset(sFldname).ValueAsString
        moRecset.MoveNext
    Loop
    '设置渲染参数
    Set Map1.Layers(0).Renderer = oRenderer
    oRenderer.Field = sFldname
    oRenderer.ValueCount = strs.Count
    '设置缺省值
    oRenderer.UseDefault = True
    Set oSym = oRenderer.DefaultSymbol
    oSym.Color = moPaleYellow
    '开始渲染
    For i = 0 To oRenderer.ValueCount - 1
        oRenderer.Value(i) = strs(i)
    Next i
    Map1.Refresh
    '消除对象，为下次点击准备
    Set oRenderer = Nothing
    Set strs = Nothing
    Set moRecset = Nothing
End Sub
经过单击按钮后我们发现原来的渲染颜色都变了，这是因为颜色是随机生成的。要得到固定的渲染，我们可以对Renderer对象的Symbol数组的Color属性进行设置，这样就将颜色固定下来了。
7.3 点密度渲染(DotDensityRenderer)
7.3.1 DotDensityRenderer定义
用该对象可以在面状图层上以点的数量表示密度值，如人口、矿产资源等。使用时，可以用其DotValue属性表示第个点代表的数量，由Field属性指定的字段提供每个图元的总数量，以决定该图元的点数。可以用DotColor设置点的颜色，用DotSize设置点的大小。
用以下语句定义一个DotDensityRenderer对象：
Set map1.layers(0).Renderer=new Mapobjects2.DotDensityRenderer
7.3.2示例
Private Sub Command2_Click()
    Dim oDotRend As New mapobjects2.DotDensityRenderer
    Set Map1.Layers("states").Renderer = oDotRend
    With oDotRend
        .Field = "Area"
        .DotSize = 3
        .DotColor = moBlue
        .DotValue = 1
        .DrawBackground = True
    End With
    Map1.Refresh
    Set oDotRend = Nothing
End Sub
7.4 分类渲染(ClassBreakRenderer)
7.4.1 ClassBreakRenderer定义
ClassBreakRenderer对象按属性数据库的一个数值字段分类，并用不同的Symbol定义的显示方式来渲染图层上的图元。
用BreakCount属性指定分类数目，用一个Break数组存储各类别的数据。注意，类别数比BreakCount数大1，例如设定BreakCount=2(有Break(0)和Break(1)两个值)，则类别数为3，分别表示小于Break(0)、在Break(0)和Break(1)之间、大于Break(1)。
可以用RampColors方法在图元上显示给定头尾颜色之间的渐近颜色，也可以直接用Symbol定义每个类别的颜色。可以在点状图层上使用SizeSymbols方法，通过指定头尾的size，达到点图元大小的渐近显示的效果。
定义ClassBreaksRenderer对象的语句如下：
Set Map1.layers(0).Renderer=new MapObjects2.ClassBreaksRenderer
7.4.2 统计对象(Statistics)
在使用ClassBreakRender对象时经常要用到statistics对象。该对象表示用一个记录集对象的CalculateStatistics方法对一个数值字段的记录集进行统计计算的结果。该对象的计算属性有：Max、Min、Mean、StdDev(均方差)、Sum。还可用Count属性返回记录集的记录数。
使用统计对象的语句为：
Dim ostats as mapobjects2.statistics
Set ostats=map1.layers(0).Records.CalculateStatistics(FieldName)
MsgBox ostats.Min
7.4.3根据面积的统计值分区显示
以下程序设置States图层的“Area”字段为数量来源字段，用RampColors方法设置颜色从淡黄到探蓝的渐进变化。
Private Sub Command3_Click()
    Dim i As Integer
    Dim oMapLayer As mapobjects2.MapLayer
    Dim ostats As mapobjects2.Statistics
    Dim oClassRend As New mapobjects2.ClassBreaksRenderer
    Dim fBreakval As Double
    Set oMapLayer = Map1.Layers("states")
    Set oMapLayer.Renderer = oClassRend
    With oClassRend
        .SymbolType = moFillSymbol
        .Field = "AREA"
        Set ostats = oMapLayer.Records.CalculateStatistics("AREA")
        fBreakval = ostats.Mean - (ostats.StdDev * 3)
        For i = 0 To 6
            If fBreakval >= ostats.Min And fBreakval <= ostats.Max Then
                .BreakCount = .BreakCount + 1
                .Break(.BreakCount - 1) = fBreakval
            End If
            fBreakval = fBreakval + ostats.StdDev
        Next
        .RampColors moPaleYellow, moNavy
    End With
    Map1.Refresh
End Sub
7.4.4  使用SizeSymbols渐近显示点图元
    在点状图层上使用SizeSymbols方法，通过指定头尾的size，可以达到点图元大小的渐进显示的效果。
以下程序设置Cities图层的“POPULATION”字段为数量来源字段，用SizeSymbols方法设置点图元大小从3号到8号的渐进变化。
Private Sub Command4_Click()
    Dim i As Integer
    Dim oMapLayer As mapobjects2.MapLayer
    Dim ostats As mapobjects2.Statistics
    Dim oClassRend As New mapobjects2.ClassBreaksRenderer
    Dim fBreakval As Double
    Set oMapLayer = Map1.Layers("cities")
    Set oMapLayer.Renderer = oClassRend
    With oClassRend
        .SymbolType = moPointSymbol
        .Field = "POPULATION"
        Set ostats = oMapLayer.Records.CalculateStatistics("POPULATION")
        fBreakval = ostats.Mean - (ostats.StdDev * 3)
        For i = 0 To 6
            If fBreakval >= ostats.Min And fBreakval <= ostats.Max Then
                .BreakCount = .BreakCount + 1
                .Break(.BreakCount - 1) = fBreakval
            End If
            fBreakval = fBreakval + ostats.StdDev
        Next
        .SizeSymbols 6, 18
        For i = 0 To .BreakCount
            .Symbol(i).Color = moRed
        Next
        .RampColors moLimeGreen, moRed
    End With
    Map1.Refresh
End Sub
7.5 图表渲染(ChartRenderer)
7.5.1 ChartRenderer定义
用ChartRenderer对象提供的属性方法，可以利用饼图或柱图来描述图元的多个参数。还可以用显示的图表的大小来表示图元的多少。
用ChartType确定是Pie chart还是Bar chart，还可以用moCustom常数和CustomChart属性来定义一个自己的图表类型。用ShowOutline属性来控制是否显示图表的轮廓线。用Field和Color属性数组表示图表来源字段和采用的颜色，用FieldCount属性表示数组的维数。
用BarHeight和BarWidth属性表示图表的行和列，用NormalizationField属性使图表标准化，用SizeField、MinPieSize和MaxPieSize属性控制图表的大小。
用NullValue属性和NoNullValue方法来处理空值。一个数值全部为空的图表将不能被显示。
用下面的语句定义一个ChartRenderer对象：
Set map1.Layers(0).Renderer=new MapObjects2.ChartRenderer
7.5.2 ChartRenderer对象的基本示例
Private Sub Command5_Click()
    Dim cr As New mapobjects2.ChartRenderer
    With cr
        .ChartType = moBar
        .FieldCount = 2
        .Field(0) = "area"
        .Color(0) = moRed
        .Field(1) = "featureid"
        .Color(1) = moGreen
    End With
    Set Map1.Layers("states").Renderer = cr
    Map1.Refresh
End Sub
7.6 Z值渲染(Zrenderer)
虽然MO在本质上是一个二维GIS开发软件，但也有一些简单的三维功能，主要是通过图元的Z值来体现的。
    用ZRenderer对象可以对MapLayer图层上图元的z值进行渲染。和ClassBreakRenderer对象类似，Zrenderer对象用BreakCount属性指定分类数目，用一个Break数组储存从各类别的数据。同样，类别数比BreakCount数大1，例如你设定BpeakCount=2(有Break(0)和Break(1)两个值)，则类别数为3，分别表示<Break(0)、在Break(0)和Break(1)之间、>Break(1)。
    可以用RampColors方法在图元上显示给定头尾颜色之间的渐进颜色，也可以直接用symbol定义每个类别的颜色。可以在点状图层上使用SizeSymbols方法，通过指定头尾的size，达到点图元大小的渐进显示的效果。
定义Zrenderer对象的基本语句如下：
Dim zren As New MapObjects2.ZRenderer
With zren
.BreakCount = 2
.Break(0) = 600
.Break(1) = 700
.SymbolType = moPointSymbol
For i = 0 To .BreakCount
    .Symbol(i).Color = QBColor(i)
    .Symbol(i).Style = moTriangleMarker
    .Symbol(i).Size = 5
Next i
End With
7.7 组渲染(GroupRenderer)
7.7.1 GroupRenderer定义
GroupRenderer定义为：
Object.Renderer(index)[=value]
其中：
Object：一般为图层对象；
Index：一个整数，表示组中的位置(index)，数值从0到object的Count属性之间；
Value：表示渲染方式的对象表达式。
使用时，先定义一个组渲染对象；
Dim GroupRend as new MapObjects2.GroupRenderer
再按前面介绍的方法分别设置各种渲染方式，用：
GroupRend.Add Renderi
来向组内添加渲染方式，最后用语句：
Map1.Layers(“states”).Renderer=GroupRend
Map1.Refresh
就可以显示渲染效果了。