用ZEMAX的宏绘图语言在ZEMAX的2D-LAYOUT中增加序号显示功能.doc

用ZEMAX的宏绘图语言在ZEMAX的2D LAYOUT中增加序号显示功能；
ZEMAX的宏绘图功能还是比较强的。 效果图如下：

源程序也分享如下：　
! Purpose: layout the system, draw the lens by Y-Z Plane, add the surface/elements number to the graph
!          It just surpport the sysmetric system, other system maybe not correct!
! Author doffery 2010-3-27
numP = 51
nray = 11
NumS = NSUR()
WREF = PWAV()
FORMAT 12.5
! 准备图框
closewindow
graphics
gosub initilization
!画图部分，根据全局座标画出镜片的形状
for i,1,nsur(),1
   !画轮廓部分
   sd = sdia(i)
   incr = sd/((nump-1)/2)
   y_ = -sd
   x_ = glcz(i)+sagg(0,y_,i)
   gosub coordtr
   xs = xv
   ys = yv
   for j,0,nump-1,1
      y_=-sd+j*incr
      x_=glcz(i)+sagg(0,y_,i)
      gosub coordtr
      xe=xv
      ye=yv
      line xs,ys,xe,ye
      xs=xe
      ys=ye
   next
   !判断是否为玻璃面，如果是则同时画出倒角部分
   if (indx(i-1)>1.0001)
         y_=sdia(i)
         x_=glcz(i)+sagg(0,y_,i)
         gosub coordtr
         x1=xv
         y1=yv
         y_=sdia(i-1)
         x_=glcz(i-1)+sagg(0,y_,i-1)
         gosub coordtr
         x2=xv
         y2=yv
       if (sdia(i)>= sdia(i-1))
          line x1,y1,x2,y1
          line x2,y1,x2,y2
       else
             line x1,y1,x1,y2
             line x1,y2,x2,y2
       endif
         y_=-sdia(i)
         x_=glcz(i)+sagg(0,y_,i)
         gosub coordtr
         x1=xv
         y1=yv
         y_=-sdia(i-1)
         x_=glcz(i-1)+sagg(0,y_,i-1)
         gosub coordtr
         x2=xv
         y2=yv
       if (sdia(i)>= sdia(i-1))
          line x1,y1,x2,y1
          line x2,y1,x2,y2
       else
             line x1,y1,x1,y2
             line x1,y2,x2,y2
       endif
   endif
next
!画光线部分
!线条的颜色按视场
paraxial off
for i,1,nfld(),1
  color i
  ! 追迹光线，取得光线数据
  hy = fldy(i)/maxf()
  ! 共三条光线，主光线，上光线，下边线
  incr = 1/((nray-1)/2)
  for k,1,nray,1
    py = -1+incr*(k-1)
    RAYTRACE 0,hy,0,py,WREF
    gosub drawrays
  next  
next
for i,1,nsur(),1
   !画表面标签
   color 1
   snum = i
   gosub surflabel
next
! TOTR 文字
SETTEXTSIZE 70,40
getsystemdata 1
effl=vec1(7)
wfno=vec1(10)
pmag=vec1(16)
pimh=vec1(15)
totr=vec1(18)
expp=vec1(14)
enpp=vec1(12)
format 7.3
color 0
settextsize
gtext 0.02*xwidth,0.905*ywidth,0,"TOTAL AXIAL LENGTH:"+$str(totr)+" MM"
gtext 0.02*xwidth,0.932*ywidth,0,"EFFL:"+$str(effl)+" MM   PIMH:"+$str(pimh)+ " MM"
gtext 0.02*xwidth,0.959*ywidth,0,"WFNO:"+$str(wfno)+"      PMAG:"+$str(pmag)
graphics off
END
! Graphics
sub initilization
xmx = XMAX()
xmn = XMIN()
ymx = YMAX()
ymn = YMIN()
xwidth = xmx-xmn
ywidth = ymx-ymn
! 画图的范围
! 取得全局座标的参考位置
mnz=glcz(1)
maz=glcz(1)
mny=sdia(1)
may=sdia(1)
for i,1,nsur(),1
if (glcz(i)<mnz) then mnz=glcz(i)
if (glcz(i)>maz) then maz=glcz(i)
if (sdia(i)<mny) then mny=sdia(i)
if (sdia(i)>may) then may=sdia(i)
next
mny=-may
aspect=(maz-mnz)/(may-mny)   ! 系统的长宽比
print aspect/1.25
! 根据长宽比例定义绘图范围
if (ywidth*0.6*aspect < xwidth*0.8)
  xleft = xmn + (0.5*xwidth-0.6*ywidth*aspect/2)
  xrigh = xmn + (0.5*xwidth+0.6*ywidth*aspect/2)
  ytopp = ymn + (.1*ywidth)
  ybott = ymn + (.7*ywidth)
else
  xleft = xmn + (0.1*xwidth)
  xrigh = xmn + (0.9*xwidth)
  ytopp = ymn + (0.4*ywidth-0.8*xwidth/aspect/2)
  ybott = ymn + (0.4*ywidth+0.8*xwidth/aspect/2)
  !SETTEXTSIZE 70,40
endif
GTITLE "LAYOUT"
GLENSNAME
GDATE
return
sub coordtr
! 座标转换
xv = xleft+ (x_-mnz)/(maz-mnz)*(xrigh-xleft)
yv = ybott- (y_-mny)/(may-mny)*(ybott-ytopp)
return
sub drawrays
     x_=ragz(1)
     y_=ragy(1)
     gosub coordtr
     xs=xv
     ys=yv
     for jj,2,nsur(),1
        x_=ragz(jj)
        y_=ragy(jj)
        gosub coordtr
        xe=xv
        ye=yv
        line xs,ys,xe,ye
        xs=xe
        ys=ye
     next
return
sub surflabel
! 给定一个表面，画出一箭头+数字
! 箭头的顶点位置即是半口径所在的位置
y_= sdia(snum)
x_ = glcz(snum)+sagg(0,y_,snum)
if (indx(snum-1)>1.0001)
  if (sdia(snum-1)>sdia(snum))
   y_=sdia(snum-1)
   x_=glcz(snum)+sagg(0,sdia(snum),snum)
  else
     y_=sdia(snum)
     x_ = glcz(snum)+sagg(0,y_,snum)
    endif
endif
if (indx(snum)>1.0001)
  if (sdia(snum)<sdia(snum+1))
   y_=sdia(snum+1)
   x_=glcz(snum)+sagg(0,sdia(snum),snum)
  else
     y_=sdia(snum)
     x_ = glcz(snum)+sagg(0,y_,snum)
    endif
endif
gosub coordtr
xx=xv
yy=yv
! 画直线
linewidth = 0.04*ywidth
line xx,yy,xx,yy-linewidth
! 画小三角形
yy2 = yy-0.005*ywidth
xx2 = xx+0.003*ywidth
xx3 = xx-0.003*ywidth
yy3 = yy2
line xx,yy,xx2,yy2
line xx2,yy2,xx3,yy3
line xx3,yy3,xx,yy
! 画数字
mm = aspect/1.25
if (mm >= 2)
  settextsize 180, 80
else
  settextsize 90,40
endif
format .0
if (mm >=2)
  gtext xx+0.004*ywidth,yy-linewidth-0.003*ywidth,0,$str(snum)
else
    gtext xx+0.008*ywidth,yy-linewidth-0.003*ywidth,0,$str(snum)
endif
return