ansys土木工程应用实例.doc

第三章
回弹
/units,si
/prep7
et,1,plane42
keyopt,1,3,2
mp,ex,1,220e9
mp,nuxy,1,0.3
TB,MISO,1,1,25,
TBTEMP,0
TBPT,,0.000814,175.88e6,
TBPT,,0.001531,324.98e6,
TBPT,,0.002819,591.26e6,
TBPT,,0.003846,801.457e6,
TBPT,,0.004239,873.22e6,
TBPT,,0.004594,924.399e6,
TBPT,,0.004955,956.88e6,
TBPT,,0.00531,976.99e6,
TBPT,,0.005699,990.2138e6,
TBPT,,0.006261,1000e6,
TBPT,,0.006957,1008.34e6,
TBPT,,0.007804,1015.5e6,
TBPT,,0.008779,1021.185e6,
TBPT,,0.009827,1026.47e6,
TBPT,,0.010929,1031.289e6,
TBPT,,0.012066,1035.444e6,
TBPT,,0.0132,1039.693e6,
TBPT,,0.014354,1044.886e6,
TBPT,,0.015494,1049.796e6,
TBPT,,0.016631,1053.951e6,
TBPT,,0.017785,1058.106e6,
TBPT,,0.019039,1062.827e6,
TBPT,,0.020276,1067.643e6,
csys,1
k,1,0.00512
k,2,0.0064
kgen,36,1,2,1,,10
*do,j,1,69,2
a,j,j+1,j+3,j+2
*enddo
a,71,72,2,1
save
lesize,all,,,4
amesh,all
nummrg,all
numcmp,all
save
cp,1,uy,166,170,171,172,173
finish
/solu
nsel,s,loc,y,270
d,all,all
nplot
allsel
nplot
nsel,s,loc,y,90
d,all,ux
nplot
allsel
outres,all,all
time,1
NSUBST,100
nlgeom,on
d,166,uy,-0.00128
solve
*get,def1,node,166,U,Y
nsel,s,loc,y,90
ddele,all,uy
allsel
f,166,fy,0
solve
*get,def2,node,166,U,Y
finish
/post1 !进入后处理器
set,list !显示所有计算的结果
set,1,last,1 !读取第一个加载步最后子步的结果
pldisp,1 !同时显示变形前与变形后结构的形状。
plnsol,s,eqv,1,1 !显示节点的等效应力
set,2,last,1 !读取第二个加载步最后子步的结果
pldisp,1 !同时显示变形前与变形后结构的形状。
plnsol,s,eqv,1,1 !显示节点的等效应力
自适应划分
/PREP7
SMRT,OFF
ANTYPE,STATIC
ET,1,PLANE42,,,3 ! 定义平面应力单元有单元厚度
MP,EX,1,210E9 ! 定义材料属性
MP,NUXY,1,.3
R,1,0.1 ! 给定厚度
LOCAL,11,1,,,,,,,0.5 ! 定义区域坐标系统为圆柱坐标系，Y轴是X的0.5倍。
K,1,2,90
K,2,2,0
L,1,2
LOCAL,12,1,,,,,,,0.8461585 ! 定义区域坐标系统为圆柱坐标系，Y轴是X的0.846倍。
K,3,3.25,90
K,4,3.25,0.0
L,3,4
CSYS,0 !回到卡式坐标系下。
L,2,4
L,1,3
AL,2,4,1,3 ! 创建面积
DL,4,1,SYMM ! 创建对称面约束
DL,3,1,SYMM
SFL,2,PRES,-10E6 ! 定义线上的分布载荷
MSHK,2 ! 混合网格划分
MSHA,0,2D ! 四边形网格
SAVE ! 备份数据库
FINISH
ADAPT,7,7,,,1 ! 求解次数为nsoln=4次，能量误差百分比stargt=7,单元尺寸改变最大比例因子facmx=1
/POST1
EPLOT ! 绘制单元
PRERR ! 打印能量误差百分比
NSEL,S,LOC,Y,0.0
NSEL,R,LOC,X,2.0
*GET,MNODE,NODE,,NUM,MAX
*GET,SY_D,NODE,MNODE,S,Y ! GET DESIRED STRESS SY VALUE
NSEL,ALL
ESEL,ALL
FINISH
第四章
钢筋混凝土板
!在四个角点增加钢性垫片，在中心点处直接施加-2mm，压碎关闭计算完毕
/clear,nostart
/config,nres,5000
/prep7
!定义单元类型
et,1,solid65 !混凝土单元
et,2,solid45
keyopt,1,6,3
keyopt,1,5,1
*afun,deg
R,1,2,0.01,90,0,2,0.01,0,0 !整体模型，实常数
!定义材料属性
mp,ex,1,24000 !混凝土材料属性
mp,prxy,1,0.2
tb,conc,1,1,9
tbdata,,0.35,1,3.1125,-1
mp,ex,2,2e5 !纵向受拉钢筋，钢支座材料属性
mp,prxy,2,0.25
tb,bkin,2,1,2,1
tbdata,,360,20000
blc4,,,1000,1000,100
blc4,,,100,100,-50
wpoff,1000,0,0
blc4,,,-100,100,-50
wpoff,0,1000,0
blc4,,,-100,-100,-50
wpoff,-1000,0,0
blc4,,,100,-100,-50
/view,1,1,1,1
/ANG,1,240,ZS,1
/replot
/REP,FAST
lsel,s,loc,z,50
lesize,all,,,2
lsel,all
lsel,s,loc,x,500
lesize,all,,,20
lsel,all
lsel,s,loc,y,500
lesize,all,,,20
vsel,s,loc,z,50
vmesh,all
type,2
mat,2
lsel,s,loc,z,-25
lesize,all,,,1
lsel,all
lsel,s,loc,z,-50
lesize,all,,,2
vsel,s,loc,z,-25
vmesh,all
nummrg,all
numcmp,all
fini
/solu
asel,s,loc,z,-50
da,all,all
nsel,all
nsel,s,loc,z,100
nsel,r,loc,y,500
nsel,r,loc,x,500
d,all,uz,-2
nlgeom,on
NSUBST,100
OUTRES,ALL,ALL
NEQIT,40
pred,on
CNVTOL,F, ,0.05,2
allsel
SOLVE
fini
/post1
PLNSOL,U,z,0,1
Esel,s,type,,1
PLNSOL,S,1,0,1 !画第一主应力
ETABLE,rebar_1,NMISC,43 !获取rebar1平均等效应力
PLETAB,REBAR_1,AVG
ETABLE,rebar_2,NMISC,47 !获取rebar2平均等效应力
PLETAB,REBAR_2,AVG
etable,seqv_i,nmisc,5 !获取solid单元i节点的平均等效应力
PLETAB,seqv_i,AVG
ETABLE,11,NMISC,53 !获取第一个积分点的状态
ETABLE,22,NMISC,60 !获取第二个积分点的状态
ETABLE,33,NMISC,67 !获取第三个积分点的状态
ETABLE,44,NMISC,74 !获取第四个积分点的状态
ETABLE,55,NMISC,81 !获取第五个积分点的状态
ETABLE,66,NMISC,88 !获取第六个积分点的状态
ETABLE,77,NMISC,95 !获取第七个积分点的状态
ETABLE,88,NMISC,102 !获取第八个积分点的状态
PLETAB,11,AVG
PLETAB,22,AVG
PLETAB,33,NOAV
PLETAB,44,AVG
PLETAB,55,NOAV
/DEVICE,VECTOR,1
PLCRACK,0,0 !显示所有开裂位置
PLCRACK,0,1 !显示第一开裂位置

