FOXPRO应用技巧篇.doc

FOXPRO应用技巧篇（六）
序号
内                   容
1
VFP表跟踪实现方法
2
用Foxpro实现对Novell服务器的管理
3
VISUAL FOXPRO 5.0动画设计
4
VFP多媒体数据处理技术
5
巧妙利用BROW语句左右翻屏的方法
6
基于FoxPro的MIS实现大量图像数据的管理
7
两个阿拉伯数字金额转换为金额数据的例子
8
VFP中如何编程实现图表功能       （小狐也根据VFP中的相关示例程序编写了一应用图表功能的表单程序，源程序可以在这里下载：   )
9
如何避免运行两份相同的程序
10
VFP之foxtools.fll库函数应用技巧几则
11
在VFP中控制IE4.0
12
一个应用加解密保护数据的方法

1、VFP表跟踪实现方法
(作者 刘珊  E-mail: zhubaiyu@)
摘要 本文介绍了Visual Foxpro中数据库触发技术的应用实例，为VFP表建立跟踪日志,提供解决网络多用户环境中数据文件安全的一种方法。

关键词 触发技术，表跟踪，自定义函数
表跟踪问题的提出：

         在管理信息系统的正常运行中，信息的安全性问题日益突出。虽然网络为我们提供了一定的数据安全性，只有授权的用户才能对数据进行日常的维护，但有时用户的误操作可能导致数据的丢失或混乱；另外，有时我们需要对数据的改动留下记载等。对重要的数据文件，记录每一个数据变化的审核日志，对其建立其相应的日志表来跟踪对它的增、删和修改操作是十分必要的。日志表中记载了何时、何用户进行了何种操作，记载了被用户增加或删除的记录信息，以及被修改记录的原来信息和修改后的信息，将被操纵过的记录进行备份。

VFP触发技术：
        Visual Foxpro与它的前期版本重大差别之一是使用了数据库（Database）这一强大功能，使之成为一个真正的DataBase。VFP的Database Container包含了表（Table）及表的各种属性定义，也包含了属于后端的SQL中的触发技术（Trigger）。
Trigger的使用为Database中的Table提供了一个记录级规则（即检测程序）。Trigger分为Insert Trigger、Update Trigger和Delete Trigger三种操作。Insert Trigger用于Table新增记录时所触发的检测程序，Update Trigger用于Table修改记录回存时所触发的检测程序，Delete Trigger用于Table中记录被删时所触发的检测程序。VFP允许对任一种操作设定不同的规则，该规则可以是表达式或用户自定义函数（UFD），若响应为真值时，表示触发成功，若响应为假值时表示触发失败。用户自定义函数（UFD）存储在Database Container中。
创建触发器有两种方式：
1) 打开表属性”对话框，在 INSERT、UPDATE 或 DELETE 触发器框中，输入触发器表达式或用户自定义函数（UFD）；
2) 使用 CREATE TRIGGER 命令。
创建、修改或移去存储过程有三种方式：
1) 在项目管理器中，选择并展开一个数据库，选定“存储过程”，然后选择“新建”、“修改”或“移去”按钮；
2) 在数据库设计器中，从“数据库”菜单中选择“编辑存储过程”按钮；
3) 在COMMAND命令窗口中，使用 MODIFY PROCEDURE 命令。
表跟踪设计：
利用Insert Trigger、Update Trigger和Delete Trigger三种操作原理，我们可以构造备份被操纵记录的用户自定义函数，并将其加入需要进行表跟踪的数据文件Trigger中，以实现表跟踪。这样，不论用户使用程序进行对此表的操纵或直接打开此表进行增删和修改记录，都能激发Trigger将被操纵记录进行日志记载。
本人构造了四个通用的自定义函数，Inslog()、Dellog()、Modlog()和addlog()，存放于Database Container的存储过程中。在需要进行表跟踪的数据文件的Insert Trigger、Delete Trigger和Update Trigger中分别加入Inslog()函数、Dellog()函数和Modlog()函数，以使对数据文件中记录的增、删和修改均激发Trigger进行日志记载。addlog()用于建立被跟踪表的日志表结构，日志表的结构设计包含了被跟踪表的所有字段信息，并且增加了用户标志opid、操作日期时间optime和操作标志opmak字段。日志表的命名规则为被跟踪表的表名前加‘L',以示区分，另外本人在存放数据文件目录下另设子目录LOGDBFS，专用于存放日志表以便管理。这四个函数程序设计如下：

