温度传感器温度控制实训.doc

温度传感器温度控制实训
一、实训目的
1、 了解温度传感器电路的工作原理
2、 了解温度控制的基本原理
3、 掌握一线总线接口的使用
二、实训说明
这是一个综合硬件实验，分两大功能：温度的测量和温度的控制。
1、DALLAS最新单线数字温度传感器DS18B20简介
Dallas 半导体公司的数字化温度传感器DS1820是世界上第一片支持“一线总线”接口的温度传感器。现场温度直接以“一线总线”的数字方式传输，大大提高了系统的抗干扰性。适合于恶劣环境的现场温度测量，如：环境控制、设备或过程控制、测温类消费电子产品等。与前一代产品不同，新的产品支持3V～5.5V的电压范围，使系统设计更灵活、方便。
DS18B20测量温度范围为 -55°C～+125°C，在-10～+85°C范围内,精度为±0.5°C。DS18B20可以程序设定9～12位的分辨率，及用户设定的报警温度存储在EEPROM中，掉电后依然保存。
DS18B20内部结构
DS18B20内部结构主要由四部分组成：64位光刻ROM、温度传感器、非挥发的温度报警触发器TH和TL、配置寄存器。DS18B20的管脚排列如下:
DQ为数字信号输入/输出端；GND为电源地；VDD为外接供电电源输入端（在寄生电源接线方式时接地）。
光刻ROM中的64位序列号是出厂前被光刻好的，它可以看作是该DS18B20的地址序列码。64位光刻ROM的排列是：开始8位（28H）是产品类型标号，接着的48位是该DS18B20自身的序列号，最后8位是前面56位的循环冗余校验码（CRC=X8+X5+X4+1）。光刻ROM的作用是使每一个DS18B20都各不相同，这样就可以实现一根总线上挂接多个DS18B20的目的。
DS18B20中的温度传感器可完成对温度的测量，以12位转化为例:用16位符号扩展的二进制补码读数形式提供，以0.0625℃/LSB形式表达，其中S为符号位。

