查询方式按键.doc

【013】查询方式按键 [51]
点击数：684    发布日期：2006-6-25 0:57:00  
【收藏】 【评论】 【打印】 【编程爱好者论坛】 【关闭】

实验参考: 笨笨工作室-实验六、查询方式按键。(查看)
实验板:   FB51A。(查看)

实验目的: <1> 掌握读取外部按键时候应该注意的事项，掌握查询方式响应按键的方法。
　　　　　<2> 掌握读取按键去抖动的方法。
　　　　  <3> 掌握判直接寻址位转移指令jb，jnb的用法。

实验现象: 最右面的数码管初始显示0，每次按下外部按键K1执行加一，计数到9时重新回0。

单片机响应外部按键的方式有两种，一种是查询方式，一种是中断方式。

查询方式：单片机不断的查询是否有按键按下，如果有按键按下的话，就执行相应的程序，否则继续查询。

中断方式：单片机处理自己的工作，如果有按键按下，向单片机发出中断请求。单片机停下现在正在处理的工作，转去执行中断程序，执行之后回来继续刚才的工作。

本实验是用查询方式完成, 只用到一个键K1，每次按下，使第一位数码管加1显示，计数到9里重新回0。显示部分电路及查表显示方法参考:【005】数码管显示数字 和 【006】多位数码管动态显示。本来想重画个电路图，在原来显示部分的基础上再把按键部分加上，但一来放在Blog上宽度有问题，再者还是不想画了，所以偷个懒，键盘部分单独拿出来吧。

显示部分：

按键部分：

由原理图知：当按键k1按下的时候，对应P1.0输入低电平。因此，我们要查询k1是否按下，只要检测到p1.0是低电平即可。 在查询键是否按下时，要注意按键的去抖动问题，关于键的消抖，见 【012】按键消抖 。

按上述方法编写程序：

        org   0000h
start:  mov   p0, #48h       ; 段码-显示0
        mov   p2, #01h       ; 位码-选通第一位数码管
main:   mov   r7, #0ffh      ; 查表时偏移量，用来实现由0到9循环显示
key:    jb    p1.0, key      ; 如果P1.0为高电平,则继续执行此句查询。
        call  del10ms        ; 否则调用延时程序实现软件去抖
        jb    p1.0, key      ; 再次查询P1.0，如果是高电平，表示是抖动，继续查询

dis:                         ; 确定按键按下，开始执行显示程序
        inc   r7             ; 偏移量自加(第一次值为0)
        mov   a, r7
        mov   dptr, #tab     ; 取表首址
        movc  a, @a+dptr     ; 用查表指令获取要显示的数字
        mov   p0, a          ; 得到该字段码送入P0口显示
        cjne  a, #48h, key   ; 未显示到最后一个数, 继续查询按键状态
        ljmp  main           ; 显示到最后一个数字则重新开始

tab:    db    0ebh, 52h, 62h, 0e1h, 64h, 44h, 0eah, 40h, 60h, 48h ; 段码表
del10ms:                     ; 10ms延时子程序(12M)
         mov  r6, #20        ; 2机器周期
temp:    mov  r5, #248       ; 2机器周期
         djnz r5, $          ; 2机器周期 2＋2×248＝498
         djnz r6, temp       ; 2机器周期 2×20＝40
         ret                 ; 2＋20×498＋40＝10002 即10ms
end

★将该程序下载到板上验证发现很不稳定，按一次键时显示可能会变几次，如果按住键不放，将会显示“8”，且不停在闪烁，用Porteus仿真了一下也是这个问题。这是由于显示了一个数字之后，单片机会返回重新查询P1.0的状态，如果按下的时间很长，就会导致单片机又检测到低电平，所以就继续显示下一个数字，常按住的话就会循环此过程，所以看到的闪烁的“8”实际上是快速动态显示“0”到“9”时人眼的视觉暂留产生的。那如何使按下一次按键，无论时间长短，只作一次按键处理呢？可以在显示完一个数字后即检测P1.0是否回到高电平（键放开），若是，表示按键一次，继续执行显示下一个数; 若不是则原地等待直到P1.0返回高电平。按此思路在程序中将一个段码送入P0口显示之后，加一判断语句(红色）：

        org   0000h
start:  mov   p0, #48h       ; 段码-显示0
        mov   p2, #01h       ; 位码-选通第一位数码管
main:   mov   r7, #0ffh      ; 查表时偏移量，用来实现由0到9循环显示
key:    jb    p1.0, key      ; 如果P1.0为高电平,则继续执行此句查询。
        call  del10ms        ; 否则调用延时程序实现软件去抖
        jb    p1.0, key      ; 再次查询P1.0，如果是高电平，表示是抖动，继续查询

dis:                         ; 确定按键按下，开始执行显示程序
        inc   r7             ; 偏移量自加(第一次值为0)
        mov   a, r7
        mov   dptr, #tab     ; 取表首址
        movc  a, @a+dptr     ; 用查表指令获取要显示的数字
        mov   p0, a          ; 得到该字段码送入P0口显示
wait2:  jnb   p1.0, wait2    ; 等待按键松开
        cjne  a, #48h, key   ; 未显示到最后一个数, 继续查询按键状态
        ljmp  main           ; 显示到最后一个数字则重新开始

tab:    db    0ebh, 52h, 62h, 0e1h, 64h, 44h, 0eah, 40h, 60h, 48h ; 段码表
del10ms:                     ; 10ms延时子程序(12M)
         mov  r6, #20        ; 2机器周期
temp:    mov  r5, #248       ; 2机器周期
         djnz r5, $          ; 2机器周期 2＋2×248＝498
         djnz r6, temp       ; 2机器周期 2×20＝40
         ret                 ; 2＋20×498＋40＝10002 即10ms
end
★再下载到板上验证，可得到预测结果，用Porteus仿真如下(注：由于此Blog空间图片上传要求在100K以内，所以只模拟了0到5的循环，而实际上是从0到9循环的，那个文件做出来要144K，无法上传。在此仅作为模拟演示):

引用地址：