中承式拱桥Ansys模型.doc

上承式、中承式和下承式拱桥的分类，主要是按照拱桥的行车道位置分的。行车道系（桥面系）在拱肋之上的称为上承式，中承式拱桥的行车道系位于拱肋矢高的中间部位，桥面系一部分用吊杆悬挂在拱肋下，一部分用立柱支撑在拱肋上。同理，下承式拱桥的车行道位于拱肋和吊杆之下。
以下是Ansys模型命令流
/prep7
et,1,beam4
et,2,link10
et,3,shell63
r,1,6,4.5,2,2,3
r,2,3,3.0,0.8,1.5,3
r,3,0.4,0.4,0.4,0.4
r,4,0.0157,9e-4
r,5,0.0157,1.4e-3
r,6,1.0,0.2,0.1,1,1.5
mp,ex,1,2e11
mp,nuxy,1,0.3
mp,dens,1,7800
mp,ex,2,3e10
mp,nuxy,2,0.2
mp,dens,2,2700
!添加关键点
k,1,-65,-5.25
k,2,-60,-10,0
k,3,-55,-5.25
k,4,-50
k,5,-45,4.75
k,6,-40,9
k,7,-35, 12.75
k,8,-30,16
k,9,-25, 18.75
k,10,-20, 21
k,11,-15,22.75
k,12,-10,24
k,13,-5,24.75
k,14,0,25
k,15,5,24.75
k,16,10,24
k,17,15,22.75
k,18,20,21
k,19,25, 18.75
k,20,30,16
k,21,35,12.75
k,22,40,9
k,23,45,4.75
k,24,50
k,25,55,-5.25
k,26,60,-10
k,27,65,-5.25
*do,i,1,29
k,27+i,5*i-75
*enddo
kgen,2,all,,,,,21,,0
!绘拱圈框架r1
*do,i,1,26
l,i,i+1
l,i+56,i+57
*enddo
l,1,28
l,27,56
l,57,84
l,83,112
!绘制拱间联系r2
*do,i,1,13
l,2*i,2*i+56
*enddo
!绘制横隔梁r5
*do,i,1,29
l,i+27,i+83
*enddo
!绘制纵梁r5
*do,i,1,28
l,i+27,i+28
l,i+83,i+84
*enddo
!绘腹拱墩r5
*do,i,1,3
l,i+56,i+84
l,i,i+28
l,i+24,i+52
l,i+80,i+108
*enddo
!绘桥梁吊杆r4r5
*do,i,1,19
l,i+4,i+32
l,i+60,i+88
*enddo
!绘桥面r3
*do,i,1,28
a,i+27,i+28,i+84,i+83
*enddo
!拱圈框架r1
lsel,s,,,1,56
latt,1,1,1
lesize,all,2
lmesh,all
!横隔梁纵梁腹拱墩r6
lsel,s,,,70,166
latt,1,6,1
lesize,all,2
lmesh,all
!拱间联系r2
lsel,s,,,59,67
lsel,a,,,57,57
lsel,a,,,69,69
latt,1,2,1
lesize,all,2
lmesh,all
!悬索
lsel,s,,,167,172
latt,1,5,2
lesize,all,,,1
lmesh,all
lsel,s,,,173,198
latt,1,4,2
lesize,all,,,1
lmesh,all
lsel,s,,,199,204
latt,1,5,2
lesize,all,,,1
lmesh,all
!桥面
aatt,2,3,3
aesize,all,2
amesh,all
finish
!施加荷载和约束
/solu
!位移约束
dk,2,all
dk,26,all
dk,58,all
dk,82,all
dk,28, , , , 1,uy,uz
dk,56, , , , 1,uy,uz
dk,84, , , , 1,uy,uz
dk,112, , , , 1,uy,uz
!重力G
acel,0,9.8,0,
pstres,1
/solu
antype,2
modopt,lanb,20
mxpand,10,0,100
pstres,1
solve
/post1
set,list
set,1,2 !设置荷载子步（第二阶）的结果为当前
pldisp,1 !绘制振型图
plnsol,u,y !绘制Uy图
etable,mi,smisc,6 !定义单元表（弯矩分布）
etable,mj,smisc,12
plls,mi,mj !绘制弯矩分布

/POST1
ETABLE,Mz1,SMISC, 6
ETABLE,Mz2,SMISC, 12

/REPLO
/VIEW,1,-1
/ANG,1
/REP,FAST
!*设置视角
PLDI, ,
ANMODE,10,0.5, ,0
!*建立动画