LS Byte:
Bit7
Bit6
Bit5
Bit4
Bit3
Bit2
Bit1
Bit0
23
22
21
20
2-1
2-2
2-3
2-4
MS Byte:
Bit15
Bit14
Bit13
Bit12
Bit11
Bit10
Bit9
Bit8
S
S
S
S
S
26
25
24
这是12位转化后得到的12位数据，存储在18B20的两个8比特的RAM中，二进制中的前面5位是符号位，如果测得的温度大于0，这5位为0，只要将测到的数值乘于0.0625即可得到实际温度；如果温度小于0，这5位为1，测到的数值需要取反加1再乘于0.0625即可得到实际温度。
例如+125℃的数字输出为07D0H，+25.0625℃的数字输出为0191H，-25.0625℃的数字输出为FF6FH，-55℃的数字输出为FC90H。
温度
数据输出（二进制）
数据输出（十六进制）
+125℃
0000 0111 1101 0000
07D0h
+85℃
0000 0101 0101 0000
0550h
+25.0625℃
0000 0001 1001 0001
0191h
+10.125℃
0000 0000 1010 0010
00A2h
+0.5℃
0000 0000 0000 1000
0008h
0℃
0000 0000 0000 0000
0000h
-0.5℃
1111 1111 1111 1000
FFF8h
-10.125℃
1111 1111 0101 1110
FF5Eh
-25.0625℃
1111 1110 0110 1111
FE6Fh
-55℃
1111 1100 1001 0000
FC90h
DS18B20温度传感器的存储器
DS18B20温度传感器的内部存储器包括一个高速暂存RAM和一个非易失性的可电擦除的E2RAM,后者存放高温度和低温度触发器TH、TL和结构寄存器。
暂存存储器包含了8个连续字节，前两个字节是测得的温度信息，第一个字节的内容是温度的低八位，第二个字节是温度的高八位。第三个和第四个字节是TH、TL的易失性拷贝，第五个字节是结构寄存器的易失性拷贝，这三个字节的内容在每一次上电复位时被刷新。第六、七、八个字节用于内部计算。第九个字节是冗余检验字节。
该字节各位的意义如下：
TM
R1
R0
1
1
1
1
1
低五位一直都是1 ，TM是测试模式位，用于设置DS18B20在工作模式还是在测试模式。在DS18B20出厂时该位被设置为0，用户不要去改动。R1和R0用来设置分辨率，如下表所示：（DS18B20出厂时被设置为12位）
分辨率设置表:
R1
R0
分辨率
温度最大转换时间
0
0
9位
93.75ms
0
1
10位
187.5ms
1
0
11位
375ms
1
1
12位
750ms
根据DS18B20的通讯协议，主机控制DS18B20完成温度转换必须经过三个步骤：每一次读写之前都要对DS18B20进行复位，复位成功后发送一条ROM指令，最后发送RAM指令，这样才能对DS18B20进行预定的操作。复位要求主CPU将数据线下拉500微秒，然后释放，DS18B20收到信号后等待16～60微秒左右，后发出60～240微秒的存在低脉冲，主CPU收到此信号表示复位成功。
2、本实验在读取温度的基础上，完成类似空调恒温控制的实验。用加热电阻代替加热电机,制冷采用自然冷却。温度值通过LED显示电路以十进制形式显示出来，单片机发出指令信号，继电器吸合，红色LED点亮，加热电阻开始加热。
三、实训内容及步骤
1、把7279阵列式键盘的J9四只短路帽打在上方，J10打在VCC处，用8P排线将JD7和八位动态数码显示的JD11相连,JD8和JD12相连，DS18B20的CONTROL接P1.4，OUT接P1.0
2、安装好仿真器，用串行数据通信线连接计算机与仿真器，把仿真头插到模块的单片机插座中，打开模块电源，插上仿真器电源插头。
3、用串行数据通信线连接计算机与仿真器，把仿真器插到模块的锁紧插座中，请注意仿真器的方向：缺口朝上。
4、打开Keil uVision2仿真软件，首先建立本实验的项目文件，接着添加“DS18B20.C”源程序，进行编译，直到编译无误。
5、全速运行程序，程序正常运行后，数码LED数显为 “XX”为十进制温度测量值。按下自锁开关“控制”LED随之灯点亮加热源开始加热，温度也随着变化，当加热到设定的控制温度时如50度时，停止加热。
5、也可以把源程序编译成可执行文件，把可执行文件用ISP烧录器烧录到89S52/89S51芯片中运行。（ISP烧录器的使用查看附录二）

四、源程序

TEMPER_L EQU 20H ;用于保存读出温度的低8位
TEMPER_H EQU 21H ;用于保存读出温度的高8位
FLAG1 EQU 22H ;是否检测到DS18B20标志位
DATA_IN DATA 025H
DATA_OUT DATA 026H
TIMER DATA 030H
BIT_COUNT DATA 031H
DBUF DATA 032H
CLK BIT P1.6
DAT BIT P1.7

ORG 0000H
LJMP START
ORG 0100H
START:SETB P1.4
clr p1.5
MAIN: LCALL GET_TEMPER;调用读温度子程序
MOV A,29H
MOV C,40H ;将28H中的最低位移入C
RRC A
MOV C,41H
RRC A
MOV C,42H
RRC A
MOV C,43H
RRC A
MOV 29H,A
LCALL TOBCD
LCALL DISPLAY ;调用数码管显示子程序
LCALL DELAY
AJMP MAIN

INIT_1820: ; 这是DS18B20复位初始化子程序
SETB P1.0
NOP
CLR P1.0
MOV R1,#3 ;主机发出延时537微秒的复位低脉冲

