东方财富通指标说明.doc

东方财富通指标说明

东方财富通指标说明

一、技术指标 1
1、ADTM动态买卖气指标： 1
2、AMOUNT成交金额： 1
3、ASR浮筹比例： 1
4、ATR真实波幅： 2
5、BBI多空指标： 2
6、BBIBOLL BBIBOLL： 2
7、BIAS乖离率： 3
8、BIAS36三六乖离： 3
9、BIAS_QL乖离率-传统版: 3
10、BOLL布林线: 3
11、BOLL副图 布林线: 4
12、BRAR情绪指标： 4
13、BTX宝塔线(副图)： 4
14、CCI商品路径指标： 5
15、CHO济坚指数 5
16、CR带状能量线 6
17、CSI股票选择指标 6
18、CYD承接因子 6
19、CYF市场能量 7
20、CYQKL博弈K线长度 7
21、CYR市场强弱 7
22、CYS市场盈亏 8
23、CYW主力控盘 8
24、DKX多空线 8
25、DMA平均差 8
26、DMI趋向指标(标准) 9
27、DMI_QL趋向指标(钱龙) 9
28、DPO区间震荡线 10
29、DPTB大盘同步 10
30、EMV简易波动指标 10
31、ENE轨道线 11
32、EXPMA指数平均线 11
33、FSL分水岭 11
34、HSL换手率 11
35、KD随机指标 12
36、KDJ经典版KDJ 12
37、LON钱龙长线 12
38、LWR威廉指标 12
39、MA均线 13
40、MACD平滑异同平均 13
41、MASS梅斯线 14
42、MFI资金流量指标 14
43、MIKE麦克支撑压力 14
44、MTM动量线 15
45、NDB脑电波 15
46、NVI负成交量 15
47、OBV累积能量线 16
48、OSC变动速率线 16
49、PB市净率 16
50、PBX瀑布线 16
51、PSY心理线 17
52、PVI正成交量 17
53、RAD威力雷达 17
54、ROC变动率指标 17
55、RSI相对强弱指标 18
56、SAR抛物转向 18
57、SCR筹码集中度 18
58、SHO钱龙短线 18
59、SKDJ慢速随机指标 19
60、SLZT神龙在天 19
61、TAPI加权指数成交值 19
62、TJCJL太极成交量 20
63、TRIX三重指数平均线 20
64、UOS终极指标 21
65、VMACD量平滑异同平均 21
66、VOL成交量 21
67、VOLTV虚拟成交量 22
68、VPT量价趋势 22
69、VR成交量变异率 22
70、WAD威廉多空力度线 23
71、WR威廉指标 23
72、WVAD威廉变异离散量 23
73、XDT心电图 23
74、XS薛斯通道 24
75、ZLJC主力进出 25
76、ZLMM主力买卖 25

27

一、技术指标

1、ADTM动态买卖气指标：
DTM:=IF(OPEN<=REF(OPEN,1),0,MAX((HIGH-OPEN),(OPEN-REF(OPEN,1))));
DBM:=IF(OPEN>=REF(OPEN,1),0,MAX((OPEN-LOW),(OPEN-REF(OPEN,1))));
STM:=SUM(DTM,N);
SBM:=SUM(DBM,N);
ADTM:IF(STM>SBM,(STM-SBM)/STM,IF(STM=SBM,0,(STM-SBM)/SBM));
MAADTM:MA(ADTM,M);
1.该指标在+1到-1之间波动;
2.低于-0.5时为很好的买入点,高于+0.5时需注意风险.

2、AMOUNT成交金额：
AMO:AMOUNT,VOLSTICK;
MAAMO1:MA(AMO,M1);
MAAMO2:MA(AMO,M2);
MAAMO3:MA(AMO,M3);
1.成交金额大，代表交投热络，可界定为热门股；
2.底部起涨点出现大成交金额，代表攻击量；
3.头部地区出现大成交金额，代表出货量；
4.观察成交金额的变化，比观察成交手数更具意义，因为成交手数并未反应股价的涨跌的后所应支出的实际金额。

3、ASR浮筹比例：
ASR:(WINNER(C*1.1)-WINNER(C*0.9))/WINNER(HHV(H,0))*100;

