用ANSYS建立钢筋混凝土梁模型.docx

______________________________________________________________________________________________________________
用ANSYS建立钢筋混凝土梁模型
问题描述：
钢筋混凝土梁在受到中间位移荷载的条件下的变形以及个组成部分的应力情况。
B=150mm
H=300mm
L=2000mm
P=5mm位移载荷
图1钢筋混凝土结构尺寸图

一、用合并节点的方法模拟钢筋混凝土梁
1．用solid65号单元以及beam188单元时
材料特性
钢材的应力应变关系

混凝土的弹性模量采用线弹性

建立钢筋线

对钢筋线划分网格后形成钢筋单元

建立混凝土单元

合并单元节点后施加约束以及位移载荷

进入求解器进行求解
钢筋单元的受力云图

混凝土的应力云图

混凝土开裂

2 使用单元solid45号单元 与beam188
钢筋的应力应变关系不变，而混凝土应力应变关系为：

混凝土单元

钢筋单元

力与位移曲线

精品资料
合并节点时的命令流:
fini
/clear,nostart
/config,nres,5000
/prep7
/title,rc-beam
b=150
h=300
a=30
l=2000
fcu=40
ec=2.85e4
displacement=10
!定义单元类型
et,1,solid45
et,2,beam188
et,3,plane42
!定义截面类型
sectype,1,beam,csolid,,0
secoffset,cent
secdata,8,0,0,0,0,0,0,0,0,0
sectype,2,beam,csolid,,0
secoffset,cent
secdata,4,0,0,0,0,0,0,0,0,0
!定义材料属性，混凝土材料属性
mp,ex,1,ec
mp,prxy,1,0.2
tb,kinh,1,,16
tbpt,,0.000179067,5.10
tbpt,,0.000358133,9.67
tbpt,,0.0005372,1.37e1
tbpt,,0.000716267,1.72e1
tbpt,,0.000895333,2.01e1
tbpt,,0.0010744,2.26e1
tbpt,,0.001253467,2.44e1
tbpt,,0.001432533,2.58e1
tbpt,,0.0016116,2.66e1
tbpt,,0.001790667,2.69e1
tbpt,,0.0019916,2.65e1
tbpt,,0.002393467,2.57e1
tbpt,,0.002795333,2.48e1
tbpt,,0.0031972,2.40e1
tbpt,,0.003599067,2.32e1
tbpt,,0.0038,2.28e1
tb,conc,1,1,9
tbdata,,0.4,1,3,-1
!纵向受拉钢筋
mp,ex,2,2e5
mp,prxy,2,0.3
tb,bkin,2,1,2,1
tbdata,,350
!横向箍筋，受压钢筋材料属性
mp,ex,3,2e5
mp,prxy,3,0.25
tb,bkin,3,1,2,1
tbdata,,200
!生成钢筋线
k,,
k,,b
kgen,2,1,2,,,h
k,,a,a
k,,b-a,a
kgen,2,5,6,,,h-2*a
kgen,21,5,8,,,,-100
*do,i,5,84,1
l,i,i+4
*enddo
*do,i,5,85,4
l,i,i+1
l,i,i+2
*enddo
*do,i,8,88,4
l,i,i-1
l,i,i-2
*enddo
!受拉钢筋
lsel,s,loc,y,a
lsel,r,loc,x,a
lsel,a,loc,x,b-a
lsel,r,loc,y,a
cm,longitudinal,line
type,2
mat,2
secnum,1
lesize,all,50
lmesh,all
alls
cmsel,u,longitudinal
cm,hooping reinforcement,line
!箍筋，受压钢筋
type,2
mat,2
secnum,2
lesize,all,50
lmesh,all
/eshape,1
!将钢筋节点建为一个集合
cm,steel,node
!生成面单元，以便拉伸成体单元
a,1,2,4,3
lsel,s,loc,y,0
lsel,a,loc,y,h
lesize,all,,,8
lsel,all
lsel,s,loc,x,0
lsel,a,loc,x,b
lesize,all,,,10
type,3
amesh,all
!拉伸成混凝土单元
type,1
real,3
mat,1
extopt,esize,20
extopt,aclear,1
vext,all,,,,,-l
alls
!合并节点
nummrg,all
numcmp,all
!边界条件约束
nsel,s,loc,y,0
nsel,r,loc,z,0
d,all,uy
d,all,ux
nsel,s,loc,y,0
nsel,r,loc,z,-l
d,all,uy
d,all,ux
!施加外部荷载
/solu
nsel,all
nsel,s,loc,y,h
nsel,r,loc,z,-1000
d,all,uy,-displacement
alls
!求解
nlgeom,on
nsubst,50
outres,all,all
neqit,50
pred,on
cnvtol,f,,0.05,2,0.5
allsel
solve
finish
/post1
allsel
/device,vector,1
!时间历程后处理
/post26
nsel,s,loc,z,-l/2
*get,Nmin,node,0,num,min
nsol,2,nmin,u,y
prod,3,2,,,,,,-1
nsel,s,loc,y,0
nsel,r,loc,z,0
*get,Nnum,node,0,count
*get,Nmin,node,0,num,min
n0=Nmin
rforce,5,Nmin,f,y
*do,i,2,ndinqr(1,13)
ni=ndnext(n0)
rforce,6,ni,f,y
add,5,5,6
n0=ni
*enddo
prod,7,5,,,,,,1/1000
/axlab,x,uy
/axlab,y,p(kn)
xvar,3
plvar,7

