2023年十层框架剪力墙结构Ansys有限元大作业.docx

Ansys有限元大作业
十层框架剪力墙构造，X、Y方向均为两跨，每个开间均为5m*3m，是进行静力分析、模态分析、瞬态分析

1、 构造形式，截面参数材料参数简介
（1）命令流
FINI
/CLE
/FILNAME,YOUZUNI
/TITLE,KUANGJIA
/UNITS,SI
/PREP7
!材料
MP,EX,1,3.15e10 ! C35
MP,NUXY,1,0.25
MP,DENS,1,2500
MP,EX,2,3.15e10 ! C35楼板
MP,NUXY,2,0.25
MP,DENS,2,4000

!单元类型
ET,1,BEAM44
ET,2,SHELL63
!实常数
R, 1, 0 !梁截面
SECTYPE,1,BEAM,RECT,,0
SECOFFSET,CENT
SECDATA,0.300,0.700,2,2
! R, 2, 0 !柱截面
SECTYPE,2,BEAM,RECT,,0
SECOFFSET,CENT
SECDATA,0.500,0.500,2,2
R, 3, 0.12,0.12,0.12,0.12 !楼板截面

nn=7
*DO,J,0,nn
N,1+12*J,4,0,0+3*J
N,2+12*J,4,5,0+3*J
N,3+12*J,4,10,0+3*J
N,4+12*J,4,15,0+3*J
N,5+12*J,0,0,0+3*J
N,6+12*J,0,5,0+3*J
N,7+12*J,0,10,0+3*J
N,8+12*J,0,15,0+3*J
N,9+12*J,-4,0,0+3*J
N,10+12*J,-4,5,0+3*J
N,11+12*J,-4,10,0+3*J
N,12+12*J,-4,15,0+3*J
*ENDDO

TYPE,1 !梁
MAT,1
REAL,1
SECNUM,1
*DO,KK,13,1+12*nn,12
*DO,I,KK,KK+3,1
*DO,J,I,I+4,4
E,J,J+4

*ENDDO
*ENDDO
*ENDDO
*DO,KK,13,1+12*nn,12
*DO,I,KK,KK+8,4
*DO,J,I,I+2,1
E,J,J+1
*ENDDO
*ENDDO
*ENDDO

TYPE,1 !柱子
MAT,1
REAL,2
SECNUM,2
*DO,I,1,12*nn,1
E,I,I+12
*ENDDO

TYPE,2 !楼面
MAT,2
REAL,3
*DO,K,13,1+12*nn,12
*DO,I,K,K+4,4
*DO,J,I,I+2,1
E,J,J+1,J+5,J+4

*ENDDO
*ENDDO
*ENDDO

ALLSEL !施加约束
NSEL,S,LOC,Z,0
/SOLU
D,ALL,ALL,0
ALLSEL
FINISH

（2）成果

2、 静力分析命令流jingli.mac
/SOLU
ACEL,0,0,9.8
*DO,I,204,245,1
SFE,I,2,PRES,,500
*ENDDO

SOLVE
FINISH

!在所有荷载作用下旳变形图
/POST1
PLDISP,1

!位移云图
PLNSOL,U,SUM,0,1

!应力云图
PLNSOL,S,EQV,0,1

!输出支座反力
PRRSOL
（2）成果：
所有荷载作用下旳变形图

最大位移云图

最大应力云图

支座反力

3 模态分析
（1）命令流motai.mac
/SOLU
ANTYPE,MODAL
MODOPT,LANPCG,5,0,100
MXPAND,
ALLSEL
SOLVE
FINISH
!模态分析
/POST1
SET,LIST

SET,FIRST
PLNSOL,U,SUM,0,1

ANMODE,10,0.5, ,0
/ANFILE,SAVE,'animate-1stmodal','avi',' '

SET,NEXT
PLNSOL,U,SUM,0,1

SET,NEXT
PLNSOL,U,SUM,0,1

SET,NEXT
PLNSOL,U,SUM,0,1

SET,NEXT
PLNSOL,U,SUM,0,1
FINISH
（2）成果：前5 阶振型

第一阶振型 从位移分布可知为弯曲振型

第二阶振型 从位移分布可知为弯曲振型

第三阶振型 从位移分布可知为扭转振型

第四阶振型 从位移分布可知为弯曲振型

第五阶振型 从位移分布可知为弯曲振型
前五阶频率：

4、瞬态分析
（1） 命令流shuntai.mac
!瞬态分析

PI=3.1415926
C=0.05

/SOLU
ANTYPE,MODAL
MODOPT,LANB,2
MXPAND,
ALLSEL
SOLVE
FINISH

/POST1
*GET,FRE1,MODE,1,FREQ
*GET,FRE2,MODE,2,FREQ
A1=1./(2.*2.*PI*FRE1)
B1=2.*PI*FRE1/2.
BET=C/(FRE1+FRE2)/PI
ALF=(C-B1*BET)/A1

*DIM,DTAB,ARRAY,1,2
*VFILL,DTAB(1,1),DATA,FRE1
*VFILL,DTAB(1,2),DATA,FRE2
*CFOPEN,RESULT,TXT
*VWRITE,DTAB(1,1),DTAB(1,2)
(F8.4,5X,F8.4,5X)
*CFCLOSE
FINISH

/SOLU
ALLSEL,ALL
ANTYPE,TRANS
TRNOPT,FULL
NCNV,0,
ALPHAD,ALF
BETAD,BET
TIMINT,ON
KBC,0
FCUM,REPL

STEP=0.01
OUTPR,ALL,ALL,
OUTRES,ALL,ALL,
*DIM,WL_220,,4000,2
*VREAD,WL_220,WL4000,TXT,,JIK,2,4000
(2F15.3)

*DO,I,1,4000
TIME,I*STEP
ALLSEL
F,86,FX,WL_220(I,1)
F,86,FY,WL_220(I,2)
ALLSEL
SOLVE
*ENDDO
FINISH

/POST26
NSOL,2,86,U,X,UX_1
PLVAR,2
NSOL,3,88,U,Y,UY_1
PLVAR,3
ESOL,4,240,85,S,EQV,SEQV_1
PLVAR,4
RFORCE,5,8,F,X,FX_1
PLVAR,5
RFORCE,6,8,F,Y,FY_1
PLVAR,6
RFORCE,7,8,M,X,MX_1
PLVAR,7
RFORCE,8,8,M,Y,MY_1
PLVAR,8
FINISH
（2） 成果：
最大位移时程曲线

最大应力时程曲线
基底最大弯矩时程曲线

基底最大剪力时程曲线