4、ATR真实波幅：
MTR:MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
ATR:MA(MTR,N);
算法：今日振幅、今日最高与昨收差价、今日最低与昨收差价中的最大值，为真实波幅，求真实波幅的N日移动平均
参数：N　天数，一般取14

5、BBI多空指标：
BBI:(MA(CLOSE,M1)+MA(CLOSE,M2)+MA(CLOSE,M3)+MA(CLOSE,M4))/4;
1.股价位于BBI 上方，视为多头市场；
2.股价位于BBI 下方，视为空头市场。

6、BBIBOLL BBIBOLL：
CV:=CLOSE;
BBIBOLL:(MA(CV,3)+MA(CV,6)+MA(CV,12)+MA(CV,24))/4;
UPR:BBIBOLL+M*STD(BBIBOLL,N);
DWN:BBIBOLL-M*STD(BBIBOLL,N);
BBI算法：
3日平均价加6日平均价加12日平均价加24日平均价，其和除以四。
用法：
1.为BBI与BOLL的迭加；
2.高价区收盘价跌破BBI线，卖出信号；
3.低价区收盘价突破BBI线，买入信号；
4.BBI线向上，股价在BBI线之上，多头势强；
5.BBI线向下，股价在BBI线之下，空头势强。

7、BIAS乖离率：
BIAS1 :(CLOSE-MA(CLOSE,N1))/MA(CLOSE,N1)*100;
BIAS2 :(CLOSE-MA(CLOSE,N2))/MA(CLOSE,N2)*100;
BIAS3 :(CLOSE-MA(CLOSE,N3))/MA(CLOSE,N3)*100;
1.本指标的乖离极限值随个股不同而不同，使用者可利用参考线设定，固定其乖离范围；
2.当股价的正乖离扩大到一定极限时，股价会产生向下拉回的作用力；
3.当股价的负乖离扩大到一定极限时，股价会产生向上拉升的作用力；
4.本指标可设参考线。

8、BIAS36三六乖离：
BIAS36:MA(CLOSE,3)-MA(CLOSE,6);
BIAS612:MA(CLOSE,6)-MA(CLOSE,12);
MABIAS:MA(BIAS36,M);
1.本指标的乖离极限值随个股不同而不同，使用者可利用参考线设定，固定其乖离范围。※一般6-12BIAS信号的可靠度比3-6BIAS佳；
2.当股价的正乖离扩大到一定极限时，股价会产生向下拉回的作用力；
3.当股价的负乖离扩大到一定极限时，股价会产生向上拉升的作用力；
4.本指标可设参考线。

9、BIAS_QL乖离率-传统版:
BIAS :(CLOSE-MA(CLOSE,N))/MA(CLOSE,N)*100;
BIASMA :MA(BIAS,M);

10、BOLL布林线:
BOLL:MA(CLOSE,N);
UPPER:BOLL+M*STD(CLOSE,N);
LOWER:BOLL-M*STD(CLOSE,N);
1.股价上升穿越布林线上限时，回档机率大；
2.股价下跌穿越布林线下限时，反弹机率大；
3.布林线震动波带变窄时，表示变盘在即；
4.BOLL须配合BB 、WIDTH 使用；
5.开关参数若设为1，图形以四条线表示。

11、BOLL副图 布林线:
BOLL:MA(CLOSE,N);
UPPER:BOLL+M*STD(CLOSE,N);
LOWER:BOLL-M*STD(CLOSE,N);
DRAWKLINE(HIGH,OPEN,LOW,CLOSE);
1.股价上升穿越布林线上限时，回档机率大；
2.股价下跌穿越布林线下限时，反弹机率大；
3.布林线震动波带变窄时，表示变盘在即；
4.BOLL须配合BB 、WIDTH 使用；
5.开关参数若设为1，图形以四条线表示。

