pic汇编实例.doc

MCD1实战一,LED8位流水灯《霹雳灯》
;该实战的目的作为学习和应用MCD1在线调试工具套件，进行项目的软件和硬件
;联合调试的范例程序，也就是当做一个用户程序实例，而演示板暂时充当用户电
;路的角色。这样就构成了一个软件、硬件齐全的自制项目模拟环境。
;本程序实现的功能是，把端口RC的8条引脚全部设置为输出模式，依次从引脚RC0
;到RC7送出高电平，然后再依次从引脚RC7到RC0送出高电平，并且周而复始，从而
;使得与该端口C相连的8只发光二极管LED循环依次点亮，其效果类似于一个简单的霹雳灯。
;该程序可用于PIC16F87X(A)所有系列
;PIC单片机学习网
;************************************************
;《霹雳灯》程序。文件名为“mcd-led1.ASM”
;**************************************************
status equ 3h ;定义状态寄存器地址
portc equ 7h ;定义端口C的数据寄存器地址
trisc equ 87h ;定义端口C的方向控制寄存器地址
flag equ 25h ;定义一个控制左移/右移的标志寄存器
;***********************************************************
org 000h ;定义程序存放区域的起始地址
nop ;放置一条ICD必须的空操用指令
bsf status,5 ;设置文件寄存器的体1
movlw 00h ;对端口C的方向控制码00H先送W
movwf trisc ;再由W转移到方向控制寄存器
bcf status,5 ;恢复到文件寄存器体0
movlw 01h ;将00000001B先送W
movwf portc ;再由W转移到数据寄存器
bsf flag,0 ;将左右移标志位置1,首先进行左移LED
bcf status,0 ;先清除C标志位
loop btfss status,0 ;测试进位/借位位,是1则修改标志
goto loop1 ;是0则不修改标志
comf flag,1 ;FLAG的BIT0作为标志位,把它取反
loop1 btfss flag,0 ;判断标志位，是1则跳到循环左移
goto loop2 ;是0则跳到循环右移
rlf portc,0 ;循环左移端口C数据寄存器，结果送W
movwf portc ;将结果再送回端口C的数据寄存器
goto loop3 ;跳过下面两条指令
loop2 rrf portc,0 ;循环右移端口C数据寄存器，结果送回W
movwf portc ;将结果再送回端口C的数据寄存器 ;
loop3 call delay ;调用廷时子程序
goto loop ;返回
;-------------------------廷时子程序----------------------------
delay ;子程序名，也是子程序入口地址
movlw 0ffh ;将外层循环参数值FFH经过W
movwf 20h ;送入用作外循环变量的20H单元
lp0 movlw 0ffh ;将内层循环参数值FFH经过W
movwf 21h ;送入用作内循环变量的21H单元
lp1 decfsz 21h,1 ;变量21H内容递减，若为0跳跃
goto lp1 ;跳转到LP1处
decfsz 20h,1 ;变量20H内容递减，若为0跳跃
goto lp0 ;跳跃到LP0处
return ;返回主程序
end ;源程序结束
;****************************************************************
; 进入该实战演练的工序流程如下:
; 1.软硬件的安装:按照本说明书前面讲的”MPLAB-ICD的安装和使用”一节内介绍的方法操作即可.
; 2.创建源文件和编辑源文件;在此介绍一种不同于前面讲的创建源文件的方法,用Windows附件中的”记事本”
; 这个为大家所熟知和好用的文件编辑器,并且可以方便的加入中文注释.不过有两点需要注意,一是注释前面的
; 分号”;”必须用西文半角输入;二是必须用”.asm”扩展名存储到事先建立的一个专用子目录下.
; 3.打开MPLAB集成开发环境:首先在WINDOWS环境下,选用开始>程序>Microchip MPLAB>MPLAB命令,启动MPLAB
; 并进入MPLAB的桌面.
; 4.创建项目:选用菜单File>New或Project>New Project,在事先建立的一个专用子目录下创建一个新项目,将
; 用记事本创建的源文件加入到该项目中.
; 5.建立项目中的目标文件:选择菜单Project >Build All(项目>建立所有文件),MPLAB将自动调用MPASM将项目
; 文件管理下的源文件(.asm)汇编成十六进制的目标文件(.hex).
; 6.ICD参数设置:通过菜单命令Project>Edit Project或者Option>Development Mode,将开发模式设置为
; ”MPLAB ICD Debugger”,点击OK按钮,打开ICD的工作窗口,在调试阶段,可以按照说明书图2-10设置各项,但需注意
; OSCILLATOR应设置为XT方式,尤其需要说明的是，选中“Enable Debug Mode”（使能调试模式）选项，在向目
; 标单片机烧写机器码程序时，会将调试临控程序同时写入单片机的指定程序存储器区域，然后才允许用ICD方式调试。
; 7.电路设置:将演示板的S1全部拔到ON，S4全部拔到OFF，S13的第5、第6、第7全部拔到OFF ，LCD不要插在演示板上，
; 以使端口C只与8只发光二极管接通;将用于选择频率的插针跳线插到”XT OSC”位置上.
; 8.向目标单片机烧写目标程序:用户在点击功能按钮”Program”向目标单片机烧写机器码程序时,会等待一段时间，
; 并且在条状的状态信息栏中，出现提示信息。有一点需要引起注意，就是PIC16F87X单片机的FLASH程序存储器的擦写
; 周期是有限的，大约为1000次，应尽量节省它的使用寿命。
; 9.运行和调试用户程序和用户电路:在各项参数设置好后,将ICD的工作窗口最小化,利用前面讲的”运行及调试”中介
; 绍的几种方法进行调试.当用自动单步方式调试时,建议临时禁止廷时子程序发挥作用,具体的方法是,可在CALL DELAY指
; 令前添加一个分号,并且重新汇编一次.为了学习目的,在调试过程中可以人为地加入一些软件漏洞(BUG)或硬件故障,来模
; 仿单片机端口引脚的片内或片外故障.
; 10.定型烧写目标单片机;经过多次重复上述步骤的反复修改和调试,使得程序和电路在联机状态完全正常,这时可以进行
; 定型烧写,即将ICD窗口中的”Enable Debug Mode”(使能调试模式)选项消除,不再将调试临控程序写入单片机中.
; 11.独立运行验收:上一步中的烧写过程完成后,即可将ICD模块和ICD仿真头(或演示板)之间的6芯电缆断开,让单片机在
; 演示板独立运行,观察实际效果.
;
;

