简单桁架桥梁ANSYS分析.doc

下面以一个简单桁架桥梁为例，以展示有限元分析的全过程。背景素材选自位于密执
安的"Old North Park Bridge"  (1904 - 1988)，见图3-22。该桁架桥由型钢组成，顶梁及侧梁，
桥身弦杆，底梁分别采用3种不同型号的型钢，结构参数见表3-6。桥长L=32m,桥高H=5.5m。
桥身由8段桁架组成，每段长4m。该桥梁可以通行卡车，若这里仅考虑卡车位于桥梁中间
位置，假设卡车的质量为4000kg，若取一半的模型，可以将卡车对桥梁的作用力简化为P1，
P2和P3，其中P1= P3=5000 N, P2=10000N，见图3-23。

图3-22位于密执安的"Old North Park Bridge"  (1904 - 1988)

图3-23桥梁的简化平面模型(取桥梁的一半)

表3-6桥梁结构中各种构件的几何性能参数
构件惯性矩m4横截面积m2
顶梁及侧梁(Beam1) 643.8310m-´ 322.1910m-´
桥身弦梁(Beam2) 61.8710-´ 31.18510-´
底梁(Beam3) 68.4710-´ 33.03110-´

解答以下为基于ANSYS图形界面(Graphic User Interface , GUI)的菜单操作流程。

安全提示：如果聊天中有涉及财产的操作，请一定先核实好友身份。发送验证问题或点击举报
天意  11:36:47
(1)进入ANSYS（设定工作目录和工作文件）
 程序→ ANSYS → ANSYS Interactive →  Working directory（设置工作目录）→ Initial jobname
（设置工作文件名）:TrussBridge → Run → OK
(2)设置计算类型
ANSYS Main Menu：Preferences… → Structural → OK
(3)定义单元类型

hhQÆRRN«•QQ
wwwwww..bbzzffxxww..ccoomm QM•9NN•}
ANSYS Main Menu：Preprocessor → Element Type →  Add/Edit/Delete... → Add…→ Beam: 2d
elastic 3 → OK（返回到Element Types窗口）→ Close
(4)定义实常数以确定梁单元的截面参数
ANSYS Main Menu: Preprocessor → Real  Constants…→ Add/Edit/Delete → Add…→ select Type 1
Beam 3 → OK → input Real Constants Set No.  : 1 , AREA: 2.19E-3，Izz: 3.83e-6(1号实常数用于顶梁和
侧梁) → Apply → input Real Constants Set  No. : 2 , AREA: 1.185E-3，Izz: 1.87E-6 (2号实常数用于弦杆)
→ Apply → input Real Constants Set No. : 3,  AREA: 3.031E-3，Izz: 8.47E-6 (3号实常数用于底梁) → OK
(back to Real Constants window) → Close  (the Real Constants window)
(5)定义材料参数
ANSYS Main Menu: Preprocessor → Material  Props → Material Models → Structural → Linear
→ Elastic → Isotropic → input EX: 2.1e11,  PRXY: 0.3(定义泊松比及弹性模量) → OK → Density (定
义材料密度) → input DENS: 7800, → OK → Close（关闭材料定义窗口）
(6)构造桁架桥模型
生成桥体几何模型
ANSYS Main Menu：Preprocessor → Modeling → Create →  Keypoints → In Active CS → NPT
Keypoint number：1，X，Y，Z Location in active CS：0，0 → Apply →同样输入其余15个特征点坐
标（最左端为起始点，坐标分别为(4,0), (8,0), (12,0), (16,0),  (20,0), (24,0), (28,0), (32,0), (4,5.5), (8,5.5),
(12,5.5), (16.5.5), (20,5.5), (24,5.5),  (28,5.5)）→ Lines → Lines → Straight Line →依次分别连接特征点
→ OK
网格划分
ANSYS Main Menu: Preprocessor → Meshing →  Mesh Attributes → Picked Lines →选择桥顶梁
及侧梁→ OK → select REAL: 1, TYPE: 1 →  Apply →选择桥体弦杆→ OK → select REAL: 2,
TYPE: 1 → Apply →选择桥底梁→ OK → select REAL: 3, TYPE:1 → OK  → ANSYS Main Menu：
Preprocessor → Meshing → MeshTool →位于Size Controls下的Lines：Set → Element Size on Picked
→ Pick all → Apply → NDIV：1 → OK → Mesh → Lines → Pick all →  OK (划分网格)
(7)模型加约束
ANSYS Main Menu: Solution → Define Loads →  Apply → Structural→ Displacement → On
Nodes →选取桥身左端节点→ OK → select Lab2: All DOF(施加全部约束) → Apply →选取桥身右
端节点→ OK → select Lab2: UY(施加Y方向约束) → OK
(8)施加载荷
ANSYS Main Menu: Solution → Define Loads →  Apply → Structural → Force/Moment → On
Keypoints →选取底梁上卡车两侧关键点（X坐标为12及20）→ OK → select Lab: FY，Value: -5000
→ Apply →选取底梁上卡车中部关键点（X坐标为16）→ OK → select Lab: FY，Value: -10000 → OK
→ ANSYS Utility Menu：→ Select → Everything
(9)计算分析
ANSYS Main Menu：Solution → Solve → Current LS → OK
(10)结果显示
ANSYS Main Menu：General Postproc → Plot Results →  Deformed shape → Def shape only → OK
（返回到Plot Results）→ Contour Plot → Nodal Solu → DOF  Solution, Y-Component of Displacement
→ OK（显示Y方向位移UY）(见图3-24(a))
定义线性单元I节点的轴力
ANSYS Main Menu → General Postproc →  Element Table → Define Table → Add → Lab:
[bar_I], By sequence num: [SMISC,1] → OK →  Close
定义线性单元J节点的轴力
ANSYS Main Menu → General Postproc →  Element Table → Define Table → Add → Lab:
[bar_J], By sequence num: [SMISC,1] → OK →  Close
画出线性单元的受力图(见图3-24(b))
ANSYS Main Menu → General Postproc → Plot  Results → Contour Plot → Line Elem Res →
LabI: [ bar_I], LabJ: [ bar_J], Fact: [1] →  OK
(11)退出系统
ANSYS Utility Menu：File → Exit → Save Everything → OK