12、BRAR情绪指标：
BR:SUM(MAX(0,HIGH-REF(CLOSE,1)),N)/SUM(MAX(0,REF(CLOSE,1)-LOW),N)*100;
AR:SUM(HIGH-OPEN,N)/SUM(OPEN-LOW,N)*100;
1.BR>400，暗示行情过热，应反向卖出；BR<40 ，行情将起死回生，应买进；
2.AR>180，能量耗尽，应卖出；AR<40 ，能量已累积爆发力，应买进；
3.BR 由300 以上的高点下跌至50以下的水平,低于AR 时,为绝佳买点；
4.BR、AR、CR、VR 四者合为一组指标群，须综合搭配使用。

13、BTX宝塔线(副图)：
B1:=REF(C,1);
B2:=REF(C,2);
SS:=IF(C>REF(C,1) AND REF(C,1)>=REF(C,2),1,IF(C<REF(C,1) AND REF(C,1)<=REF(C,2),-1,IF(C>REF(C,2) AND REF(C,2)>REF(C,1),2,IF(C<REF(C,2) AND REF(C,2)<REF(C,1),-2,0))));
SM:=IF(REF(SS,1)<>0,REF(SS,1),IF(REF(SS,2)<>0,REF(SS,2),IF(REF(SS,3)<>0,REF(SS,3),IF(REF(SS,5)<>0,REF(SS,5),IF(REF(SS,6)<>0,REF(SS,6),IF(REF(SS,7)<>0,REF(SS,7),0))))));
mc:=IF(REF(SS,1)<>0,B2,IF(SM>0,MIN(B1,B2),MAX(B1,B2)));
TOW1:=IF(C>REF(C, 1), C,REF(C, 1));
tow2:=IF((SS=-1 OR SS=-2) AND SM>0, B2,TOW1);
TOWER:=IF(tow1>tow2,tow1,TOW2);
STICKLINE(SS=1 OR SM>=1 AND SS=0,B1,C,10,1),COLORRED;
STICKLINE(SS=-1 OR SM<=-1 AND SS=0,B1,C,10,0),COLORCYAN;
STICKLINE(SS=2,B2,C,10,1),COLORRED;
STICKLINE(SS=-2,B2,C,10,0),COLORCYAN;
STICKLINE((SS=-1 OR SS=-2) AND SM>0,B2,B1,10,1),COLORRED;
STICKLINE((SS=1 OR SS=2) AND SM<0,B2,B1,10,0),COLORCYAN;

14、CCI商品路径指标：
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:(TYP-MA(TYP,N))/(0.015*AVEDEV(TYP,N));
1.CCI 为正值时，视为多头市场；为负值时，视为空头市场；
2.常态行情时，CCI 波动于±100 的间；强势行情，CCI 会超出±100 ；
3.CCI>100 时，买进，直到CCI<100 时，卖出；
4.CCI<-100 时，放空，直到CCI>-100 时，回补。

15、CHO济坚指数
MID:=SUM(VOL*(2*CLOSE-HIGH-LOW)/(HIGH+LOW),0);
CHO:MA(MID,N1)-MA(MID,N2);
MACHO:MA(CHO,M);
1.CHO 曲线产生急促的「凸起」时，代表行情即将向上或向下反转；
2.股价>90 天平均线，CHO由负转正时，买进；
3.股价<90 天平均线，CHO由正转负时，卖出；
4.本指标也可设参考线，自定超买超卖的界限值；
5.本指标须配合OBOS、ENVELOPE同时使用。

16、CR带状能量线
MID:=REF(HIGH+LOW,1)/2;
CR:SUM(MAX(0,HIGH-MID),N)/SUM(MAX(0,MID-LOW),N)*100;
MA1:REF(MA(CR,M1),1+M1/2.5);
MA2:REF(MA(CR,M2),1+M2/2.5);
MA3:REF(MA(CR,M3),1+M3/2.5);
MA4:REF(MA(CR,M4),1+M4/2.5);
1.CR>400时，其10日平均线向下滑落，视为卖出信号；CR<40买进；
2.CR 由高点下滑至其四条平均线下方时，股价容易形成短期底部；
3.CR 由下往上连续突破其四条平均线时，为强势买进点；
4.CR 除了预测价格的外，最大的作用在于预测时间；
5.BR、AR、CR、VR 四者合为一组指标群，须综合搭配使用。