*Insert Trigger:
FUNCTION inslog()
m.path=substr(dbf(),1,rat('\',dbf()))
m. logname=m.path+'LOGDBFS\L'+SUBSTR(DBF(),LEN(m.path)+1)
IF NOT FILE(m.logname)
=addlog() &&建立日志表结构
ENDI
SCATTER MEMVAR
m.opmak='增' &&增加记录标志
m.opid=SYS(0) &&取网络用户标志
m.optime=datetime() &&增加记录时间
INSERT INTO (m.logname) ;
FROM MEMVAR &&记载所增记录
RETURN .T.

*Delete Trigger:
FUNCTION dellog()
m.path=substr(dbf(),1,rat('\',dbf()))
m. logname=m.path+'LOGDBFS\L'+SUBSTR(DBF(),LEN(m.path)+1)
IF NOT FILE(m.logname)
=addlog()
ENDI
SCATTER MEMVAR
m.opmak='删' &&删除记录标志
m.opid=SYS(0)
m.optime=datetime()
INSERT INTO (m.logname) ;
FROM MEMVAR &&记载所删记录
RETURN .T.

*Update Trigger:
FUNCTION modlog()
m.path=substr(dbf(),1,rat('\',dbf()))
m. logname=m.path+'LOGDBFS\L'+SUBSTR(DBF(),LEN(m.path)+1)
IF NOT FILE(m.logname)
=addlog()
ENDI
DIME alog[FCOUNT()+3]
alog[FCOUNT()+2]=SYS(0)
alog[FCOUNT()+3]=datetime()
alog[FCOUNT()+1]='修(原)'
FOR i=1 TO FCOUNT()
alog[I]=oldval(field[I])
ENDFOR
INSERT INTO (m.logname) ;
FROM ARRAY alog &&记载更改前信息
alog[FCOUNT()+1]='修(现)'
FOR i=1 TO FCOUNT()
alog[I]=EVALUATE(field[I])
ENDFOR
INSERT INTO (m.logname) ;
FROM ARRAY alog &&记载更改后信息
RETURN .T.

*建立日志表结构:
FUNCTION addlog()
*取被跟踪表字段
COPY STRU TO tmp EXTEND
*建立用户标志、操作时间和操作标志字段信息
INSERT INTO tmp.dbf ;
(field_name,field_type,field_len);
VALUES ('OPMAK','C',6)
INSERT INTO tmp.dbf ;
(field_name,field_type,field_len);
VALUES ('OPID','C',10)
INSERT INTO tmp.dbf ;
(field_name,field_type,field_len);
VALUES ('OPTIME','T',8)
USE IN tmp
oldselect=SELECT() &&生成日志表结构
SELE 0
CREATE (m.logname) FROM tmp
DELETE FILE tmp.dbf
SELECT (oldselect)
RETURN

返回页首

2、用Foxpro实现对Novell服务器的管理
（朱西讲  E-mail: zbsf1@）
          Novell网络以其严格的保密性和明确的权限管理倍受广大用户的青睐，使其始终居于多用户环境的领先地位。本人在多年校园网络的管理中发现，Novell网在目录和文件的管理方面(非安全性)还存在不足。一是，教学管理的需要，学期初要对网络中众多帐号的主工作目录进行清理，用Del、Deltree或Filer命令手动清理费时费力；二是，教学管理中常常需要将某些文档发送到某些帐号的主工作目录中，用Copy、Xcopy或Ncopy命令手动发送同样繁琐。由于Novell没有提供其他更加便捷的方法，鉴于此，本人用数据库语言Foxpro编写了“Novell服务器管理系统”程序，成功地解决了上述两个问题。现将本程序向各位朋友简单介绍如下：

程序功能说明:
1、本程序共包含两大功能模块:
文档清理和文档发送。清理和发送文档的目标位置通过逐层选择菜单实现。其中，把选择帐号菜单XZZH巧妙地设定于窗口WINUSER中，实现了带标记“◆”随意选择帐号名称的功能；另外，巧妙构建系统运行进度指示表，使用户能清楚地了解系统运行的进程。
2、文档清理功能:
通过调用Dos和Netware的Deltree、Flag、Flagdir命令，将所选帐号主工作目录下所有属性的目录和文件清除。程序先清除主工作目录下所有Normal属性的目录和文件，后清除非Normal属性的目录和文件，提高了系统运行的效率。
3、文档发送功能:
通过调用Netware的Ncopy命令，将源文档发送到所选帐号的主工作目录下。
4、本程序稍加修改即可用于单台或多台服务器的网络中。

程序运行环境:

1、网络中有两台文件服务器NVZXJ、NVPSP，都建有SYS、STUDENT、TEACHER三个卷和相同的帐号。其中，其他帐号、学生帐号和教师帐号的主工作目录分别位于两服务器的SYS卷、STUDENT卷和TEACHER卷的根目录下，且目录名与帐号名相同。

2、建立结构相同的三个数据库文件USER1.DBF、USER2.DBF、USER3.DBF，分别存放其他帐号、学生帐号和教师帐号的名字，字段名为BZ、USER，字段类型为字符型，宽度分别为4和10。

3、程序运行前必须以Supervisor帐号登录到两台服务器，否则，“文档发送&rdquo功能的应用范围将会受到限制。

4、合理配置启动盘的CONFIG.SYS文件的内容，并将本系统程序文件、数据库文件及Deltree.exe、Flag.exe、Flagdir.exe文件拷贝到同一目录下，以保证程序的正常运行。
5、该程序在PII-266服务器，486、586工作站，Netware 3.12，MS-DOS 6.22，Ucdos
7.0，Foxpro 2.6 For Dos下运行通过。

（程序清单附后）
邮编：255100
电话：[phone]
E-mail: zbsf1@
------------------------------------

附：程序清单
*******************
* 程序名:MAIN.PRG *
* 功 能:主程序 *
*******************
SET TALK OFF
SET SCORE OFF
SET SAFE OFF
SET STAT OFF
SET CURSOR OFF
SET COLO TO W/R+
CLEAR
SET COLO TO
CLEAR ALL
DEFINE WINDOWS WINMAIN FROM 2,2 TO 24,79;
DOUBLE TITLE " ※ NOVELL 服 务 器 管 理 系 统 ※ ";
FOOTER "※ 淄博师范网络中心 朱西讲(Ver: 1.0 1999.1) ※";
NOFLOAT NOGROW &&建立系统主窗口
ACTIVATE WINDOWS WINMAIN
MOVE WINDOWS WINMAIN CENTER &&将主窗口移至屏幕中央
**建立系统主菜单
SELE=1 &&主菜单选项变量SELE
DIMENSION OPTION(7)
OPTION(1)="\-"
OPTION(2)=" \<1.文 档 清 理 "
OPTION(3)="\-"
OPTION(4)=" \<2.文 档 发 送 "
OPTION(5)="\-"
OPTION(6)=" \<3.退 出 系 统 "
OPTION(7)="\-"
DO WHILE .T.
@4,28 MENU OPTION,7,7 TITLE "※ 主 菜 单 ※";
SHADOW COLOR SCHEME 5
READ MENU TO SELE
DO CASE
CASE SELE=0 .OR. SELE=6
EXIT
CASE SELE=2
DO SERVER.PRG
CASE SELE=4
SPACE=SPACE(45) &&源文档路径变量SPACE
YN=SPACE(1)
DO SOURCE.PRG WITH SPACEYN
DO SERVER.PRG
ENDCASE
ENDDO
CLEA ALL
ERASE TMPZH.DBF
ERASE BLANK.DBF
SET TALK ON
SET SCORE ON
SET SAFE ON
SET STAT ON
SET CURSOR ON
SET COLO TO
RETURN

***************************
* 程序名:SERVER.PRG *
* 功 能:选择“服务器”名 *
***************************
SERSELE=1 &&“服务器”菜单选项变量SERSELE
DIMENSION SER(7)
SER(1)="\-"
SER(2)=" \<1. NVZXJ "
SER(3)="\-"
SER(4)=" \<2. NVPSP "
SER(5)="\-"
SER(6)=" \<3. 返 回 "
SER(7)="\-"
DO WHILE .T.
@4,26 MENU SER,7,7 TITLE "※ 选择服务器名 ※";
SHADOW COLOR SCHEME 7
READ MENU TO SERSELE
DO CASE
CASE SERSELE=0 .OR. SERSELE=6
EXIT
CASE SERSELE=2
SERNAME="NVZXJ\" &&将服务器名赋予变量SERNAME
DO VOL.PRG
CASE SERSELE=4
SERNAME="NVPSP\"
DO VOL.PRG
ENDCASE
ENDDO

********************************
* 程序名: SOURCE.DBF *
* 功 能: 输入被发送文档的路径 *
********************************
PARAMETER SOURCE,QD
DEFINE WINDOWS WINSOURCE IN WINDOWS WINMAIN;
FROM 3,10 TO 17,60 DOUBLE NOFLOAT NOGROW;
TITLE " ※ 请输入被发送文档的完整路径 ※ " COLOR SCHEME 7
ACTIVATE WINDOWS WINSOURCE
MOVE WINDOWS WINSOURCE CENTER
SET CURSOR ON
@7,2 TO 11,46 DOUBLE COLOR Bg+/R
@6,20 SAY '注 意'
@9,12 say "请仔细检查输入路径的正确性"
@1,2 GET SOURCE
@3,2 SAY "是否发送此路径下子目录中的文档：" GET QD PICTURE "Y"
READ
SET CURSOR OFF
RELEASE WINDOWS WINSOURCE
RETURN

**************************
* 程序名: VOL.PRG *
* 功 能: 选择“卷”名 *
**************************
VOLSELE=1 &&“卷”菜单选项变量VOLSELE
DIMENSION VOL(9)
VOL(1)="\-"
VOL(2)=" \<1. SYS " &&系统卷
VOL(3)="\-"
VOL(4)=" \<2. STUDENT " &&学生卷
VOL(5)="\-"
VOL(6)=" \<3. TEACHER " &&教师卷
VOL(7)="\-"
VOL(8)=" \<4. 返 回 "
VOL(9)="\-"
DO WHILE .T.
@4,28 MENU VOL,9,9 TITLE "※ 选择卷名 ※";
SHADOW COLOR SCHEME 4
READ MENU TO VOLSELE
DO CASE
CASE VOLSELE=0 .OR. VOLSELE=8
EXIT
CASE VOLSELE=2
SERVOL=SERNAME+"SYS:" &&服务器及卷名路径
DO USER.PRG
CASE VOLSELE=4
SERVOL=SERNAME+"STUDENT:" &&服务器及卷名路径
DO USER.PRG
CASE VOLSELE=6
SERVOL=SERNAME+"TEACHER:" &&服务器及卷名路径
DO USER.PRG
ENDCASE
ENDDO

**********************************************
* 程 序 名: USER.PRG *
* 功 能: 系统管理(系统清理、文件发送) *
* 辅助库文件: USER1.DBF BZ(C,4) USER(C,10) *
* USER2.DBF BZ(C,4) USER(C,10) *
* USER3.DBF BZ(C,4) USER(C,10) *
* BLANK.DBF NR(C,100) *
**********************************************
ON KEY LABEL F12 DO XTGL &&按键F12,执行系统管理程序XTGL
DEFINE WINDOW WINUSER IN WINDOWS WINMAIN;
FROM 2,10 TO 18,60;
TITLE " ※ 请选择帐号名称 ※ ";
DOUBLE NOFLOAT NOGROW;
FOOTER "PageUp,PageDown 翻页" COLOR SCHEME 5
*建立选择帐号菜单:XZZH
DO CASE
CASE VOLSELE=2
USE USER1 &&帐号名称库文件USER1.DBF
DEFINE POPUP XZZH IN WINDOWS WINUSER FROM 1,2 TO 12,20;
PROMPT FIELD USER1.BZ+USER1.USER;
MARGIN SCROLL SHADOW
CASE VOLSELE=4
USE USER2 &&帐号名称库文件USER2.DBF
DEFINE POPUP XZZH IN WINDOWS WINUSER FROM 1,2 TO 12,20;
PROMPT FIELD USER2.BZ+USER2.USER;
MARGIN SCROLL SHADOW
CASE VOLSELE=6
USE USER3 &&帐号名称库文件USER3.DBF
DEFINE POPUP XZZH IN WINDOWS WINUSER FROM 1,2 TO 12,20;
PROMPT FIELD USER3.BZ+USER3.USER;
MARGIN SCROLL SHADOW
ENDCASE
ACTI WINDOWS WINUSER
MOVE WINDOWS WINUSER CENTER
@ 3,24 SAY "***********************"
@ 4,24 SAY "* *"
@ 5,24 SAY "* 选择：回车键/空格键 *"
@ 6,24 SAY "* *"
@ 7,24 SAY "* 确定：F12键 *"
@ 8,24 SAY "* *"
@ 9,24 SAY "***********************"
ON SELECT POPUP XZZH DO SCZH WITH PROMPT() &&执行SCZH.PRG
DO WHILE .T.
ACTIVATE POPUP XZZH
ENDDO
*帐号选择标记
PROCEDURE SCZH
PARAMETERS DD
DD=SUBST(DD,5)
LOCATE ALL FOR USER=DD
IF BZ=" "
REPL BZ WITH "◆" &&选择标记
ELSE
REPL BZ WITH " " &&取消标记
ENDIF
RETURN
**生成临时帐号库文件TMPZH.DBF
PROCEDURE XTGL
ON KEY &&取消捕获按键
COPY TO TMPZH FIELD USER FOR BZ="◆" &&存入选择的帐号
REPL ALL BZ WITH " " &&将帐号库中BZ字段的数据清空
RELEASE WINDOWS WINUSE &&清除窗口WINUSER
RELEASE POPUP XZZH &&清除帐号选择菜单XZZH
DEACTIVATE WINDOWS WINMAIN
**系统管理
USE TMPZH
IF EOF()
CLOSE DATABASE
ERASE TMPZH.DBF
WAIT "您没有选择任何帐号，请按任意键返回" WINDOWS
ACTIVATE WINDOWS WINMAIN
RETURN TO MASTER
ENDIF
@7,31 SAY "系 统 进 度 表" COLOR BG+/R+
@8,8 TO 12,70 DOUBLE COLOR W/R+ &&画框
JL=RECCOUNT() &&将TMPZH.DBF的记录条数赋予变量JL
I=1 &&进度控制变量I
GO TOP
IF SELE=2
** 文档清理
DO WHILE .NOT. EOF() .AND. I<=JL
ML=SERVOL+ALLTRIM(USER)+"\*.*"
QL=SERVOL+ALLTRIM(USER)
@9,14 SAY "正在清理帐号："+QL COLOR BG+/R+
* 删除NORMAL属性的目录和文件
!DELTREE /Y &ML>NUL
* 将非NORMAL属性的目录文件清单存入BLANK.DBF
!NDIR &ML /SUB>ML.TXT
ERASE BLANK.DBF
SELE 2
CREATE TABLE BLANK (NR C(100)) &&建立库BLANK.DBF
APPE FROM ML.TXT SDF &&追加ML.TXT的内容到BLANK.DBF
ERASE ML.TXT
* 根据ML.TXT，构建非NORMAL属性的目录、文件的路径
DELETE FOR SUBSTR(NR,1,4)=="----";
.OR. SUBSTR(NR,1,6)=="Files:";
.OR. SUBSTR(NR,1,3)==" ";
.OR. SUBSTR(NR,1,12)=="Directories:"
PACK &&删除多余的记录
REPL ALL NR WITH SUBSTR(NR,1,17);
FOR NR#SERVOL &&删除记录中多余的内容
GO TOP
SCAN
IF NR=SERVOL
JM=ALLTRIM(NR)+"\" &&服务器及卷名和“\”
DELETE
ELSE
IF SUBSTR(NR,15,3)==" " &&目录文件无扩展名
REPL NR WITH JM+ALLTRIM(NR)
ELSE &&目录文件有扩展名
REPL NR WITH JM+ALLTRIM(SUBSTR(NR,1,14));
+"."+ALLTRIM(SUBSTR(NR,15,3))
ENDIF
ENDIF
ENDSCAN
PACK
GO TOP
* 删除非NORMAL属性的目录和文件
SCAN
WJ=ALLTRIM(NR)
!FLAG &WJ N>NUL &&消除文件的非NORMAL属性
!FLAGDIR &WJ N>NUL &&消除目录的非NORMAL属性
ENDSCAN
GO TOP
SCAN
WJ=ALLTRIM(NR)
!DELTREE /Y &WJ>NUL
ENDSCAN
**进度表及百分率
@9,53 SAY "已完成："+ALLTRIM(STR((I*((70-11)/JL)/(70-11))*100))+"%" COLOR BG+/R+
@10,10 SAY SPACE((RECNO(1)*((70-8-3)/JL))) COLOR /W*
@11,10 SAY SPACE((RECNO(1)*((70-8-3)/JL))) COLOR /W*
USE
SELECT TMPZH
I=I+1
SKIP
ENDDO
CLOSE DATABASE
WAIT '清理完毕，按任意键返回' WINDOWS
ELSE
** 文档发送
SML=ALLTRIM(SPACE) &&将被发送文档的路径赋予变量SML
DO CASE
CASE UPPER(SUBSTR(SML,1,2))=="A:"
WAIT "请将软盘插入Ａ驱动器,按任意键发送文件" WINDOWS
CASE UPPER(SUBSTR(SML,1,2))=="B:"
WAIT "请将软盘插入Ｂ驱动器,按任意键发送文件" WINDOWS
ENDCASE
DO WHILE .NOT. EOF() .AND. I<=JL
QL=SERVOL+ALLTRIM(USER)
@0,0
IF YN='Y'
!NCOPY &SML /S /E &QL>NUL &&同时拷贝子目录的文档
ELSE
!NCOPY &SML &QL>NUL
ENDIF
@9,12 SAY "发送文档给帐号："+QL COLOR BG+/R+
@9,53 SAY "已完成："+ALLTRIM(STR((I*((70-11)/JL)/(70-11))*100))+"%" COLOR BG+/R+
@10,10 SAY SPACE((RECNO(1)*((70-8-3)/JL))) COLOR /W*
@11,10 SAY SPACE((RECNO(1)*((70-8-3)/JL))) COLOR /W*
I=I+1
SKIP
ENDDO
CLOSE DATABASE
WAIT '发送完毕，按任意键返回' WINDOWS
ENDIF
SET COLOR TO W/R+
CLEAR
SET COLOR TO
ACTIVATE WINDOWS WINMAIN &&激活主窗口WINMAIN
RETURN TO MASTER &&返回主程序MAIN.PRG

返回页首
3、FOXPRO动画设计
        VISUAL FOXPRO是目前国内非常流行的可视化数据库开发工具，它以强大的功能，
便捷的开发方法深受广大用户的喜爱。而动画功能一直是3DSTUDIO、PHOTOSHOP、VISUAL BASIC等软件制作工具的开发专利，是否数据库软件中就真的不能实现动画功能呢
回答是否定的。下面我就详细告诉你如何在VISAUL FOXPRO 5.0中进行实现动画设计。
　　为了使动画效果更加逼真，通常采用电视动画片的制作方法，即将一个连续的动
作分解为若干个非连续的子动作，通过定时器定时调用各个子动作，依靠人的视觉暂
留使动作看起来就好象是一组连续的动作。在VFP中可将分解的动作存于图像框内，
结合MOVE方法和计时器产生动画效果。
★实现目的：让蝴蝶展开翅膀飞起来。
★实现原理：设定三个蝴蝶图标，其中二个张开翅膀（或合上翅膀）、一个合上
翅膀（或张开翅膀）。将一个图标作为移动的蝴蝶(设置为可见)，其它两个图标设置
为不可见。利用timer控件的Interval属性设置的时间间隔来交替切换张开翅膀和合
上翅膀两个图标，达到蝴蝶拍动翅膀，"动起来"的效果。再利用控件的MOVE方法达
到蝴蝶"飞起来"的效果。图标如下:

文件名: BFLY1.BMP BFLY2.BMP

★应用实例：在VFP 5.0中实现动画功能。
实例一:实现"让蝴蝶动起来"的动画效果。用于应用系统的帮助说明。
① 建立含有如下控件的窗体FORM:
控件 CAPTION NAME FORECOLOR FONTSIZE PICTURE
窗体 实现"让蝴蝶动起来"的动画效果。 FORM1
标签 实例一:实现"让蝴蝶动起来"的动画效果。LABEL1 0,0,255 12
标签 编制者:蔡可训 1998年7月16日 LABEL2 255,0,0 12
图像框 BTRFLY BFLY2.BMP
图像框 BTRFLY1 BFLY1.BMP
图像框 BTRFLY2 BFLY2.BMP
命令按钮 退 出 COMMAND1

②程序清单：
在FORM1_ACTIVATE事件中，输入下列语句:
public flap
flap=0 &&定义控制是张开翅膀还是合上翅膀位图的切换变量
thisform.btrfly.visible=.t.
thisform.btrfly1.visible=.f.
thisform.btrfly2.visible=.f.
thisform.timer1.interval=200
在TIMER1_TIMER事件中，输入下列语句:
if flap=0 &&交替切换两幅位图
thisform.btrfly.Picture=thisform.btrfly1.Picture &&换上张开翅膀位图
flap=1
else
thisform.btrfly.Picture=thisform.btrfly2.Picture &&否则为合上翅膀位图
flap=0
endi
在COMMAND1_CLICK事件中，输入下列语句:
release thisform

实例二:实现"让蝴蝶飞起来"的动画效果。
① 建立含有如下控件的窗体FORM:
控件 CAPTION NAME FORECOLOR FONTSIZE PICTURE
窗体 实现"让蝴蝶飞起来"的动画效果。 FORM1
图像框 MAIN BFLY1.BMP
图像框 CLOSEWINGS BFLY2.BMP
图像框 OPENWINGS BFLY1.BMP
命令按钮 退 出 COMMAND1

②程序清单：
在FORM1_ACTIVATE事件中，输入下列语句:
public pickbmp
pickbmp=.t.
thisform.main.visible=.t.
thisform.openwings.visible=.f.
thisform.closewings.visible=.f.
thisform.timer1.interval=200
在TIMER1_TIMER事件中，输入下列语句:
thisform.main.move (thisform.main.left+20,thisform.main.top-5)
if thisform.main.left>thisform.width &&判别是否飞出窗体
thisform.main.move (20,thisform.height-20) &&将位图移到左下角准备向右飞
endi
if pickbmp &&交替切换两幅位图,同时将位图沿着一定轨迹移动。
thisform.main.picture=thisform.openwings.picture &&换上张开翅膀的位图
else
thisform.main.picture=thisform.closewings.picture &&换上合上翅膀的位图
endi
pickbmp=.not.pickbmp
在COMMAND1_CLICK退出事件中，输入下列语句:
release thisform
以上程序在同创P/200,WINDOWS 95,Visual Foxpro 5.0中文版软硬件环境下运
行通过。

返回页首

4、VFP中多媒体数据快速处理与实现技巧
黄云 何东

一. VFP与OLE技术

Visual FoxPro(以下简称VFP)是一种高级数据库应用程序开发系统，可利用OLE技术实现对象的链接与嵌入。为此 VFP在定义数据库(表)的过程中，提供了General字段，用以将各种媒体对象放入数据库中。并可用APPEND、MODIFY命令或系统菜单对数据库中的各种媒体对象进行输入、输出和编辑等操作。虽然VFP提供的OLE编程方式简单快捷，但在实际运行VFP程序的过程中，发现使用OLE方式处理多媒体数据运行效果并不理想，其原因在于：

⒈重复占用磁盘空间
笔者曾用General字段建立一个多媒体数据库。在进行多媒体数据入库操作后，发现备注文件（.FPT）的生成长度略大于原文件（.BMP、.WAV、.AVI）长度，且有些操作不能删除原文件，造成重复占用磁盘使用空间。

⒉运行速度慢
在VFP中利用OLE方法处理多媒体数据，访问磁盘的次数明显增加。由于频繁地读取磁盘数据，使得用户操作有明显的等待时间。

二. VFP中多媒体程序的设计与实现

为简化多媒体数据的管理，提高多媒体信息的输出速度，笔者对VFP中多媒体信息处功能、外部应用程序接口、