(a)桥梁中部最大挠度值为0.003 374m          (b)桥梁中部轴力最大值为25 380N
图3.24桁架桥挠度UY以及单元轴力计算结果

!%%%%% [ANSYS算例]3.4.2(2) %%%%% begin %%%%%% 
!------注：命令流中的符号$，可将多行命令流写成一行------ 
/prep7                      !进入前处理 
/PLOPTS,DATE,0            !设置不显示日期和时间 
!=====设置单元和材料  
ET,1,BEAM3                !定义单元类型 
R,1,2.19E-3,3.83e-6, , , , ,     !定义1号实常数用于顶梁侧梁 
R,2,1.185E-3,1.87e-6,0,0,0,0,    !定义2号实常数用于弦杆 
R,3,3.031E-3,8.47E-6,0,0,0,0,  !定义3号实常数用于底梁 
MP,EX,1,2.1E11              !定义材料弹性模量 
MP,PRXY,1,0.30              !定义材料泊松比 
MP,DENS,1,,7800          !定义材料密度 
!-----定义几何关键点  
K,1,0,0,, $ K,2,4,0,, $ K,3,8,0,, $K,4,12,0,, $K,5,16,0,, $K,6,20,0,, $K,7,24,0,, $K,8,28,0,, $K,9,32,0,, $K,10,4,5.5,, 
$K,11,8,5.5,, $K,12,12,5.5,, $K,13,16,5.5,, $K,14,20,5.5,, $K,15,24,5.5,, $K,16,28,5.5,, 
!-----通过几何点生成桥底梁的线 
L,1,2 $L,2,3 $L,3,4 $L,4,5 $L,5,6 $L,6,7 $L,7,8 $L,8,9  
!------生成桥顶梁和侧梁的线 
L,9,16 $L,15,16 $L,14,15 $L,13,14 $L,12,13 $L,11,12 $L,10,11 $L,1,10  
!------生成桥身弦杆的线  
L,2,10 $L,3,10 $L,3,11 $L,4,11 $L,4,12 $L,4,13 $L,5,13 $L,6,13 $L,6,14 $L,6,15 $L,7,15 $L,7,16 $L,8,16  
!------选择桥顶梁和侧梁指定单元属性  
LSEL,S,,,9,16,1, 
LATT,1,1,1,,,,  
hhQÆRRN«•QQ 
wwwwww..bbzzffxxww..ccoomm QM•9NN•}

!-----选择桥身弦杆指定单元属性  
LSEL,S,,,17,29,1, 
LATT,1,2,1,,,, 
!-----选择桥底梁指定单元属性  
LSEL,S,,,1,8,1, 
LATT,1,3,1,,,, 
!------划分网格  
AllSEL,all                         !再恢复选择所有对象 
LESIZE,all,,,1,,,,,1                  !对所有对象进行单元划分前的分段设置  
LMESH,all                        !对所有几何线进行单元划分   
!=====在求解模块中，施加位移约束、外力，进行求解 
/solu 
NSEL,S,LOC,X,0                    !根据几何位置选择节点  
D,all,,,,,,ALL,,,,,                     !对所选择的节点施加位移约束 
AllSEL,all                          !再恢复选择所有对象  
NSEL,S,LOC,X,32                   !根据几何位置选择节点 
D,all,,,,,,,UY,,,,                       !对所选择的节点施加位移约束 
ALLSEL,all                         !再恢复选择所有对象   
!------基于几何关键点施加载荷 
FK,4,FY,-5000  $FK,6,FY,-5000  $FK,5,FY,-10000 
/replot                             !重画图形 
Allsel,all                           !选择所有信息(包括所有节点、单元和载荷等) 
solve                              !求解 
!=====进入一般的后处理模块  
/post1                             !后处理 
PLNSOL, U,Y, 0,1.0                  !显示Y方向位移 
PLNSOL, U,X, 0,1.0                 !显示X方向位移 
!------显示线单元轴力------ 
ETABLE,bar_I,SMISC, 1 
ETABLE,bar_J,SMISC, 1 
PLLS,BAR_I,BAR_J,0.5,1             !画出轴力图  
finish                              !结束 

你参考这个例题试一下