17、CSI股票选择指标
{钱龙版 CSI指标}
CSI:EMA(SMA(ABS(CLOSE-ma(c,n1)),2,1),2);
csi1:ema(csi,m1);

18、CYD承接因子
CYDS:WINNER(CLOSE)/(VOL/CAPITAL);
CYDN:WINNER(CLOSE)/MA(VOL/CAPITAL,N);
1.CYD称为承接因子指标，其市场含义是以今天的成交量承接所有获利盘需要的天数;
2.CYD可以反映市场上持股者的信心。 CYD大，说明以较小的成交量就可以维持较多的获利盘，说明市场上持股者的信心较强；反之CYD小，或者由于成交量大或者由于获利盘小，都反映了持股者信心不足;
3.可以用CYD来寻找市场大盘信心崩溃的点，当CYD极低时，说明市场投资人信心极低，市场信心崩溃，根据相反原理，此时就是大盘的底了，是中线炒底的机会。
4.可以用CYD寻找市场中个股信心最强的股票。如果在某一天CYD很大，显示这只股票的持股者信心特强，则这只股票很可能有强庄在其中，下面就有迅猛拉抬的可能。
5.股价在筹码密集区下方和密集区内,CYD越低越好,说明市场承接市场抛盘能力加大。
6.股价在筹码密集区的上方，尤其是已经进入拉升阶段，CYD越高越好，说明主力的获利盘没有散户承接，主力不能出货。如CYD突然走低，小心主力派发。
7.零号指数CYD如果低于5是绝对中线底部信号，大盘将在5天内见底反转。

19、CYF市场能量
CYF:100-100/(1+EXPMA(100*VOL/CAPITAL,N));
1.CYF反映了市场公众的状态和追涨热情,又称市场能量指标;
2.使用CYF判断股票的活跃程度, CYF小于10的股票是冷门股，CYF在20到40之间是活跃股，CYF大于50是热门股;
3.CYF与股价顶背离时,易形成反转.

20、CYQKL博弈K线长度
KL:100*(WINNER(CLOSE)-WINNER(OPEN));

21、CYR市场强弱
DIVE:=0.01*EXPMA(AMOUNT,N)/EXPMA(VOL,N);
CYR:(DIVE/REF(DIVE,1)-1)*100;
MACYR:MA(CYR,M);
1.CYR是成本均线派生出的指标,是13日成本均线的升降幅度;
2.使用CYR可以对股票的强弱进行排序,找出其中的强势和弱势股票。

22、CYS市场盈亏
CYC13:=0.01*EXPMA(AMOUNT,13)/EXPMA(VOL,13);
CYS:(CLOSE-CYC13)/CYC13*100;

23、CYW主力控盘
VAR1:=CLOSE-LOW;
VAR2:=HIGH-LOW;
VAR3:=CLOSE-HIGH;
VAR4:=IF(CLOSE>=0,(VAR1/VAR2+VAR3/VAR2)*VOL,(VAR3/VAR2+VAR1/VAR2)*VOL);
CYW: SUM(VAR4,10)/10000, COLORSTICK;

24、DKX多空线
MID:=(3*CLOSE+LOW+OPEN+HIGH)/6;
DKX:(20*MID+19*REF(MID,1)+18*REF(MID,2)+17*REF(MID,3)+
16*REF(MID,4)+15*REF(MID,5)+14*REF(MID,6)+
13*REF(MID,7)+12*REF(MID,8)+11*REF(MID,9)+
10*REF(MID,10)+9*REF(MID,11)+8*REF(MID,12)+
7*REF(MID,13)+6*REF(MID,14)+5*REF(MID,15)+
4*REF(MID,16)+3*REF(MID,17)+2*REF(MID,18)+REF(MID,20))/210;
MADKX:MA(DKX,M);
1、当多空线上穿其均线时为买入信号;
2、当多空线下穿其均线时为卖出信号。

25、DMA平均差
DIF:MA(CLOSE,N1)-MA(CLOSE,N2);
AMA:MA(DIF,M);
1.DMA 向上交叉其平均线时，买进；
2.DMA 向下交叉其平均线时，卖出；
3.DMA 的交叉信号比MACD、TRIX 略快；
4.DMA 与股价产生背离时的交叉信号，可信度较高；
5.DMA、MACD、TRIX 三者构成一组指标群，互相验证。

