消除季节和长期因素的ARIMA模型.doc

一、 作原始数据的散点图
程序如下：
data cj;
input x@@;y=dif12(x);
t=intnx('month','01jan2000'd,_n_-1);format t monyy.;
cards;
2962.9 2804.9 2626.6 2571.5 2636.9 2645.2 2596.9 2636.3
3136.9 3347.3 3107.8 3680 3332.8 3047.1 2876.1 2820.9
2929.6 2908.7 2851.4 2889.4 2854.3 3029.3 3421.7 4033.3
3324.4 3596.1 3114.8 3052.2 3202.1 3158.8 3096.6 3143.7
3422.4 3661.9 3733.1 4404.4 3907.4 3706.4 3494.8 3406.9
3463.3 3576.9 3562.1 3609.6 3971.8 4204.4 4202.7 4735.7
4569.4 4211.4 4049.8 4001.8 4166.1 4250.7 4209.2 4262.7
4717.7 4983.2 4965.6 5562.5 5300.9 5012.2 4799.1 4663.3
4899.2 4935 4934.9 5040.8 5495.2 5846.6 5909 6850.4
6641.6 6001.9 5796.7 5774.6 6175.6 6057.8 6012.2 6077.4
6553.6 6997.7 6821.7 7499.2 7488.3 7013.7 6685.8 6672.5
7157.5 7026 6998.2 7116.6 7668.4 8263 8104.7 9015.3
;
proc gplot;plot x*t;symbol i=join v=dot c=red;
run;

从图形可以看出，原始数据表现出一定的季节性及长期趋势性，显然是非平稳的时间序列，下面通过自相关函数进一步确定其非平稳性。添加程序：
proc arima;identify var=x nlag=12;

可以看到原始数据的自相关函数出现非常缓慢的衰减，所以该时间序列是非平稳的。下面分别通过差分对原始数据消除季节性因数及长期趋势影响。
二、 消除原始数据的季节因数和趋势性因数
先进行12步差分消除季节因素得到如下图形：

可见还有明显的长期趋势，且近似为线性的，故继续进行1阶差分消除长期趋势

由上述图形可以看出经过12步差分和一次差分后得到的时间序列基本平稳，我们通过自相关函数进一步检验其平稳性并分析应该用哪种模型进行拟合，添加程序：
proc arima;identify var=x(1,12) nlag=12;

分析数据的自相关函数和偏自相关函数，它们只是在12期的时候会再次超过两倍的标准差，除此之外都是在两倍的标准差内的，所以数据基本平稳；同时数据的白噪声检验显示在延迟6期情况下数据的相关性不是很大，但也不是纯随机的，故具有研究和分析的意义；因为其自相关函数和偏自相关函数是拖尾的，所以建立ARMA 模型。
三、 模型的拟合
修改程序为：
proc arima;identify var=x(1,12) nlag=12 minic p=(0:5) q=(0:5);

根据BIC越小模型越优的原则，因为BIC（4，2）=9.776887最小，所以建立ARMA（4,2）模型。
四、 对建立的模型进行参数估计和显著性检验
添加程序：
estimate p=4 q=2 method=cls;
得到如下结果：

从结果可以看出有些参数未通过显著性检验，故进行调整，修改程序为：
estimate p=(1,4) q=(1) method=cls;

从结果可以看出还有参数的显著性检验没通过，继续调整程序为：
estimate p=(1) q=(1) method=cls;

此时所有的参数都非常显著，故此时建立的模型是最精干的。该模型为：

即：

残差序列近似为白噪声序列，所以模型是适应的。
五、 利用模型进行预报
添加程序：
forecast lead=5 id=t out=caijing;
proc gplot data=caijing;
plot x*t=1 forecast*t=2 l95*t=3 u95*t=3/overlay;
symbol1 c=blue i=none v=star;
symbol2 c=red i=join v=none l=1 w=1;
symbol3 c=green i=join v=none l=2 w=2;
得到结果如下：

从上述图形可以看出，模型建立的比较适应，实际值都近似在拟合的曲线的上。