电子音乐盒(单片机课程设计).doc

电子音乐盒
1、设计任务和要求 1
2、总体设计 1
3、硬件设计 2
3.1 硬件电路 2
3.2 原理说明 2
4、软件设计 3
5、仿真、安装和调试 3
6、收获与体会 4
参考文献 5
附件1：元件清单 6
附件2: 总电路图 7
附件3：音乐程序 8

单片机课程设计报告

音乐盒设计
1、设计任务和要求
(1)利用I/O口产生一定频率的方波，驱动蜂鸣器，发出不同的音调，从而演乐曲(内存两首乐曲)。
(2)采用七段数码管显示当前播放的歌曲序号。
(3)可通过功能键选择乐曲，暂停，播放，上一曲，下一曲。
2、总体设计
(1)要产生音频脉冲，只要算出某一音频的周期(1/音频),然后将此周期除以2,即为半周期的时间,利用定时器计时这个半周期时间,每当计时到后就将输出脉冲的I/O反相,然后重复计时此半周期时间再对I/O口反相,就可在I/O脚上得到此频率的脉冲
(2)利用8051的内部定时器使其工作在计数器模式MODE1下,改变记数值TH0及TL0以产生不同频率的方法。例如频率为523HZ,其周期T=1/523=1912微秒,因此只要令计数器定时956/1=956在每记数9次时将I/O口反相,就可得到中音D0(523HZ)。
记数脉冲值与频率的关系公式如下：
N=Fi/2/Fr N：记数值
　　　　Fi：内部计时一次为1微秒．故其频率为1MHZ
　　 Fr；要产生的频率
(3)：起记数值的求法如下：
T＝65536－N＝65536－Fi／2／Fr
例如：设K＝65536，F＝1000000＝Fi＝1MHZ，求低音D0（523HZ），高音的D0（1046HZ）的记数值。
T＝65536－N＝65536－Fi／2／Fr＝65536－1000000／2／Fr＝65536－500000／Fr
低音D0的T＝65536－500000／262＝63627
中音D0的T＝65536－500000／523＝64580
低音D0的T＝65536－500000／1047＝65059
3、硬件设计
3.1 硬件电路
本设计中用到89C51单片机，喇叭，七段显示数码管LED。（硬件电路原理图如图1所示）
3.2 原理说明
当键盘有键按下时，判断键值，启动计数器T0，产生一定频率的脉冲，驱动蜂鸣器，放出乐曲。同时启动定时器T1,显示歌曲号。
（1） 硬件电路中用、分别接S1、S2作为上、下一曲的功能键
（2） 用P1.0-P1.6控制七段码a,b,c,d,e,f。
（3） 用P2.0口控制喇叭。
（4） 电路为12MHZ晶振频率工作，起振电路中C1,C2均为30pf。

图1 音乐盒原理图
4、软件设计
本程序可以实现课程设计的基本要求，并可以通过按键播放两首歌曲，程序流程图如下：

开始
初始化
设置音节起始位置
设置节拍间距
读取音阶，音符
显示当前播放歌曲序号
节拍结束
音乐结束