26、DMI趋向指标(标准)
MTR:= SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),N);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SUM(IF(HD>0 AND HD>LD,HD,0),N);
DMM:= SUM(IF(LD>0 AND LD>HD,LD,0),N);
PDI: DMP*100/MTR;
MDI: DMM*100/MTR;
ADX: MA(ABS(MDI-PDI)/(MDI+PDI)*100,M);
ADXR:(ADX+REF(ADX,M))/2;
(标准算法)
用法：市场行情趋向明显时，指标效果理想。
PDI(上升方向线) MDI(下降方向线) ADX(趋向平均值)
1.PDI线从下向上突破MDI线，显示有新多头进场，为买进信号；
2.PDI线从上向下跌破MDI线，显示有新空头进场，为卖出信号；
3.ADX值持续高于前一日时，市场行情将维持原趋势；
4.ADX值递减，降到20以下，且横向行进时，市场气氛为盘整；
5.ADX值从上升倾向转为下降时，表明行情即将反转。

27、DMI_QL趋向指标(钱龙)
MTR := SMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),N,1);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SMA(IF(HD>0 AND HD>LD,HD,0),N,1);
DMM:= SMA(IF(LD>0 AND LD>HD,LD,0),N,1);
PDI: DMP*100/MTR;
MDI: DMM*100/MTR;
ADX: SMA(ABS(MDI-PDI)/(MDI+PDI)*100,N,1);
ADXR:(ADX+REF(ADX,M))/2;
钱龙算法)
用法：市场行情趋向明显时，指标效果理想。
PDI(上升方向线) MDI(下降方向线) ADX(趋向平均值)
1.PDI线从下向上突破MDI线，显示有新多头进场，为买进信号；
2.PDI线从上向下跌破MDI线，显示有新空头进场，为卖出信号；
3.ADX值持续高于前一日时，市场行情将维持原趋势；
4.ADX值递减，降到20以下，且横向行进时，市场气氛为盘整；
5.ADX值从上升倾向转为下降时，表明行情即将反转。

28、DPO区间震荡线
1.DOP>0 ，表示目前处于多头市场；DOP<0 ，表示目前处于空头市场；
2.在0 轴上方设定一条超买线，当股价波动至超买线时，会形成短期高点；
3.在0 轴下方设定一条超卖线，当股价波动至超卖线时，会形成短期低点；
4.超买超卖的范围随个股不同而不同，使用者应自行调整；
5.本指标可设参考线。

29、DPTB大盘同步
100*COUNT((CLOSE>OPEN AND INDEXC>INDEXO) OR (CLOSE<OPEN AND INDEXC<INDEXO),N)/N;
个股与大盘的同步系数。指标值越高反映出该股随大盘波动，大于75为散户股；指标值越低反映出该股走出独立行情，小于50为庄股可能性较高。同时应结合个股具体走势进行研判。
30、EMV简易波动指标
VOLUME:=MA(VOL,N)/VOL;
MID:=100*(HIGH+LOW-REF(HIGH+LOW,1))/(HIGH+LOW);
EMV:MA(MID*VOLUME*(HIGH-LOW)/MA(HIGH-LOW,N),N);
MAEMV:MA(EMV,M);
1.EMV 由下往上穿越0 轴时，视为中期买进信号；
2.EMV 由上往下穿越0 轴时，视为中期卖出信号；
3.EMV 的平均线穿越0 轴，产生假信号的机会较少；
4.当ADX 低于±DI时，本指标失去效用；
5.须长期使用EMV 指标才能获得最佳利润。

31、ENE轨道线
UPPER:(1+M1/100)*MA(CLOSE,N);
LOWER:(1-M2/100)*MA(CLOSE,N);
ENE:(UPPER+LOWER)/2;