;MCD1实战二：《单键触发8位二进制累加计数器》
;程序文件名为"MCD-LED2.ASM"
;PIC单片机学习网
;该程序的目的是让大家熟悉输入、输出端口的使用
;该程序的功能是把演示板当做一个按键计数器。刚刚接通电源时，8只发光二极管都不亮。
;表示计数器初值为0，当按下开关S3（RB0）时，计数器的值加1，发光二极管D3点亮，表示值1，然后松开
;按钮；再次按下开关S3（RB0）时，计数器的值又加1，发光二极管D4点亮，表示值2，依次类推，反复循环。
;程序清单：
;*************************************************
status equ 3h ;定义状态寄存器地址
portb equ 6h ;定义端口B的数据寄存器地址
trisb equ 86h ;定义端口B的方向控制寄存器地址
portc equ 7h ;定义端口C的数据寄存器地址
trisc equ 87h ;定义端口C的方向控制寄存器地址
data1 equ 20h ;定义一个廷时变量寄存器
data2 equ 21h ;定义另一个廷时变量寄存器
n1 equ d'13' ;定义一个外层循环廷时常数
n2 equ 0ffh ;定义一个内层廷时常数
rp0 equ 5h ;定义状态寄存器的页选位RP0
;*************************************************
org 000h ;定义程序存放区域的起始地址
nop ;放置一条ICD必须的空操作指令
bsf status,rp0 ;设置文件寄存器体1
movlw 00h ;将端口C的方向控制码00H先送W
movwf trisc ;再转到方向寄存器，将其设置为输出
movlw 0ffh ;同理，将端口B设置为输入
movwf trisb ;
bcf status,rp0 ;恢复到文件寄存器体0
movlw 00h ;送计器初值00H到RC口显示
movwf portc ;
check btfsc portb,0 ;测试S3按下否？是！跳过下条指令
goto check ;否！则循环检测
call delay ;调用廷时子程序，消除按钮抖动的影响
btfsc portb,0 ;再次测试S3按下否？是！跳过下条指令
goto check ;否！则循不检测
incf portc,1 ;端口C的数据寄存器加1，并送LED显示
check1 btfss portb,0 ;测试S3断开否？是！跳过下条指令
goto check1 ;否！则循不检测
call delay ;调用廷时子程序，消除按钮抖动的影响
btfss portb,0 ;再次测试S3断开否？是！跳过下条指令
goto check1 ;否！则循不检测
goto check ;返回
;*************10MS廷时子程序************************
delay ;子程序名，也是子程序入口地址
movlw n1 ;将外层循环参数值送到DATA1
movwf data1 ;
lp0 movlw n2 ;将内层循环参数值送到DATA2
movwf data2 ;
lp1 decfsz data2,1 ;变量DATA2内容递减，若为0则跳跃
goto lp1 ;跳转到LP1
decfsz data1,1 ;变量DATA1内容递减，若为0则跳跃
goto lp0 ;跳转到LP0
return ;返回主程序
end ;源程序结束
;***************************************************
; 进入该实战演练的工序流程如下:
; 1.软硬件的安装:按照本说明书前面讲的”MPLAB-ICD的安装和使用”一节内介绍的方法操作即可.
; 2.创建源文件和编辑源文件;在此介绍一种不同于前面讲的创建源文件的方法,用Windows附件中的”记事本”
; 这个为大家所熟知和好用的文件编辑器,并且可以方便的加入中文注释.不过有两点需要注意,一是注释前面的
; 分号”;”必须用西文半角输入;二是必须用”.asm”扩展名存储到事先建立的一个专用子目录下.
; 3.打开MPLAB集成开发环境:首先在WINDOWS环境下,选用开始>程序>Microchip MPLAB>MPLAB命令,启动MPLAB
; 并进入MPLAB的桌面.
; 4.创建项目:选用菜单File>New或Project>New Project,在事先建立的一个专用子目录下创建一个新项目,将
; 用记事本创建的源文件加入到该项目中.
; 5.建立项目中的目标文件:选择菜单Project >Build All(项目>建立所有文件),MPLAB将自动调用MPASM将项目
; 文件管理下的源文件(.asm)汇编成十六进制的目标文件(.hex).
; 6.ICD参数设置:通过菜单命令Project>Edit Project或者Option>Development Mode,将开发模式设置为
; ”MPLAB ICD Debugger”,点击OK按钮,打开ICD的工作窗口,在调试阶段,可以按照说明书图2-10设置各项,但需注意
; OSCILLATOR应设置为XT方式,尤其需要说明的是，选中“Enable Debug Mode”（使能调试模式）选项，在向目
; 标单片机烧写机器码程序时，会将调试临控程序同时写入单片机的指定程序存储器区域，然后才允许用ICD方式调试。
; 7.电路设置:将演示板的S1全部拔到ON，S4全部拔到OFF，S13的第1拔到ON、第5、第6、第7全部拔到OFF ，LCD不要插在演示板上，
; 以使端口C只与8只发光二极管接通;将用于选择频率的插针跳线插到”XT OSC”位置上.
; 8.向目标单片机烧写目标程序:用户在点击功能按钮”Program”向目标单片机烧写机器码程序时,会等待一段时间，
; 并且在条状的状态信息栏中，出现提示信息。有一点需要引起注意，就是PIC16F87X单片机的FLASH程序存储器的擦写
; 周期是有限的，大约为1000次，应尽量节省它的使用寿命。
; 9.运行和调试用户程序和用户电路:在各项参数设置好后,将ICD的工作窗口最小化,利用前面讲的”运行及调试”中介
; 绍的几种方法进行调试.当用自动单步方式调试时,建议临时禁止廷时子程序发挥作用,具体的方法是,可在CALL DELAY指
; 令前添加一个分号,并且重新汇编一次.为了学习目的,在调试过程中可以人为地加入一些软件漏洞(BUG)或硬件故障,来模
; 仿单片机端口引脚的片内或片外故障.
; 10.定型烧写目标单片机;经过多次重复上述步骤的反复修改和调试,使得程序和电路在联机状态完全正常,这时可以进行
; 定型烧写,即将ICD窗口中的”Enable Debug Mode”(使能调试模式)选项消除,不再将调试临控程序写入单片机中.
; 11.独立运行验收:上一步中的烧写过程完成后,即可将ICD模块和ICD仿真头(或演示板)之间的6芯电缆断开,让单片机在
; 演示板独立运行,观察实际效果.
;