二、用约束方程法模拟钢筋混凝土梁
1．用solid65号单元以及beam188单元时
混凝土以及钢筋采用线弹性关系：
建立钢筋线

对钢筋线划分网格后形成钢筋单元

建立混凝土单元

对钢筋线节点以及混凝土节点之间建立约束方程

后施加约束以及位移载荷

进入求解器进行求解；钢筋单元的受力云图

混凝土的应力云图

混凝土开裂
2 使用单元solid45号单元 与beam188
使用混凝土的本构关系曲线

钢材的本构关系曲线

钢筋的von mises 应力

混凝土的应力

用在solid45号单元下，用合并节点法、约束方程法建立模中钢筋与混凝土之间的关系的时候的一个力与位移全程曲线的比较。

约束方程法命令流:

fini
/clear,nostart
/config,nres,5000
/prep7
/title,rc-beam
b=150
h=300
a=30
l=2000
fcu=40
ec=2.85e4
displacement=5
!定义单元类型
et,1,solid65
et,2,beam188
et,3,plane42
!定义截面类型
sectype,1,beam,csolid,,0
secoffset,cent
secdata,8,0,0,0,0,0,0,0,0,0
sectype,2,beam,csolid,,0
secoffset,cent
secdata,4,0,0,0,0,0,0,0,0,0
!定义材料属性，混凝土材料属性
mp,ex,1,ec
mp,prxy,1,0.2
tb,kinh,1,,16
tbpt,,0.000179067,5.10
tbpt,,0.000358133,9.67
tbpt,,0.0005372,1.37e1
tbpt,,0.000716267,1.72e1
tbpt,,0.000895333,2.01e1
tbpt,,0.0010744,2.26e1
tbpt,,0.001253467,2.44e1
tbpt,,0.001432533,2.58e1
tbpt,,0.0016116,2.66e1
tbpt,,0.001790667,2.69e1
tbpt,,0.0019916,2.65e1
tbpt,,0.002393467,2.57e1
tbpt,,0.002795333,2.48e1
tbpt,,0.0031972,2.40e1
tbpt,,0.003599067,2.32e1
tbpt,,0.0038,2.28e1
!tb,conc,1,1,9
!tbdata,,0.4,1,3,-1
!纵向受拉钢筋
mp,ex,2,2e5
mp,prxy,2,0.3
tb,bkin,2,1,2,1
tbdata,,350
!横向箍筋，受压钢筋材料属性
mp,ex,3,2e5
mp,prxy,3,0.25
tb,bkin,3,1,2,1
tbdata,,200
!生成钢筋线
k,,
k,,b
kgen,2,1,2,,,h
k,,a,a
k,,b-a,a
kgen,2,5,6,,,h-2*a
kgen,21,5,8,,,,-100
*do,i,5,84,1
l,i,i+4
*enddo
*do,i,9,81,4
l,i,i+1
l,i,i+2
*enddo
*do,i,12,84,4
l,i,i-1
l,i,i-2
*enddo
!受拉钢筋
lsel,s,loc,y,a
lsel,r,loc,x,a
lsel,a,loc,x,b-a
lsel,r,loc,y,a
cm,longitudinal,line
type,2
mat,2
secnum,1
lesize,all,50
lmesh,all
alls
cmsel,u,longitudinal
cm,hooping reinforcement,line
!箍筋，受压钢筋
type,2
mat,2
secnum,2
lesize,all,50
lmesh,all
/eshape,1
!将钢筋节点建为一个集合
cm,steel,node
!生成面单元，以便拉伸成体单元
a,1,2,4,3
lsel,s,loc,y,0
lsel,a,loc,y,h
lesize,all,,,10
lsel,all
lsel,s,loc,x,0
lsel,a,loc,x,b
lesize,all,,,20
type,3
amesh,all
!拉伸成混凝土单元
type,1
real,3
mat,1
extopt,esize,30
extopt,aclear,1
vext,all,,,,,-l
alls
!建立约束方程
cmsel,s,hooping reinforcement
cmsel,a,longitudinal
nsll,s,1
ceintf,,ux,uy,uz
allsel,all
!边界条件约束
nsel,s,loc,y,0
nsel,r,loc,z,0
d,all,uy
d,all,ux
nsel,s,loc,y,0
nsel,r,loc,z,-l
d,all,uy
d,all,ux
!施加外部荷载
/solu
nsel,all
nsel,s,loc,y,h
nsel,r,loc,z,-1000
d,all,uy,-displacement
alls
!求解
nlgeom,on
nsubst,200
outres,all,all
neqit,100
pred,on
cnvtol,f,,0.05,2,0.5
allsel
solve
finish
/post1
allsel
plcrack,0,1
plcrack,0,2
!时间历程后处理
/post26
nsel,s,loc,z,-l/2
*get,Nmin,node,0,num,min
nsol,2,nmin,u,y
prod,3,2,,,,,,-1
nsel,s,loc,y,0
nsel,r,loc,z,0
*get,Nnum,node,0,count
*get,Nmin,node,0,num,min
n0=Nmin
rforce,5,Nmin,f,y
*do,i,2,ndinqr(1,13)
ni=ndnext(n0)
rforce,6,ni,f,y
add,5,5,6
n0=ni
*enddo
prod,7,5,,,,,,1/1000
/axlab,x,uy
/axlab,y,p(kn)
xvar,3
plvar,7

Welcome To
Download !!!

欢迎您的下载，资料仅供参考！