32、EXPMA指数平均线
EXP1:EXPMA(CLOSE,M1);
EXP2:EXPMA(CLOSE,M2);
1.EXPMA 一般以观察12日和50日二条均线为主；
2.12日指数平均线向上交叉50日指数平均线时，买进；
3.12日指数平均线向下交叉50日指数平均线时，卖出；
4.EXPMA 是多种平均线计算方法的一；
5.EXPMA 配合MTM 指标使用，效果更佳。

33、FSL分水岭
SWL:(EXPMA(CLOSE,5)*7+EXPMA(CLOSE,10)*3)/10;
SWS:DMA(EMA(CLOSE,12),MAX(1,100*(SUM(VOL,5)/(3*CAPITAL))));
股价在分水岭之上为强势,反之为弱势.
34、HSL换手率
HSL:100*VOL/CAPITAL;
MA1:MA(HSL,M1);
MA2:MA(HSL,M2);
换手线是根据换手率绘制的曲线，使对于成交量的研判不受股本变动的影响，更增加了成交量具有可比性。

35、KD随机指标
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);

36、KDJ经典版KDJ
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D;
1.指标>80 时，回档机率大；指标<20时，反弹机率大；
2.K在20左右向上交叉D时，视为买进信号；
3.K在80左右向下交叉D时，视为卖出信号；
4.J>100 时，股价易反转下跌；J<0 时，股价易反转上涨；
5.KDJ 波动于50左右的任何信号，其作用不大。

37、LON钱龙长线
LC := REF(CLOSE,1);
VID := SUM(VOL,2)/(((HHV(HIGH,2)-LLV(LOW,2)))*100);
RC := (CLOSE-LC)*VID;
LONG := SUM(RC,0);
DIFF := SMA(LONG,10,1);
DEA := SMA(LONG,20,1);
LON : DIFF-DEA;
LONMA : MA(LON,10);
LONT : LON, COLORSTICK;

38、LWR威廉指标
RSV:= (HHV(HIGH,N)-CLOSE)/(HHV(HIGH,N)-LLV(LOW,N))*100;
LWR1:SMA(RSV,M1,1);
LWR2:SMA(LWR1,M2,1);

39、MA均线
MA1:ma(CLOSE, M1);
MA2:ma(CLOSE, M2);
MA3:ma(CLOSE, M3);
MA4:ma(CLOSE, M4);
MA5:ma(CLOSE, M5);
MA6:ma(CLOSE, M6);
MA7:ma(CLOSE, M7);
MA8:ma(CLOSE, M8);
MA9:ma(CLOSE, M9);
MA10:ma(CLOSE,M10);
1.股价高于平均线，视为强势；股价低于平均线，视为弱势
2.平均线向上涨升，具有助涨力道；平均线向下跌降，具有助跌力道；
3.二条以上平均线向上交叉时，买进；
4.二条以上平均线向下交叉时，卖出；
5.移动平均线的信号经常落后股价，若以EXPMA 、VMA 辅助，可以改善。

40、MACD平滑异同平均
DIF:EMA(CLOSE,SHORT)-EMA(CLOSE,LONG);
DEA:EMA(DIF,MID);
MACD:(DIF-DEA)*2,COLORSTICK;
DIFF线　收盘价短期、长期指数平滑移动平均线间的差
DEA线　 DIFF线的M日指数平滑移动平均线
MACD线　DIFF线与DEA线的差，彩色柱状线
参数：SHORT(短期)、LONG(长期)、M 天数，一般为12、26、9
用法：
1.DIFF、DEA均为正，DIFF向上突破DEA，买入信号。
2.DIFF、DEA均为负，DIFF向下跌破DEA，卖出信号。
3.DEA线与K线发生背离，行情反转信号。
4.分析MACD柱状线，由红变绿(正变负)，卖出信号；由绿变红，买入信号

41、MASS梅斯线
MASS:SUM(MA(HIGH-LOW,N1)/MA(MA(HIGH-LOW,N1),N1),N2);
MAMASS:MA(MASS,M);
1.MASS>27 后，随后又跌破26.5，此时股价若呈上涨状态，则卖出；
2.MASS<27 后，随后又跌破26.5，此时股价若呈下跌状态，则买进；
3.MASS<20 的行情，不宜进行投资。