;实战三、《花样LED闪烁灯》
;该实战的目的是让大家进一步熟悉IO口输入输出的的使用
;随着大家对程序指令的进一定熟悉,本实例减略了简单的注释
;通过前面的实例大家对PIC16F87X(A)的寄存器已经有了初步的认识,本实例不再
;单独定义寄存器,引入了PIC16F877的预定义文件
;PIC单片机学习网 陈学乾
;程序名为"MCD-LED3.ASM"
;*************************************************
;* 本程序是一个LED灯的循环闪烁程序,用INT键(S3)来切换*
;* 闪烁模式 *
;*************************************************
include <p16f877.inc>
;*----
MODESEL equ 20h
MODESELB equ 21h
Count equ 22h
Count1 equ 23h
Count2 equ 24h
PORTDB equ 25h

;*-----

org 0
nop
goto start
org 4
goto ISR

org 10
start
clrf PORTC ;清D口
movlw 00h
movwf MODESEL ;初始化模式选择寄存器
movwf MODESELB
movlw b'10010000'
movwf INTCON ;初始化中断控制
bsf STATUS,RP0
clrf TRISC ;设C口全为输出
movlw b'10111111'
OPTION ;选择INT下降沿有效

bcf STATUS,RP0
call FMsel
movwf PORTDB
movwf PORTC
main btfsc PORTB,0 ;\
goto $+6 ; \
call Delay ; 按键去抖动
btfsc PORTB,0
goto $+3 ; /
call FMsel ;/
movwf PORTDB
movf MODESELB,W ;
movwf MODESEL ;
call LongDelay
bcf STATUS,C
rlf PORTDB,1
btfsc STATUS,C
bsf PORTDB,0
movf PORTDB,W
movwf PORTC
goto main