5、仿真、安装和调试
按照上面设计的电路在proteus软件内画图, 打开单片机软件开发系统Keil,选择89c51单片机,在其中编写程序,运行生成一个后缀名为hex的文件,然后将该文件下载到proteus中的AT89c51单片机中进行仿真,观察实验现象。仿真能实现播放音乐，按键选择曲目，暂停，播放功能。仿真成功后，安装好实验板,然后将音乐程序下载到电路板内 ,观察结果。能实现播放音乐，按键换曲等功能。
程序调试中出现的问题及解决的办法：
（1） 有时会出现程序一点错误也没有，但就是不能正常运行的现象，最后我们发现是因为程序中有的指令书写得不规范导致的，例如有的RET返回指令一定要按正确格式书写或在两行指令间最好不要留空行。
（2） 程序中的跳转指令的运用很重要，为保险起见，都用LJMP,我们就遇到过跳转指令用错程序无法正常运行的现象。当用JNZ指令时，跳转范围比较少，这时要用一个标号中转。
（3） 编程时要注意，在程序开始时，要写入各定时器中断的入口地址。
（4） 编程过程中要注意加注释或分割线，否则，在程序过长时容易变得很乱，不便于查找或更改。
（5） 编程前要加流程图，这样会使思路清晰，例如数字音乐盒的设计思路完全可以按着MP3的工作方式列写流程图。
（6） LCD计时正常显示的解决办法：
a. 两个定时器同时工作，存在中断时序问题，刚开始时我们把定时器1设定在方式3，计250us，由于定时中断过于频繁，使CPU负载过大，导致音乐不能正常播放，时间不能正常显示。
解决办法：将定时器1设定在工作方式1，16位计数，计50ms,效果有很大改观。但还有问题。
b. 当音乐为全4拍起始时，此时音乐节奏与定时器T1中断频率错开，LCD显示和音乐播放都会好一些。
c. 另外，在歌曲中，当遇到一个音符发音为4拍，在编曲中为*CH，因时间较长，当定时器T1此时来中断时，就会对歌曲播放产生影响，若改为发音一拍，中断对歌曲播放影响减弱，但音乐效果变差。
改进方案：若采用可以定时时间更长的单片机，可以避免所有问题。
6、收获与体会
(1) 上学期学习单片机的课时不多，对单片机的硬件设计，软件设计掌握的深度不够，但通过此次课程设计，明显的改善了，首先对于硬件电路的工作原理有了进一步的学习，同时有了一个提升；软件方面，在程序的设计，程序的调试方面都有了很大的进步。
(2) 在一个好的氛围里才能踏下心来做东西，在这一段时间里，寝室成员都认真对待这次课程设计，除了自己做好自己的课题外，在遇到不懂的地方互相讨论，查阅资料，互助解决问题。另外在编程中出现问题时，一定要戒骄戒躁，脚踏实地，认真看书，仔细分析，仔细调试，就一定会发现错误。我们也是这么做的，这一点在这次的课程设计中十分重要。
(3) 通过这次课程设计，我体会到了成功的喜悦，听着自己设计的程序下载到单片机中播放出音乐,心理非常自豪。这次的课程设计在一定程度上改变了我学习单片机这门课程的态度，从最初的认为学它没有什么实际意义，到如今爱上单片机学习，并希望能将理论运用到实践，设计出更好更完整的系统。我明白了一个人要想做好一件事，就必须具备自信心，耐心，还要有毅力，要胆大心细，要勇于尝试，要手脑并用，最后才能交出一份令人满意的答卷。

参考文献
[1] 许珉.单片机原理及应用[M].北京:中国电力出版社,2007.08
[2] 三恒星科技.MCS-51单片机原理与应用实例[M]. 北京：电子工业出版社，2008.01
[3] 王为青，程国钢.单片机Keil Cx51应用开发技术[M]. 北京：人民邮电出版社,2007.02
[4] John Markus.电子电路大全[M].北京：计量出版社，1995
[5] 阎石.数字电子技术基础[M].北京：高等教育出版社，1998.12，第4版
[6] 邓元庆.数字电路与逻辑设计[M].北京：电子工业出版社，2001
[7]

附件1：元件清单
名称
数量（个）
型号
备注
电阻
6

排阻RX8(1个)1k(2个),5.5k(1个),10k(1个),15(1个)
数码管
1
7SEG-DIGITAL

开关
4

BUTTON
单片机
1
AT89C51

三极管
1
2N3906

扬声器
1

SPEAKER
电源
2

5V
电容
3

30pf(2个),10uf(1个)
晶振
1

CRYSTAL

附件2:总电路图