42、MFI资金流量指标
TYP := (HIGH + LOW + CLOSE)/3;
V1:=SUM(IF(TYP>REF(TYP,1),TYP*VOL,0),N)/SUM(IF(TYP<REF(TYP,1),TYP*VOL,0),N);
MFI:100-(100/(1+V1));
1.MFI>80 为超买，当其回头向下跌破80 时，为短线卖出时机；
2.MFI<20 为超卖，当其回头向上突破20 时，为短线买进时机；
3.MFI>80，而产生背离现象时，视为卖出信号；
4.MFI<20，而产生背离现象时，视为买进信号。
43、MIKE麦克支撑压力
HLC:=REF(MA((HIGH+LOW+CLOSE)/3,N),1);
HV:=EMA(HHV(HIGH,N),3);
LV:=EMA(LLV(LOW,N),3);
STOR:EMA(2*HV-LV,3);
MIDR:EMA(HLC+HV-LV,3);
WEKR:EMA(HLC*2-LV,3);
WEKS:EMA(HLC*2-HV,3);
MIDS:EMA(HLC-HV+LV,3);
STOS:EMA(2*LV-HV,3);
1.MIKE指标共有六条曲线，上方三条压力线，下方三条支撑线；
2.当股价往压力线方向涨升时，其下方支撑线不具参考价值；
3.当股价往支撑线方向下跌时，其上方压力线不具参考价值；

44、MTM动量线
MTM:CLOSE-REF(CLOSE,N);
MAMTM:MA(MTM,M);
MTM线　:当日收盘价与N日前的收盘价的差；
MTMMA线:对上面的差值求N日移动平均；
参数：N 间隔天数，也是求移动平均的天数，一般取6
用法：
1.MTM从下向上突破MTMMA，买入信号；
2.MTM从上向下跌破MTMMA，卖出信号；
3.股价续创新高，而MTM未配合上升，意味上涨动力减弱；
4.股价续创新低，而MTM未配合下降，意味下跌动力减弱；
5.股价与MTM在低位同步上升，将有反弹行情；反之，从高位同步下降，将有回落走势。

45、NDB脑电波
HH:=IF(C/REF(C,1)>1.098AND >REF(H,1),2*C-REF(C,1)-H,2*C-H-L);
V1:=BARSCOUNT(C)-1;
V2:=2*REF(C,V1)-REF(H,V1)-REF(L,V1);
DK:SUM(HH,0)+V2;
MDK5:MA(DK,P1);
MDK10:MA(DK,P2);

46、NVI负成交量
NVI:100*MULAR(if(v<ref(v,1),c/ref(c,1),1),0);
MANVI:MA(NVI,N);
.观察NVI 时，必须先设定一条平均线才能研判；
2.NVI 主要是追踪大户资金流向的指标；
3.NVI 向上穿越其平均线时，买进；
4.NVI 向下穿越其平均线时，卖出；
5.NVI 须配合PVI 同时使用。

47、OBV累积能量线
VA:=IF(CLOSE>REF(CLOSE,1),VOL,-VOL);
OBV:SUM(IF(CLOSE=REF(CLOSE,1),0,VA),0);
MAOBV:MA(OBV,M);
1.股价一顶比一顶高，而OBV 一顶比一顶低，暗示头部即将形成；
2.股价一底比一底低，而OBV 一底比一底高，暗示底部即将形成；
3.OBV 突破其Ｎ字形波动的高点次数达5 次时，为短线卖点；
4.OBV 跌破其Ｎ字形波动的低点次数达5 次时，为短线买点；
5.OBV 与ADVOL、PVT、WAD、ADL同属一组指标群，使用时应综合研判。

48、OSC变动速率线
OSC:100*(CLOSE-MA(CLOSE,N));
MAOSC:EXPMEMA(OSC,M);
1.OSC 以100 为中轴线，OSC>100 为多头市场；OSC<100 为空头市场；
2.OSC 向上交叉其平均线时，买进；OSC 向下交叉其平均线时卖出；
3.OSC 在高水平或低水平与股价产生背离时，应注意股价随时有反转的可能；
4.OSC 的超买超卖界限值随个股不同而不同，使用者应自行调整