TSR1:MOV R0,#107
DJNZ R0,$
DJNZ R1,TSR1
SETB P1.0 ;然后拉高数据线
NOP
NOP
NOP
MOV R0,#25H
TSR2:JNB P1.0,TSR3 ;等待DS18B20回应
DJNZ R0,TSR2
LJMP TSR4 ; 延时
TSR3:SETB FLAG1 ; 置标志位,表示DS1820存在
LJMP TSR5
TSR4:CLR FLAG1 ; 清标志位,表示DS1820不存在
LJMP TSR7
TSR5:MOV R0,#117
TSR6:DJNZ R0,TSR6 ; 时序要求延时一段时间
TSR7:SETB P1.0
RET
GET_TEMPER: ; 读出转换后的温度值
SETB P1.0
LCALL INIT_1820 ;先复位DS18B20
JB FLAG1,TSS2
RET ; 判断DS1820是否存在?若DS18B20不存在则返回
TSS2:MOV A,#0CCH ; 跳过ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 发出温度转换命令
LCALL WRITE_1820
LCALL DELAY1 ;这里通过调用显示子程序实现延时一段时间,等待AD转换结束,12位的话750微秒
LCALL INIT_1820 ;准备读温度前先复位
MOV A,#0CCH ; 跳过ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 发出读温度命令
LCALL WRITE_1820
LCALL READ_18200 ; 将读出的温度数据保存到35H/36H
RET
WRITE_1820: ;写DS18B20的子程序(有具体的时序要求)
MOV R2,#8 ;一共8位数据
CLR C
WR1: CLR P1.0
MOV R3,#6
DJNZ R3,$
RRC A
MOV P1.0,C
MOV R3,#23
DJNZ R3,$
SETB P1.0
NOP
DJNZ R2,WR1
SETB P1.0
RET
READ_18200: ; 读DS18B20的程序,从DS18B20中读出两个字节的温度数据
MOV R4,#2 ; 将温度高位和低位从DS18B20中读出
MOV R1,#29H ; 低位存入29H(TEMPER_L),高位存入28H(TEMPER_H)
RE00:MOV R2,#8 ; 数据一共有8位
RE01:CLR C
SETB P1.0
NOP
NOP
CLR P1.0
NOP
NOP
NOP
SETB P1.0
MOV R3,#9
RE10:DJNZ R3,RE10
MOV C,P1.0
MOV R3,#23
RE20:DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
DEC R1
DJNZ R4,RE00
RET
TOBCD:
MOV A,29H ;将29H中的十六进制数转换成10进制
MOV B, #10
DIV AB
MOV DBUF+1, A
MOV A, B
MOV DBUF,A
MOV A,DBUF+1
CJNE A,#5,$+3
JNC WW
SETB P1.4
CLR P1.5
RET
WW: CLR P1.4
SETB P1.5
DISPLAY:
ANL P2,#00H ; CS7279有效
MOV DATA_OUT,#10100100B ; A4H,复位命令
CALL SEND
MOV DATA_OUT,#10000000B ; 在第一个数码管上显示
CALL SEND
MOV DATA_OUT,DBUF
CALL SEND
MOV DATA_OUT,#10000001B ; 译码方式0,2位显示在第一个数码管上显示
CALL SEND
MOV DATA_OUT,DBUF+1
CALL SEND
RET

SEND: MOV BIT_COUNT,#8 ; 发送字符子程序
ANL P2,#00H
CALL LONG_DELAY
SEND_LOOP:MOV C,DATA_OUT.7
MOV DAT,C
SETB CLK
MOV A,DATA_OUT
RL A
MOV DATA_OUT,A
CALL SHORT_DELAY
CLR CLK
CALL SHORT_DELAY
DJNZ BIT_COUNT,SEND_LOOP
CLR DAT
RET
LONG_DELAY: MOV TIMER,#80 ;延时约200US
DELAY_LOOP: DJNZ TIMER,DELAY_LOOP
RET
SHORT_DELAY: MOV TIMER,#6 ;延时约20US
SHORT_LP: DJNZ TIMER,SHORT_LP
RET

DELAY: LCALL DELAY1
LCALL DELAY1
LCALL DELAY1
LCALL DELAY1
LCALL DELAY1
RET
DELAY1:MOV R1, #0
DLOOP: DJNZ R1, DLOOP
DJNZ R0, DELAY1
RET
END
五 实训结果

六 实训体会