附件3：音乐程序
OUT BIT P2.0 ;定义音频输出端口,p2.0
N EQU 6 ;歌曲总数
OUT_NUM EQU P1 ;数码管显视当前所放歌曲曲数
ORG 0000H
AJMP MAIN
ORG 0003H
AJMP LAST_SONG ;外部中断0用于接上一曲歌按键
ORG 000BH
AJMP F_T0 ;定时器0用于定时，作音符发生器用
ORG 0013H
q4: AJMP NEXT_SONG ;外部中断1接下一曲歌按键
ORG 001BH
AJMP START_PAUSE ;定时器1用计数，这里用作中断，接开始/暂停键,初值为0ffH，方式2
ORG 0030H
MAIN: MOV SP,#60H
MOV DPTR,#TABLE ;DPRT指向每首歌曲的入口地址的地址。
MOV R0,#30H ;R0中存入数据30H，这里在以30H开始的单元存放每首歌曲的入口地址，其中30H,31H存放
;歌曲的节拍入口地址，32H，33H存放歌曲音符入口地址，每首歌占用四个存储存单元。
MOV R5,#00H ;R5中存放表TABLE中正在执行操作的序号
MOV R6,#1 ;R6存放正在设置入口信息的歌曲数
SET_TAB: MOV A,R5 ;设置每首歌曲的入口信息，存放在以30H开始的存储单元中。
MOVC A,@A+DPTR
MOV @R0,A
INC R5
INC R0
MOV A,R5
MOVC A,@A+DPTR
MOV @R0,A
INC R5
INC R0
MOV A,R5
MOVC A,@A+DPTR
MOV @R0,A
INC R0
INC R5
MOV A,R5
MOVC A,@A+DPTR
MOV @R0,A
INC R0
INC R5
INC R6 ;设置完一首歌曲后，歌曲数加一
CJNE R6,#N+1,SET_TAB ;是否设置完，没有便继续，否则进行下面的操作
;*********************************** 对中断，计数器的相关参数进行设置
MOV TMOD, #61H ;计数器0工作方式1，计数器1工作方式2
MOV TH1,#0FFH ;给计数器1置初值0FFH，又由于是工作方式2，所以
MOV TL1,#0FFH ;计数器计数为1，相当于一外部中断。
SETB ET1 ;允许计数器1中断
SETB ET0 ;允许计数器具0中断
CLR PT0 ;计数器0为低优先级
SETB PT1 ;计数器1为高优先级
SETB IT0 ;外部中断0为跳沿触发
SETB PX0 ;高优先级
SETB IT1 ;外部中断1为跳沿触发
SETB PX1 ;高优先级
SETB EX1 ;允许外部中断1中断
SETB EX0 ;允许外部中断定0中断
SETB EA ;开中断总开关
SETB TR1 ;定时器1开始工作，作中断用
SETB OUT ;音频输出端口初始化
;*********************************** ;设置结束
CLR F0 ;设置F0=0，用来作暂停/播放的标置位用
MOV 22H,#01H ;22H单元中存放正在播放的歌曲编号
MOV DPTR,#OUT_TAB ;将正在播放的歌曲编号送数码管显视
MOV A,22H
MOVC A,@A+DPTR
MOV OUT_NUM,A
MOV R7,#00H ;R7中存放歌曲总信息的入口地址
START0:MOV R4,#00H ;R4存放当前正在播放歌曲的第几个节拍数
MOV R0,#30H ;30H开始的单元中存放歌曲的入口信息
MOV A,R7 ;将歌曲的节拍表的入口地址送到DPTR
ADD A,R0
MOV R0,A
MOV DPH,@R0
INC R0
MOV DPL,@R0
INC R0
MOV A,R4
INC R4
MOVC A,@A+DPTR ;取出第一节拍数,其实第一个节拍不是歌曲的第一个节拍，而是表示几分音符
;****************************************************
MOV 26H,A ;将取出的音符数+节拍数保存在职26H单元中
NEXT: MOV R0,#30H ;开始取出歌曲的第一个数据
MOV A,R7
ADD A,R0
MOV R0,A
MOV DPH,@R0
INC R0
MOV DPL,@R0
INC R0
MOV A,R4
INC R4
MOVC A,@A+DPTR ;放在A中
;****************************************************
JZ END0 ;若为0，则表示为休止符，不唱，本次音符不唱，
MOV R1,A ;不为0，取出节拍数
ANL A,#0FH
MOV R2,A
MOV A,R1
SWAP A
ANL A,#0FH
JNZ SING ;音符不为0，唱
CLR TR0 ;为0，不唱,关频率发生器
SJMP SING1
SING: DEC A ;开始唱,进行相应的数据处理
MOV R3,A
RL A
MOV DPH,@R0
INC R0
MOV DPL,@R0
INC R0
MOVC A,@A+DPTR
MOV 21H,A
MOV TH0,A
MOV A,R3
RL A
INC A
MOVC A,@A+DPTR
MOV 20H,A
MOV TL0,A
SETB TR0 ;开唱
SING1:LCALL DELAY ;每个音符唱多久
JB F0,FOR ;是否暂停，
AJMP NEXT ;没有暂停，继续
FOR: CLR TR0 ;暂停，不唱
JB F0,$ ;等待播放
AJMP NEXT ;开始播放
END0: CLR TR0 ;不唱
MOV A,22H ;唱完处理
CJNE A,#N,WW ;是不是全部歌曲都唱完
MOV 22H,#01H ;全部唱完，则从第一首开始再唱
MOV R7,#00H
MOV OUT_NUM,#11111001B ;数码管显视第一首歌曲编号
AJMP WWW
WW: MOV A,R7 ;没有全部唱完，唱下一首,歌曲的入口信息调整
ADD A,#4
MOV R7,A
INC 22H
CLR EA
PUSH DPH
PUSH DPL
MOV A,22H
MOV DPTR,#OUT_TAB
MOVC A,@A+DPTR
MOV OUT_NUM,A ;数码管显视相应的歌曲编号
POP DPL
POP DPH
WWW: SETB EA
AJMP START0 ;开始下一首的演唱
F_T0: MOV TH0,21H ;定时器0置初值
MOV TL0,20H
CPL OUT ;频率产生
RETI
NEXT_SONG: PUSH ACC ;下一曲中断程序处理，保护现场
PUSH DPH
PUSH DPL
CLR EA ;关中断
MOV A,22H
CJNE A,#N,Q ;是最后一首吗？
MOV R7,#00H ;是最后一首，则R7指向第一首，演唱第一首
MOV 22H,#01H
AJMP BACK
Q: INC 22H ;不是最后一首，唱下一首,R7内容加4，歌曲数加1
MOV A,R7
ADD A,#4
MOV R7,A
BACK: MOV R4,#00H ;数码管显视相应的歌曲编号
MOV A,22H
MOV DPTR,#OUT_TAB
MOVC A,@A+DPTR
MOV OUT_NUM,A
;********************************************
MOV B,R0 ;对下首要演唱的歌曲的几分拍进行调整,同时对R0中的内容进行保护
MOV R4,#00H
MOV R0,#30H
MOV A,R7
ADD A,R0
MOV R0,A
MOV DPH,@R0
INC R0
MOV DPL,@R0
INC R0
MOV A,R4
INC R4
MOVC A,@A+DPTR
MOV 26H,A ;结果存入26H单元中
DEC R4
MOV R0,B ;恢复R0中的内容
;********************************************
POP DPL ;恢复现场
POP DPH
POP ACC
SETB EA
RETI ;中断返回
LAST_SONG: PUSH ACC ;上一曲中断程序处理开始，保护现场
PUSH DPH
PUSH DPL
CLR EA ;关中断
MOV A,22H ;曲目数送A
CJNE A,#1,QQ ;是否是第一首
MOV 22H,#N ;是第一首歌曲
MOV B,#4 ;将R7指向最后一首歌曲
MOV A,#N-1
MUL AB
MOV R7,A
AJMP BACK2 ;处理结束
QQ: DEC 22H
MOV A,R7 ;R7减4
SUBB A,#4
MOV R7,A
BACK2: MOV R4,#00H
MOV A,22H
MOV DPTR,#OUT_TAB
MOVC A,@A+DPTR
MOV OUT_NUM,A ;数码管显视相应歌曲的编号
;********************************************
MOV B,R0 ;对下首要演唱的歌曲的几分拍进行调整,同时对R0中的内容进行保护
MOV R4,#00H
MOV R0,#30H
MOV A,R7
ADD A,R0
MOV R0,A
MOV DPH,@R0
INC R0
MOV DPL,@R0
INC R0
MOV A,R4
INC R4
MOVC A,@A+DPTR
MOV 26H,A ;结果存入26H单元中
DEC R4
MOV R0,B ;R0中的内容恢复
;********************************************
POP DPL ;恢复现场
POP DPH
POP ACC
SETB EA
RETI ;中断返回
START_PAUSE:CPL F0 ;开始/暂停中断处理程序，将标置位取反
JB F0,RETURN ;为1返回
SETB TR0 ;为0则播放
RETURN: RETI ;中断返回
DELAY: MOV 27H,26H ;音符演奏时间控制
D2: MOV 28H,#125
D3: MOV 29H,#248
DJNZ 29H,$
DJNZ 28H,D3
DJNZ 27H,D2
DJNZ R2,DELAY
RET
;OUT_TAB: DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH,77H,7CH,39H,5EH,79H,71H,73H ;共阴数码管显视用
OUT_TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,88H,83H,0C6H,0A1H,86H,8EH,0FFH ;共阳
TABLE: DW SONG1,TABLE1,SONG2,TABLE2,SONG3,TABLE3,SONG4,TABLE4 ,SONG5,TABLE5
TABLE1:DW 64580,64684,64777,64820,64898,64968,65030
DW 63628,63835,64021,64103,64260,64400,64524
SONG1: DB 04H ;1=C 2/4 军港之夜
DB 32H,54H,52H,32H,54H,52H,32H,12H,12H,32H,32H,54H,52H,32H,52H,52H,32H,32H,21H,31H,24H,0E2H,0D1H,0E1H,0D2H,0C2H,14H,14H
DB 0C2H,32H,32H,12H,21H,31H,24H,32H,34H,0D2H,0C2H,14H,14H,32H,52H,52H,32H,52H,54H,32H,34H,31H,21H,12H,24H,24H
DB 34H,0E2H,0C2H,0D1H,0E1H,0D4H,12H,0E2H,32H,32H,0E2H,0D1H,0E1H,0D4H,0D2H,0E2H,32H,32H,0E2H,0E2H,0D1H,0E1H,0D4H
DB 22H,0D1H,11H,0E2H,0D2H,0C4H,0C4H,32H,52H,52H,32H,62H,5H,61H,54H,31H,52H,31H,12H,31H,31H,32H,54H,52H,32H,52H,52H,32H
DB 32H,21H,31H,24H,0E2H,0D1H,0E1H,0D2H,0C2H,34H,34H,32H,52H,52,32H,62H,51H,61H,54H,31H,52H,31H,12H,32H,12H,32H,32H,54H,52H
DB 32H,52H,52H,31H,31H,32H,21H,31H,24H,0E2H,0D1H,0E1H,0D2H,0C2H,14H,14H
DB 32H,52H,52H,32H,32H,21H,31H,24H,0E2H,0D1H,0E1H,0D2H,0C2H,14H,14H
DB 0C2H,32H,32H,12H,21H,31H,24H,32H,34H,0D2H,0C2H,14H,14H,32H,52H,52H,32H,52H,54H,32H,34H,31H,21H,12H,24H,24H
DB 34H,0E2H,0C2H,0D1H,0E1H,0D4H,12H,0E2H,32H,32H,0E2H,0D1H,0E1H,0D4H,0D2H,0E2H,32H,32H,0E2H,0E2H,0D1H,0E1H,0D4H
DB 22H,0D1H,11H,0E2H,0D2H,0C4H,0C4H,32H,52H,52H,32H,62H,5H,61H,54H,31H,52H,31H,12H,31H,31H,32H,54H,52H,32H,52H,52H,32H
DB 32H,21H,31H,24H,0E2H,0D1H,0E1H,0D2H,0C2H,34H,34H,32H,52H,52,32H,62H,51H,61H,54H,31H,52H,31H,12H,32H,12H,32H,32H,54H,52H
DB 32H,52H,52H,31H,31H,32H,21H,31H,24H,0E2H,0D1H,0E1H,0D2H,0C2H,14H,14H
DB 32H,52H,52H,32H,32H,21H,31H,24H,74H,0D2H,0C2H,14H,14H,14H,14H
DB 00H
TABLE2:DW 63835,64021,64103,64260,64400,64524,64580,64684,64777
DW 64820,64898,64968,65030,65058,65110,65157,65178
SONG2: DB 02H ;1=C 4/4 死了都要爱
DB 04H,94H
DB 0E8H,0E4H,0E4H,0E8H,0E4H,0F4H,0D4H,0C4H,0B4H,84H,84H,92H,92H,94H,92H,02H
DB 0A4H,0A2H,0B2H,0B4H,0C4H,84H,82H,92H,94H,0A4H
DB 04H,0C2H,0C2H,0D4H,0C2H,0D2H,0D8H,0D4H,0D2H,92H
DB 0E8H,0E4H,0E4H,0E8H,0E4H,0F4H,0D4H,0C4H,0B4H,84H,84H,92H,92H,94H,92H,02H
DB 0A4H,0A2H,0B2H,0B4H,0C4H,0E8H,0D8H
DB 0C8H,0C8H,08H,08H,78H,28H,38H,34H,24H
DB 24H,64H,64H,24H,64H,72H,72H,78H,58H,54H,44H,38H,34H,14H,34H,84H,74H,74H,62H,62H,0D8H,78H,28H,38H,34H,24H
DB 24H,64H,64H,24H,64H,72H,72H,72H,94H,92H,94H,0A4H,58H,58H,54H,44H ;#音不准
DB 58H,58H,58H,58H,0A8H,0A8H,0A4H,0B4H,0A4H,84H,0A4H,94H,98H,98H,08H
DB 84H,82H,82H,82H,82H,94H,0A2H,94H,92H,82H,74H,72H,74H,72H,72H,72H,72H,92H,91H,91H,94H,54H,74H,94H
;;*************************************************
DB 0A8H,0A4H,0A2H,0B2H,0C4H,0B4H,0A4H,0A4H,0A4H,92H,92H,98H,82H,72H,78H,04H,0A4H,0A2H,0B2H,0B4H,0C4H,84H,82H,92H,94H,0A4H
DB 04H,0C4H,0D4H,0C4H,0C8H,04H,94H
DB 0E8H,0E4H,0E4H,0E8H,0E4H,0F4H,0D4H,0C4H,0B4H,84H,84H,92H,92H,94H,92H,02
DB 0A4H,0A2H,0B2H,0B4H,0C4H,84H,82H,92H,94H,0A4H,04H,0C2H,0C2H,0D4H,0D8H,0D4H,0D2H,92H
DB 0E8H,0E4H,0E4H,0E8H,0E4H,0F4H,0D4H,0C4H,0B4H,84H,84H,92H,92H,94H,92H,02
DB 0A4H,0A2H,0B2H,0B4H,0C4H,84H,82H,92H,94H,0A4H,04H,0C2H,0C2H,0D4H,0D8H,0D4H,0D2H,92H
;*************
DB 0A4H,0A2H,0B2H,0B3H,0C4H,0E8H,0D8H
DB 0C8H,0C8H,0C8H,08H
DB 00H
TABLE3: DW 64898,64968,65030,65086,65135,65158,65199,64260,64400,64524,64580,64684,64777,64862
SONG3: DB 03H ;G=2/4 中华人民共和国国歌
DB 04H,04H,0C2H,14H,12H,12H,12H,11H,11H,0C2H,0D1H,0E1H,14H,14H,02H,32H,12H,21H,31H,52H,51H,51H,54H
DB 32H,31H,31H,12H,11H,31H,52H,51H,31H,24H,24H,24H,64H,54H,24H,34H,52H,34H,52H,32H,21H,31H,12H,11H,21H,34H,04H
DB 52H,51H,0D1H,12H,12H,32H,31H,31H,52H,51H,51H,22H,22H,22H,0D2H,0D1H,0D1H,24H,22H,0C2H,14H,12H,12H,34H,32H,32H,54H,54H,54H,54H
DB 12H,11H,31H,52H,51H,51H,64H,54H,32H,31H,11H,52H,52H,52H,32H,02H,12H,02H,0C4H,14H
DB 0A2H,0A1H,11H,52H,52H,52H,32H,02H,12H,02H,0C4H,14H,0C4H,14H,0C4H,14H,14H,04H
DB 04H,04H,04H,04H
DB 00H
TABLE4:DW 64260,64400,64524,64580 ,64684,64777,64280,64898,64968,65030,65058,65110,65157,65178,65217
SONG4:DB