;*----------
Delay ; call指令占用2个指令周期
clrf Count ; 清 Count占用1个指令周期
Dloop
decfsz Count,f ; 这两行指令将延时
goto Dloop ; (256 * 3) -1 个指令周期
return ; return占用2个指令周期

;*----------------
LongDelay
clrf Count
clrf Count1
movlw 0x01
movwf Count2
LDloop
decfsz Count,f
goto LDloop
decfsz Count1,f
goto LDloop
decfsz Count2,f
goto LDloop
return

;*---------------
FMsel
movf MODESEL,w
movwf MODESELB
movf MODESEL,w
addwf PCL
retlw b'11111000'
retlw b'11110000'
retlw b'11100000'
retlw b'11000000'
retlw b'10000000'
movlw 00h
movwf MODESELB
bsf INTCON,GIE
retlw b'11111000'
return

;*-------------
ISR
btfss INTCON,INTF
goto $+3
bcf INTCON,INTF
incf MODESEL
retfie
end
;****************************************************
; 进入该实战演练的工序流程如下:
; 1.创建源文件和编辑源文件;在此介绍一种不同于前面讲的创建源文件的方法,用Windows附件中的”记事本”
; 这个为大家所熟知和好用的文件编辑器,并且可以方便的加入中文注释.不过有两点需要注意,一是注释前面的
; 分号”;”必须用西文半角输入;二是必须用”.asm”扩展名存储到事先建立的一个专用子目录下.
; 2.打开MPLAB集成开发环境:首先在WINDOWS环境下,选用开始>程序>Microchip MPLAB>MPLAB命令,启动MPLAB
; 并进入MPLAB的桌面.
; 3.创建项目:选用菜单File>New或Project>New Project,在事先建立的一个专用子目录下创建一个新项目,将
; 用记事本创建的源文件加入到该项目中.
; 4.建立项目中的目标文件:选择菜单Project >Build All(项目>建立所有文件),MPLAB将自动调用MPASM将项目
; 文件管理下的源文件(.asm)汇编成十六进制的目标文件(.hex).
; 5.ICD参数设置:通过菜单命令Project>Edit Project或者Option>Development Mode,将开发模式设置为
; ”MPLAB ICD Debugger”,点击OK按钮,打开ICD的工作窗口,在调试阶段,可以按照说明书图2-10设置各项,但需注意
; OSCILLATOR应设置为XT方式,尤其需要说明的是，选中“Enable Debug Mode”（使能调试模式）选项，在向目
; 标单片机烧写机器码程序时，会将调试临控程序同时写入单片机的指定程序存储器区域，然后才允许用ICD方式调试。
; 6.电路设置:将演示板的S1全部拔到ON，S4全部拔到OFF，S13的第1拔到ON、第5、第6、第7全部拔到OFF ，LCD不要插在演示板上，
; 以使端口C只与8只发光二极管接通;将用于选择频率的插针跳线插到”XT OSC”位置上.
; 7.向目标单片机烧写目标程序:用户在点击功能按钮”Program”向目标单片机烧写机器码程序时,会等待一段时间，
; 并且在条状的状态信息栏中，出现提示信息。有一点需要引起注意，就是PIC16F87X单片机的FLASH程序存储器的擦写
; 周期是有限的，大约为1000次，应尽量节省它的使用寿命。
; 8.运行和调试用户程序和用户电路:在各项参数设置好后,将ICD的工作窗口最小化,利用前面讲的”运行及调试”中介
; 绍的几种方法进行调试.当用自动单步方式调试时,建议临时禁止廷时子程序发挥作用,具体的方法是,可在CALL DELAY指
; 令前添加一个分号,并且重新汇编一次.为了学习目的,在调试过程中可以人为地加入一些软件漏洞(BUG)或硬件故障,来模
; 仿单片机端口引脚的片内或片外故障.
; 9.定型烧写目标单片机;经过多次重复上述步骤的反复修改和调试,使得程序和电路在联机状态完全正常,这时可以进行
; 定型烧写,即将ICD窗口中的”Enable Debug Mode”(使能调试模式)选项消除,不再将调试临控程序写入单片机中.
; 10.独立运行验收:上一步中的烧写过程完成后,即可将ICD模块和ICD仿真头(或演示板)之间的6芯电缆断开,让单片机在
; 演示板独立运行,观察实际效果.
;