钢筋混凝土梁
!采用均匀网格划分，同时取消两种垫片,DMX=6.415,最大第一主应力263.629，28个子部计算完毕
/clear,nostart
/config,nres,5000
/prep7
!定义单元类型
et,1,solid65 !混凝土单元
et,2,pipe20 !钢筋单元
et,3,plane42 !用于拉伸成体单元之用
!定义实常数
r,1,18,8.99 !纵向受拉钢筋实常数
r,2,8,3.99 !纵向受压钢筋，箍筋实常数
r,3 !混凝土
!定义材料属性
mp,ex,1,24000 !混凝土材料属性
mp,prxy,1,0.2
tb,conc,1,1,9
tbdata,,0.4,1,3,-1
mp,ex,2,2e5 !纵向受拉钢筋
mp,prxy,2,0.3
tb,bkin,2,1,2,1
tbdata,,350
mp,ex,3,2e5 !横向箍筋，受压钢筋材料属性
mp,prxy,3,0.25
tb,bkin,3,1,2,1
tbdata,,200
/pnum,node,1
/pnum,elem,1
!!产生所有的节点**********!!!
n,1
n,9,150
fill,1,9
ngen,11,9,1,9,1,,30
ngen,19,1000,1,99,1,,,-75
/view,1,1,1,1
!!!!!!!箍筋，受压钢筋*******!!!!
type,2
real,2
mat,3
!水平箍筋
*do,ii,11,16,1
e,ii,ii+1
*enddo
*do,ii,83,88,1
e,ii,ii+1
*enddo
!竖直箍筋
*do,ii,11,74,9
e,ii,ii+9
*enddo
*do,ii,17,80,9
e,ii,ii+9
*enddo
!产生整个模型的箍筋
egen,19,1000,1,28,1
!此时最大的单元编号为532
!纵向受压钢筋
*do,ii,83,17083,1000
e,ii,ii+1000
*enddo
*do,ii,89,17089,1000
e,ii,ii+1000
*enddo
!!!!!纵向受拉钢筋************!!!!!!!!!!
type,2
real,1
mat,2
*do,ii,11,17011,1000
e,ii,ii+1000
*enddo
*do,ii,17,17017,1000
e,ii,ii+1000
*enddo
!此时最大单元编号为604
/view,1,1,1,1
/pnum,elem,0
/pnum,node,0
/eshape,1
eplot
!!!**********生成面单元，以便拉伸成体单元!!!!!!
k,1
k,2,150,
k,3,150,300
k,4,,300
a,1,2,3,4
lsel,s,loc,y,0
lsel,a,loc,y,300
lesize,all,,,8
lsel,all
lsel,s,loc,x,0
lsel,a,loc,x,150
lesize,all,,,10
type,3
amesh,all
type,1 !拉伸成混凝土单元
real,3
mat,1
extopt,esize,18
extopt,aclear,1
vext,all,,,,,-1350
/pnum,mat,1
/pnum,node,0
/pnum,elem,0
/view,1,1,1,1
eplot
allsel
nummrg,all
numcmp,all
eplot
/solu
nsel,s,loc,y,-0 !右边界约束
nsel,r,loc,z,-1275
d,all,uy
d,all,ux
asel,s,loc,z,0 !对称面约束
da,all,symm
nsel,all !施加外部载荷
nsel,s,loc,y,300
nsel,r,loc,z,-600
d,all,uy,-5
allsel
gplot
nlgeom,on
NSUBST,200
OUTRES,ALL,ALL
NEQIT,50
pred,on
CNVTOL,F, ,0.05,2,0.5
allsel
SOLVE
FINISH
/post1
allsel
/DEVICE,VECTOR,1
PLCRACK,0,1 !显示第一开裂位置
PLCRACK,0,2 !显示第二开裂位置
!/DEVICE,VECTOR,0
!PLNSOL,U,Y,0,1
!ESEL,S,TYPE,,2
!PLNSOL,S,1,0,1
预应力钢筋混凝土
/PREP7
ET,1,LINK8
ET,2,SOLID65
ET,3,PLANE42
R,1,6126
MP,EX,1,2e5
MP,PRXY,1,0.3
MP,ALPX,1,2e-5
MP,EX,2,3.354e
MP,PRXY,2,0.2
BLC4, , ,780,210
BLC4,275,210,230,1690
BLC4,-570,1900,1920,200
wpoff,390,191
wprot,0,90
ASBW,1
wprot,0,0,90
ASBW,4
ASBW,5
/PNUM,AREA,1
/PNUM,LINE,1
gplot
aglue,all
nummrg,all
numcmp,all
SAVE
lesize,8,,,20
lesize,21,,,8
lesize,22,,,8
lesize,5,,,4
lesize,9,,,2
lesize,7,,,2
lsel,s,,,21,22,1
lsel,a,,,5
LCCAT,all
allsel
amesh,6
LSEL,s,LCCA
lDELE,all
allsel
lesize,4,,,20
lesize,6,,,20
lesize,18,,,2
lesize,19,,,2
lsel,s,,,18,19,1
LCCAT,all
allsel
amesh,4
LSEL,s,LCCA
lDELE,all
allsel
lesize,2,,,6
lesize,3,,,8
lesize,14,,,2
lesize,12,,,2
lsel,s,,,2,18,16
LCCAT,all
allsel
amesh,2
LSEL,s,LCCA
lDELE,all
allsel
lesize,20,,,6
lesize,17,,,8
lesize,13,,,2
lsel,s,,,19,20,1
LCCAT,all
allsel
amesh,5
LSEL,s,LCCA
lDELE,all
allsel
lesize,10,,,6
lesize,15,,,6
lesize,11,,,6
lesize,1,,,8
lesize,16,,,8
allsel
amesh,1
amesh,3
SAVE
TYPE, 2
EXTOPT,ESIZE,40,0,
EXTOPT,ACLEAR,1
EXTOPT,ATTR,0,0,0
MAT,2
REAL,1
VEXT,all, , ,0,0,4000,,,,
/VIEW, 1 ,1,1,1
/ANG, 1
EPLOT
TYPE,1
MAT,1
REAL,1
lmesh,29
FINISH
/SOL
DL,23, ,ALL,
DL,38, ,ALL,
DL,1, ,UY,
DL,16, ,UY,
DK,1, , , ,0,UX,UY
SAVE
BFL,29,TEMP,-375
CNVTOL,F, ,0.05,2, ,
NSUBST,10,0,0
OUTRES,ERASE
OUTRES,ALL,ALL
TIME,5
SOLVE
4.6混凝土开裂模拟
/TITLE,Crack
/PREP7
ET,1,SOLID65
KEYOPT,1,5,2
ET,2,LINK8
ET,3,PIPE16
R,1
R,2,0.15
R,3,1,0.5
MP,EX,1,2E6
MP,PRXY,1,0
TB,CONC,1
TBDATA,,,,,-1
MP,EX,2,30E6
MP,PRXY,2,0.3
!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
BLC4, , ,5,6,1.5
/VIEW, 1 ,1,1,1
/ANG, 1
/REP,FAST
!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
/PNUM,LINE,1
LSEL,,LOC,Z,0.1,1.4
LSEL,R,LOC,Y,0
TYPE, 2
MAT, 2
REAL, 2
LESIZE,ALL,,,1
LMESH,ALL
ALLSEL
LSEL,,LOC,Z,1.5
LSEL,R,LOC,Y,1,4
TYPE, 3
MAT, 1
REAL, 3
LESIZE,ALL,,,4
LMESH,ALL
ALLSEL
TYPE, 1
MAT, 1
REAL, 1
LSEL,,LOC,X,1,4
LESIZE,ALL,,,1
ALLSEL
MSHAPE,0,3D
MSHKEY,1
VMESH,ALL
FINISH
!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
/PREP7
CE,1,0,4,UZ,1,7,UZ,-1,7,ROTX,-3,
CE,2,0,6,UZ,1,7,UZ,-1,7,ROTX,-1.5,
CE,3,0,8,UZ,1,7,UZ,-1,7,ROTX,1.5,
CE,4,0,5,UZ,1,7,UZ,-1,7,ROTX,3,
CE,5,0,1,UZ,1,11,UZ,-1,11,ROTX,-3,
CE,6,0,12,UZ,1,11,UZ,-1,11,ROTX,-1.5,
CE,7,0,10,UZ,1,11,UZ,-1,11,ROTX,1.5,
CE,8,0,9,UZ,1,11,UZ,-1,11,ROTX,3,
NSEL,,LOC,Z,0
D,ALL,ALL
ALLSEL
NSEL,,LOC,Z,1.5
D,ALL,ROTY
D,ALL,ROTZ
ALLSEL
F,7,MX,300
F,11,MX,300
/SOL
NSUBST,5,0,0
AUTOTS,1
SOLVE
!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
/POST1
SET,LAST
*GET,SCON,NODE,17,S,Z
ETAB,ST,LS,1
ESORT,ST
*GET,STL,SORT,,MAX
*status,parm
/DEVICE,VECTOR,1
PLCRACK
SAVE
FINISH
4.7混凝土浇筑模拟
/TITLE,CASTCONCRETE
/PREP7
ET,1,SOLID70
MP,KXX,1,300.89
MP,C,1,0.94500
MP,DENS,1,2400
MP,KXX,2,300.89
MP,C,2,0.94500
MP,DENS,2,2600
BLOCK,,50,,2,,40,
BLOCK,-25,75,-10,0,-20,60,
/VIEW, 1 ,1,1,1
/ANG, 1
LSEL,,LOC,Z,0
LSEL,R,LOC,X,1,49
LESIZE,ALL,,,10
ALLSEL
LSEL,,LOC,Z,40
LSEL,R,LOC,X,1,49
LESIZE,ALL,,,10
ALLSEL
LSEL,,LOC,X,0
LSEL,R,LOC,Z,1,39
LESIZE,ALL,,,10
ALLSEL
LSEL,,LOC,X,50
LSEL,R,LOC,Z,1,39
LESIZE,ALL,,,10
ALLSEL
LSEL,,LOC,Z,0
LSEL,R,LOC,Y,1,1.5
LESIZE,ALL,,,2
ALLSEL
LSEL,,LOC,Z,40
LSEL,R,LOC,Y,1,1.5
LESIZE,ALL,,,2
ALLSEL
LSEL,,LOC,Z,-20
LSEL,R,LOC,X,1,49
LESIZE,ALL,,,20
ALLSEL
LSEL,,LOC,Z,60
LSEL,R,LOC,X,1,49
LESIZE,ALL,,,20
ALLSEL
LSEL,,LOC,X,-25
LSEL,R,LOC,Z,1,39
LESIZE,ALL,,,20
ALLSEL
LSEL,,LOC,X,75
LSEL,R,LOC,Z,1,39
LESIZE,ALL,,,20
ALLSEL
LSEL,,LOC,Z,-20
LSEL,R,LOC,Y,-9,-1.3
LESIZE,ALL,,,10
ALLSEL
LSEL,,LOC,Z,60
LSEL,R,LOC,Y,-9,-1.3
LESIZE,ALL,,,10
ALLSEL
VSEL,,LOC,Y,1,1.5
MAT,1
VMESH,1
ALLSEL
VSEL,,LOC,Y,-9,-1.5
MAT,2
VMESH,2
ALLSEL
NUMMRG,ALL
NUMCMP,NODE
NROPT,FULL
ESEL,S,MAT,,2
NSLE,S
IC,ALL,TEMP,16.5
ASEL,,LOC,X,-25
ASEL,A,LOC,X,75
ASEL,A,LOC,Y,-10
ASEL,A,LOC,Z,-20
ASEL,A,LOC,Z,60
NSLA,S
SF,ALL,HFLUX,0
ALLSEL
NSEL,,LOC,X,49,76
NSEL,R,LOC,Y,0
NSEL,A,LOC,X,-26,1
NSEL,R,LOC,Y,0
NSEL,A,LOC,Z,39,61
NSEL,R,LOC,Y,0
NSEL,A,LOC,Z,-21,1
NSEL,R,LOC,Y,0
SF,ALL,CONV,2016,20
ESEL,,MAT,,1
EKILL,ALL
NSLE,S
IC,ALL,TEMP,40
NSEL,,LOC,Y,0,1
ESLN,S,1
EALIVE,ALL
ALLSEL
NSEL,,LOC,X,1,49
NSEL,R,LOC,Z,1,39
NSEL,R,LOC,Y,0
CM,DD,NODE
ALLSEL
NSEL,,LOC,Y,0,1
ESLN,S,1
NSLE,S
NSEL,U,,,DD
SF,ALL,CONV,2016,20
HE00=47880/1.862
BFE,ALL,HGEN,,HE00
ALLSEL
/SOLU
ANTYPE,TRANS
TIME,1
AUTOTS,0
DELTIM,1
KBC,0
SOLVE
/POST1
PLNSOL,TG,SUM
/PREP7
NSEL,,LOC,Y,0,1
ESLN,S,1
HE00=47880*(2/2.862- 1/1.862)
BFE,ALL,HGEN,,HE00
ALLSEL
/SOLU
ANTYPE,TRANS
TIME,2
AUTOTS,0
DELTIM,1
KBC,0
SOLVE
/POST1
PLNSOL,TG,SUM
/PREP7
ESEL,,MAT,,1
NSLE,S
SFEDELE,ALL,ALL,CONV
ALLSEL
NSEL,,LOC,X,1,49
NSEL,R,LOC,Z,1,39
NSEL,R,LOC,Y,0,1
CM,KK,NODE
NSEL,,LOC,Y,0,2
ESLN,S,1
NSLE,S
NSEL,U,,,KK
SF,ALL,CONV,2016,20
ALLSEL
NSEL,,LOC,Y,0,1
ESLN,S,1
HE00=47880*(3/3.862-2/2.862)
BFE,ALL,HGEN,,HE00
ALLSEL
NSEL,,LOC,Y,1,2
ESLN,S,1
HE00=47880/1.862
BFE,ALL,HGEN,,HE00
ALLSEL
/SOLU
ANTYPE,TRANS
TIME,3
AUTOTS,0
DELTIM,1
KBC,0
SOLVE
/POST1
PLNSOL,TG,SUM
/PREP7
NSEL,,LOC,Y,0,1
ESLN,S,1
HE00=47880*(4/4.862-3/3.862)
BFE,ALL,HGEN,,HE00
ALLSEL
NSEL,,LOC,Y,1,2
ESLN,S,1
HE00=47880*(2/2.862-1/1.862)
BFE,ALL,HGEN,,HE00
ALLSEL
/SOLU
ANTYPE,TRANS
TIME,4
AUTOTS,0
DELTIM,1
KBC,0
SOLVE
/POST1
PLNSOL,TG,SUM
SAVE
FINISH
!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
/PREP7
ET,1,SOLID45
MP,EX,1,0.325E10
MP,DENS,1,2400
MP,PRXY,1,0.2
MP,ALPX,1,0.9E-5
MP,REFT,1,15
MP,EX,2,2.08E10
MP,DENS,2,2600
MP,PRXY,2,0.2
MP,ALPX,2,0.9E-5
ESEL,,MAT,,2
MPCHG,2,ALL
ALLSEL
/SOLU
ASEL,,LOC,X,-25
ASEL,A,LOC,X,75
ASEL,A,LOC,Y,-10
ASEL,A,LOC,Z,-20
ASEL,A,LOC,Z,60
NSLA,S
D,ALL,ALL
ALLSEL
ESEL,,MAT,,1
EKILL,ALL
NSEL,,LOC,Y,0,1
ESLN,S,1
EALIVE,ALL
MPCHG,1,ALL
ALLSEL
ACEL,0,9.8,0
LDREAD,TEMP,,,1,,'CASTCONCRETE','rth',''
ANTYPE,TRANS
NLGEOM,ON
CNVTOL,F,,0.2,2,200
TIME,1
AUTOTS,0
DELTIM,1
KBC,0
SOLVE
/SOLU
LDREAD,TEMP,,,2,,'CASTCONCRETE','rth',''
TIME,2
SOLVE
/SOLU
NSEL,,LOC,Y,1,2
ESLN,S,1
EALIVE,ALL
MPCHG,1,ALL
ALLSEL
LDREAD,TEMP,,,3,,'CASTCONCRETE','rth',''
TIME,3
SOLVE
/SOLU
LDREAD,TEMP,,,4,,'CASTCONCRETE','rth',''
TIME,4
SOLVE
FINISH
SAVE
!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
/POST1
PLNSOL,U,Y
PLNSOL,S,Y
PLESOL,S,Y
5.2行架桥
/TITLE,TRUSS
/PREP7
ET,1,BEAM4
ET,2,LINK8
ET,3,SHELL63
R,1,3,0.25,2.25,3,1,,-0.0001,1
R,2,3,0.25,2.25,3,1,,,1
R,3,2,1/6,2/3,2,1,,,2/3
R,4,1
R,5,1,-1.5E-4
R,6,0.3
MP,EX,1,35E10
MP,DENS,1,3000
MP,PRXY,1,1/6
MP,EX,2,21E10
MP,DENS,2,3500
MP,PRXY,2,0.3
MP,EX,3,3.5E10
MP,DENS,3,2500
MP,PRXY,3,1/6
MP,EX,4,3.5E10
MP,DENS,4,2500
MP,PRXY,4,1/6
!>>>>>>>>>>>>>>>>>>>>>
N,1,0,-5,0
NGEN,4,1,1,,,12
N,5,0,-5,12
NGEN,3,1,5,,,12
NSYM,Y,7,ALL
TYPE,1
REAL,1
MAT,1
E,1,2
E,2,3
E,3,4
E,8,9
E,9,10
E,10,11
TYPE,1
REAL,2
MAT,1
E,5,6
E,6,7
E,12,13
E,13,14
E,5,12
E,6,13
E,7,14
TYPE,1
REAL,3
MAT,2
E,7,4
E,14,11
TYPE,2
REAL,4
MAT,3
E,5,2
E,2,7
E,12,9
E,9,14
TYPE,2
REAL,5
MAT,3
E,5,1
E,6,2
E,7,3
E,12,8
E,13,9
E,14,10
TYPE,3
REAL,6
MAT,4
E,1,2,9,8
E,2,3,10,9
E,3,4,11,10
NSYM,X,14,ALL
ESYM,,14,ALL
NUMMRG,ALL
NUMCMP,ALL
SAVE
/SOLU
D,17,UX
D,17,UY
D,17,UZ
D,22,UX
D,22,UY
D,22,UZ
D,4,UY
D,4,UZ
D,11,UY
D,11,UZ
ACEL,,,10
F,1,FZ,-10000
F,8,FZ,-10000
SAVE
SOLVE
!>>>>>>>>>>>>>>>>>>>>
/POST1
PLVECT,U
PRNSOL,U,Z
PRESOL,ELEM
FINISH
SAVE
5.3悬索桥
/TITLE,CABLE
/PREP7
ET,1,LINK10
ET,2,BEAM3
R,1,1,1E-5
R,2,0.02,1E-5
R,3,0.5,1/24,1
MP,EX,1,25E10
MP,PRXY,1,0.1
MP,DENS,1,1000
MP,EX,2,30E10
MP,PRXY,2,0.1
MP,DENS,2,1000
A=250
*DO,I,1,10
X=10*(I-1)
Y=A*COSH(X/A)-A
N,I,X,Y
*ENDDO
N,11,100,20
*DO,I,1,10
X=10*I
Y=0
N,11+I,X,Y
*ENDDO
type,1
real,1
mat,1
*DO,I,1,10
E,I,I+1
*ENDDO
type,1
real,2
mat,1
*DO,I,2,10
E,I,I+10
*ENDDO
type,2
real,3
mat,2
E,1,12
*DO,I,1,9
E,I+11,I+12
*ENDDO
NSYM,X,21,ALL
ESYM,,21,ALL
NUMMRG,ALL
NUMCMP,ALL
SAVE
!>>>>>>>>>>>>>>>>>>>>
/SOLU
D,41,UX
D,41,UY
D,21,UY
D,31,UX
D,31,UY
D,11,UX
D,11,UY
NSEL,U,NODE,,41
NSEL,U,NODE,,21
D,ALL,UZ
ALLSEL
ACEL,,10,,
NROPT,FULL
ESEL,,REAL,,2
ESEL,A,REAL,,3
EKILL,ALL
ALLSEL
NLGEOM,ON
TIME,1
NSUBST,10,20,5
OUTRES,ERASE
OUTRES,ALL,ALL
SSTIF,ON
SOLVE
/POST1
ESEL,,LIVE
PLVECT,U
ALLSEL
/PREP7
UPGEOM,1,LAST,LAST,'Cable','RST'
/SOLU
SOLVE
/POST1
ESEL,,LIVE
P