49、PB市净率
PB:CONST(C)/FINANCE(34);

50、PBX瀑布线
PBX1:(EXPMA(CLOSE,M1)+MA(CLOSE,M1*2)+MA(CLOSE,M1*4))/3;
PBX2:(EXPMA(CLOSE,M2)+MA(CLOSE,M2*2)+MA(CLOSE,M2*4))/3;
PBX3:(EXPMA(CLOSE,M3)+MA(CLOSE,M3*2)+MA(CLOSE,M3*4))/3;
PBX4:(EXPMA(CLOSE,M4)+MA(CLOSE,M4*2)+MA(CLOSE,M4*4))/3;
PBX5:(EXPMA(CLOSE,M5)+MA(CLOSE,M5*2)+MA(CLOSE,M5*4))/3;
PBX6:(EXPMA(CLOSE,M6)+MA(CLOSE,M6*2)+MA(CLOSE,M6*4))/3;
1.股价上升穿越轨道线上限时，回档机率大；
2.股价下跌穿越轨道线下限时，反弹机率大；
3.股价波动于轨道线内时，代表常态行情，此时，超买超卖指标可发挥效用；
4.股价波动于轨道线外时，代表脱轨行情，此时，应使用趋势型指标。

51、PSY心理线
PSY:COUNT(CLOSE>REF(CLOSE,1),N)/N*100;
PSYMA:MA(PSY,M);
1.PSY>75，形成Ｍ头时，股价容易遭遇压力；
2.PSY<25，形成Ｗ底时，股价容易获得支撑；
3.PSY 与VR 指标属一组指标群，须互相搭配使用。
52、PVI正成交量
NVI:100*MULAR(if(v>ref(v,1),c/ref(c,1),1),0);
MANVI:MA(NVI,N);
1.观察PVI 时，必须先设定一条平均线才能研判；
2.PVI 主要是追踪散户资金流向的指标；
3.PVI 向上穿越其平均线时，买进；
4.PVI 向下穿越其平均线时，卖出；
5.PVI 须配合NVI 同时使用。

53、RAD威力雷达
SM:=(OPEN+HIGH+CLOSE+LOW)/4;
SMID:=MA(SM,D);
IM:=(INDEXO+INDEXH+INDEXL+INDEXC)/4;
IMID:=MA(IM,D);
SI1:=(SMID-REF(SMID,1))/SMID;
II:=(IMID-REF(IMID,1))/IMID;
RADER1:SUM((SI1-II)*2,S)*1000;
RADERMA:SMA(RADER1,M,1);

54、ROC变动率指标
ROC:100*(CLOSE-REF(CLOSE,N))/REF(CLOSE,N);
MAROC:MA(ROC,M);
1.本指标的超买超卖界限值随个股不同而不同，使用者应自行调整；
2.本指标的超买超卖范围，一般介于±6.5之间；
3.本指标用法请参考MTM 指标用法；
4.本指标可设参考线。

55、RSI相对强弱指标
LC:=REF(CLOSE,1);
RSI1:SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*100;
RSI2:SMA(MAX(CLOSE-LC,0),N2,1)/SMA(ABS(CLOSE-LC),N2,1)*100;
RSI3:SMA(MAX(CLOSE-LC,0),N3,1)/SMA(ABS(CLOSE-LC),N3,1)*100;
1.RSI>80 为超买，RSI<20 为超卖；
2.RSI 以50为中界线，大于50视为多头行情，小于50视为空头行情；
3.RSI 在80以上形成Ｍ头或头肩顶形态时，视为向下反转信号；
4.RSI 在20以下形成Ｗ底或头肩底形态时，视为向上反转信号；
5.RSI 向上突破其高点连线时，买进；RSI 向下跌破其低点连线时，卖出。

56、SAR抛物转向
SAR(P,STEP,MAXP),CIRCLEDOT;

57、SCR筹码集中度
A:=P1+(100-P1)/2;
B:=(100-P1)/2;
CC:=COST(A);
DD:=COST(B);
SCR:(CC-DD)/(CC+DD)*100/2;

58、SHO钱龙短线
VAR1:=MA((VOL-REF(VOL,1))/R