;实战四《简易四路抢答器》
;该抢答器供不多于4个参赛队或者个人的抢答比赛场合使用。每个参赛队的座位前
;安装1只抢答按钮开关（用板上的S9、S10、S11、S12）和一个信号灯（D4、D5、D6、D7）。
;主持人座位前装一只复原开关（板上S3）、1只蜂鸣器（板上BUZ1）和一个抢答器工作状态
;指示灯（D10),每当主持人口头发出号令之后.哪个队先按下座位上的按钮开关,该座位的信
;号灯就先被点亮,同时封锁其他按钮开关的活动.并且熄灭主持人座位上的状态指示灯和发出
;三声类似于电话振铃的提示声,以声明此次抢答动作已经完成.在主持人确认后,按下复原按钮
;,状态指示灯重新点亮,并且同时发出"笛-笛-"声,为下一次抢答作好准备.
;PIC单片机学习网 陈学乾
;程序文件名:"MCD-INTBUZ.ASM"
;*********************************************************************
;程序清单
;*********************************************************************
tmr0 equ 1h ;定义定时器/计数器0寄存器地址
status equ 3h ;定义状态寄存器地址
option_reg equ 81h ;定义选项寄存器地址
option_temp equ 0a6h ;（在BACK1）定义选项寄存器的备份寄存器的地址
intcon equ 0bh ;定义中断控制寄存器地址
portc equ 7h ;定义端口RC的数据寄存器地址
trisc equ 87h ;定义端口RC的方向控制寄存器地址
portb equ 06h ;定义端口RB的数据寄存器地址
trisb equ 86h ;定义端口RB的方向控制寄存器地址
c equ 0 ;定义进位标志位的位地址
z equ 2 ;定义0标志位的位地址
w equ 0 ;定义传送目标寄存器为W的指示位
f equ 1 ;定义传送目标寄存器为RAM的指示位
t0if equ 2 ;定义TMR0中断标志位的位地址
t0ie equ 5 ;定义TMR0中断使能位的位地址
inte equ 4 ;定义外部中断使能位的位地址
intf equ 1 ;定义外部中断标志位的位地址
count equ 20h ;定义一个计数器变量
count1 equ 24h ;定义一个计数器变量
count2 equ 25h ;定义一个计数器变量
count3 equ 27h ;定义一个计数器变量
count4 equ 28h ;定义一个计数器变量
portb_b equ 21h ;为PORTC定义一个备份寄存器
w_temp equ 7fh ;为W在体0和体1定义2个备份寄存器
;w_temp equ 0ffh ;（若是16F873/4，则需保留FFH单元）
status_temp equ 23h ;为STATUS定义一个备份寄存器
rp0 equ 5h ;定义状态寄存器中的页选位RP0
;******************复位向量和中断向量***********************
org 000h ;
nop ;设置一条ICD必须的空操作指令
goto main ;
org 0004h ;
goto serv ;跳转到中断服务子程序
;*******************主程序************************************
main
bsf status,rp0 ;
movlw 0 ;
movwf trisc ;设置RC口全部为输出
movlw 0ffh ;
movwf trisb ;设置RB口全部为输入
movlw 02h ;设置选项寄存器：上拉电阻启用；INT下降沿触发
movwf option_reg ;分频器给TMR0；分频比1：8
bcf status,rp0 ;
movlw 90h ;
movwf intcon ;开发INT中断
clrf portc ;RC口灯全灭
loop
movf portb,w ;读取RB口数据
iorlw b'11100001' ;送RB口的数到备份寄存器并将除S9、S10、S11、S12以外的位全部送1
movwf portb_b ;
xorlw 0ffh ;没有键按下转LOOP继续检测
btfsc status,z ;
goto loop ;
call delay10ms ;防抖动廷时
movf portb,w ;
iorlw b'11100001' ;
xorwf portb_b,0 ;再次读取RB口的数据，与前一次读的数相同则键值有效
btfsc status,z ;
goto loop ;
comf portb_b,w ;取反以便使被按下按键的位为1，其它位为0
movwf portc ;送RC口显示
call tone3t ;调用发声三次子程序
loop1
comf portb,w ;检测按键是否有松开
andlw b'00011110' ;
btfsc status,z ;
goto loop ;松开了返回
goto loop1 ;没松开继续检测
;*********************中断服务子程序*****************************
serv
;********************保存护现场部分*******************************
movwf w_temp ;保护W
swapf status,w ;保护STATUS
clrf status ;选择体0
movwf status_temp ;将STATUS存入体0的备份寄存器
;********************* 调查中断源**********************************
btfsc intcon,intf ;检查不是INT中断，返回
goto intserv ;是！转到INT中断处理部分
goto retfie0 ;
;*********************INT中断处理部分******************************
intserv