ANSYS用单元死活模拟浇铸过程中的温度分布.doc

用单元死活模拟浇铸过程中的温度分布
要想对浇铸过程的温度场进行分析,必须熟悉下面两个方面的内容：1.瞬态温度场的分析,2.单元死活的应用。
瞬态温度场分析：在进行瞬态温度分析时,我们常遇到的一个问题是温度结果明显不合理，:计算得到的温度高于给定的最高温度或低于给定的最低温度。造成这种结果的原因有两个：1、单元不合理，网格太大。2、时间积分方法不恰当。针对上述两个原因，我们采取的措施是：1、细划网格。2、选择向后积分法（THETA=1）。
单元死活：应用单元死活进行分析时,需要用到多个载荷步。在不同的载荷步之间单元的死活状态不同,ANSYS的通用动画生成工具生成的动画无法表现单元状态随时间的变化,因此必须使用ANSYS的DISPLAY Utility来生成能够表现单元死活状态的动画。
下面是一个简单的模拟浇铸过程的例子，环境温度为70，浇铸温度为600，计算结果应是：最低温度不低于70，最高温度不高于600。如果我们划分的网格不适当，则会出现最低温度低于70或最高温度高于600的情况，因此必须细划网格并选择THETA=1。计算完成后使用ANSYS的DISPLAY Utility来生成动画文件。

fini
/cle
/prep7

et,1,55 
et,2,55 
KXX , 1,1.99/3600
DENS,1,0.00073 
C ,1,0.100
KXX,2,7.38E-6 
DENS,2,9.35E-5 
c,2,1 

k,1,-.5,-.5 
k,4,6,-.5 
k,12
k,13,5.5
k,21,-.5,6 
k,22,,6 
k,23,5.5,6 
k,24,6,6
a,12,13,23,22 
a,1,12,22,21
a,1,4,13,12 
a,4,24,23,13
lsel,s,,,5,6
lsel,a,,,9,11,2
lesize,all,,,8 
lsel,all
lesize,all,,,20 
asel,s,,,1 
aatt,2,2,2 
asel,all
amesh,all 
fini
/solu 
antype,tran
!solc,on
timint,off
lsel,s,,,7,8
lsel,a,,,10
nsll,s 
sf,all,conv,100,70
alls
esel,s,type,,2 
nropt,full 
ekill,all 
alls
tunif,100
time,1
outres,all,all
solve

dtop=0
tim=1
delt=.05
timint,on
tintp,,,,1
*do,ii,1,20
ddele,all,temp
esel,s,type,,2
nsle,s 
tim=tim+delt
time,tim
dtop=dtop+.3
nsel,r,loc,y,0,dtop 
esln,s,1
ealive,all 
nsel,r,loc,y,dtop
esln,s
nsle,s,1
d,all,temp,600
esel,s,live
nall
eall
solve
*enddo

fini
/show,tmpplt,f33
/post1
dtop=0
*do,ii,2,21
set,ii
dtop=dtop+.3
nsel,r,loc,y,0,dtop
esln,s,1
esel,a,type,,1
nall 
plns,temp
*enddo
窗体顶部
窗体底部

在ANSYS5.6中如何施加函数变化的表面载荷
________________________________________
ANSYS5.7版本具有函数加载功能，可以很方便地在模型表面施加函数变化的各种载荷，在ANSYS5.6版本中，也可以通过变通的方式来实现此功能，其思路是：
首先选定所要施加函数变化表面载荷的表面上的节点，利用ANSYS的参数数组和嵌入函数知识写一简单的命令流，定义好相应节点位置的面载荷值，然后通过在节点上施加面载荷来完成。
下面以在一圆柱表面施加函数变化载荷为例：
/prep7
et,1,45
cyl4,,,0.5,,,,3
vsweep,all
asel,s,loc,y,0.01,1
nsla
!
*get,nmax,node,,num,max,
*get,nmin,node,,num,min,
*afun,deg
*dim,t1,array,nmax,1,1,
csys,1
*do,k,nmin,nmax
*if,nsel(k),eq,1,then
t1(k)=1000*sin(ny(k))
*else
t1(k)=0
*endif
*enddo
!
sffun,pres,t1(1)
sf,all,pres,0

在ANSYS中怎样给面施加一个非零的法向位移约束?
给面施加非零的法向位移约束的过程如下:
1) 在面上施加一个对称约束条件 (DA,2,SYMM)
2) 将实体模型上的载荷传递到有限元模型 (SBCTRAN)
3) 选择需要施加约束条件的面(ASEL,S,,,2)
4) 选择附在面上的节点 (NSLA,S,1)
5) 创建节点组元 (CM,AREA2_N,NODE)
6) 删除面上的对称约束条件 (DADELE,2,SYMM)
7) 删除节点上的零位移约束(DDELE,AREA2_N,UY)
8) 在节点组元上施加一个非零的法向位移约束(D,AREA2_N,UY,.05)
9) 图示节点验证约束是否正确 (NPLOT)

在任意面施加任意方向任意变化的压力
在某些特殊的应用场合，可能需要在结构件的某个面上施加某个坐标方向的随坐标位置变化的压力载荷，当然，这在一定程度上可以通过ANSYS表面效应单元实现。如果利用ANSYS的参数化设计语言，也可以非常完美地实现此功能，下面通过一个小例子描述此方法。

!!!
!!!在执行如下加载命令之前,请务必用选择命令asel将需要加载的几何面选择出来
!!!
finish
/prep7
et,500,shell63
press=100e6
amesh,all
esla,s
nsla,s,1
! 如果载荷的反向是一个特殊坐标系的方向,可在此建立局部坐标系,并将
! 所有节点坐标系旋转到局部坐标系下.
*get,enmax,elem,,num,max
dofsel,s,fx,fy,fz
fcum,add !!!将力的施加方式设置为"累加",而不是缺省的"替代"
*do,i,1,enmax
*if,esel(i),eq,1,then
*get,ae,elem,i,area !此命令用单元真实面积，如用投影面积，请用下几条命令
! *get,ae,elem,i,aproj,x !此命令用单元X投影面积，如用真实面积，请用上一条命令
! *get,ae,elem,i,aproj,y !此命令用单元Y投影面积
! *get,ae,elem,i,aproj,z !此命令用单元Z投影面积
xe=centrx(i) !单元中心X坐标(用于求解压力值)
ye=centry(i) !单元中心Y坐标(用于求解压力值)
ze=centrz(i) !单元中心Z坐标(用于求解压力值)
! 下面输入压力随坐标变化的公式,本例的压力随X和Y坐标线性变化.
p_e=(xe-10)*press+(ye-5)*press
f_tot=p_e*ae
esel,s,elem,,i
nsle,s,corner
*get,nn,node,,count
f_n=f_tot/nn
*do,j,1,nn
f,nelem(i,j),fx,f_n !压力的作用方向为X方向
! f,nelem(i,j),fy,f_n !压力的作用方向为Y方向
! f,nelem(i,j),fz,f_n !压力的作用方向为Z方向
*enddo
*endif
esla,s
*enddo
aclear,all
fcum,repl !!!将力的施加方式还原为缺省的"替代"
dofsel,all
allsel